gentoo resync : 07.04.2018

6 files changed, 452 insertions, 6 deletions

diff --git a/sys-devel/Manifest.gz b/sys-devel/Manifest.gz
index d1fa5b0a06f6..934baa7aa1c0 100644
--- a/sys-devel/Manifest.gz
+++ b/sys-devel/Manifest.gz
diff --git a/sys-devel/binutils/Manifest b/sys-devel/binutils/Manifest
index 0584bbb1f332..f959925068de 100644
--- a/sys-devel/binutils/Manifest
+++ b/sys-devel/binutils/Manifest
@@ -17,6 +17,7 @@ EBUILD binutils-2.26.1.ebuild 280 BLAKE2B 6c8363e933c3a7e40fc21a737b59d08d2b9bdd
 EBUILD binutils-2.27-r1.ebuild 293 BLAKE2B 750c39e7ba698916b54eadd97e36fa8b84c9aaa547bcd671deaff719e9d95e66265a12c7845ea7a98de4337263230ac69f0f634c29a6bead78fa13820dca280f SHA512 4137e36156afbfd4ddc6ba08b6fc94e37556375c42f77e21d72d8338e55af094ef28bcbdfcf2c686232b5932208562f38b64db8638d2199ecfc2465518544267
 EBUILD binutils-2.28.1.ebuild 280 BLAKE2B 6c8363e933c3a7e40fc21a737b59d08d2b9bddc950a6b103036e3b8dff1933f9b8d803fe2c85b1497119ee1fb6358c08234cf44eb5a57a43061c815fbd510080 SHA512 322c2cbc01135c2c22afeeeef1a6147e9c896432ee81cee131965013e67d569f49e4017e76d9fec90a00175fd4af2cf0fd3e00ef1e76157f85506e5d33e3035d
 EBUILD binutils-2.29.1-r1.ebuild 328 BLAKE2B 1f38a6896f710e1c18ea80569f02a93814daaf0fa84b08f9762bbe002607189a8c75ddcbee978af878d5976ede247f31d84fda6c00142f5020e7d18b4b03b17c SHA512 7a08fc2878be20f311cd5cf10f59035f17869da5f59822a73c55da3c134a9dffdc57de855f7392b396dfe3a526c1dc4ff60d3202466b6e9c2d26e1cd18a48289
+EBUILD binutils-2.30-r1.ebuild 11829 BLAKE2B ad60e93099fe94c11dfe4f25fc719256896649eccc30e586b2df2a7f30c2eb64e36a0d693d9916ec79ba99fe40a03c3ed330da4183bb0721817ea151d92df7a2 SHA512 91c0d96611bfff8f79820849a98547716236f96f1aa45f4c861f3aa466f6e3c51eeeac219ba4e851d337dbf97dafb007e54d9403d63064840624d5947fb27859
 EBUILD binutils-2.30.ebuild 10534 BLAKE2B a2fc2c0f281338402e6603cec7e53cd9760faf2966fa9c8223f2840ed6b7fb9590a829b4d1c218be3fde12e2835bb5d38a0f4f950da4087a385ae748b6592cc8 SHA512 4e58b473af1c16d605d7aed56baa84cd6c83835bb4ba2ed91990c78e7dbd4fb1584a415cfa7807da7a7bbdb725b717908e023711f47119735c9ab5b7343578e9
-EBUILD binutils-9999.ebuild 10335 BLAKE2B 576d8aa44e86a6ec442908d0e0d85b9e28808febcef399148183e026c75ee3082d7457eee734f2cf83331da6b9a0860aec5ff9a796b1d8aa13b4aed09f43a885 SHA512 398758514207ffce6c0c3d8fa1c0ec34465fa72c20d1ed572a4911e88ac79b05a679e15727346fabe4b84c96d9f6f555d70db7f75fa501a0c3492cd21af6d71d
+EBUILD binutils-9999.ebuild 11630 BLAKE2B 3fa2f747f6a8132c3e09f41d1dc5728f471f264ffc273c1e00fdd1a4892b76c668e1511c16adfdad74c3ed2dee61302903d54d9f91567bb29b7e875cfeaa3d14 SHA512 b802b3ee0d6eb9770d6611bfbccf860debb97179e33468024037062351359c5a8d9adf86f11da7ddc4ca48dff49ee9243d5a369d67dc40a15b1d2100be587776
 MISC metadata.xml 447 BLAKE2B 78d0b6e0a34f19d0f90f568fb84fcddbc995eb2c64f9c4feef2545d49322311fc6825b3b208dc03718bd75d550581efbdc9ee26e7f7a6f856902e640f90bf0f5 SHA512 73cb18db3a677767a78d5cab44ca721083ef17b4a158c10a66a186835b57a3d763b6f6753c836620b32ec912834ae8da2148c8fa0e4932170956b92c75169a9d
diff --git a/sys-devel/binutils/binutils-2.30-r1.ebuild b/sys-devel/binutils/binutils-2.30-r1.ebuild
new file mode 100644
index 000000000000..145bbe7e2907
--- /dev/null
+++ b/sys-devel/binutils/binutils-2.30-r1.ebuild
@@ -0,0 +1,415 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils libtool flag-o-matic gnuconfig multilib versionator
+
+DESCRIPTION="Tools necessary to build programs"
+HOMEPAGE="https://sourceware.org/binutils/"
+LICENSE="GPL-3+"
+IUSE="+cxx doc multitarget +nls static-libs test"
+
+# Variables that can be set here:
+# PATCH_VER          - the patchset version
+#                      Default: empty, no patching
+# PATCH_BINUTILS_VER - the binutils version in the patchset name
+#                    - Default: PV
+# PATCH_DEV          - Use download URI https://dev.gentoo.org/~{PATCH_DEV}/distfiles/...
+#                      for the patchsets
+#                      Default: dilfridge :)
+
+PATCH_VER=1
+
+case ${PV} in
+	9999)
+		BVER="git"
+		EGIT_REPO_URI="https://sourceware.org/git/binutils-gdb.git"
+		inherit git-r3
+		S=${WORKDIR}/binutils
+		EGIT_CHECKOUT_DIR=${S}
+		;;
+	*)
+		BVER=${PV}
+		SRC_URI="mirror://gnu/binutils/binutils-${BVER}.tar.xz https://sourceware.org/pub/binutils/releases/binutils-${BVER}.tar.xz"
+		;;
+esac
+SLOT="${BVER}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+
+#
+# The Gentoo patchset
+#
+PATCH_BINUTILS_VER=${PATCH_BINUTILS_VER:-${BVER}}
+PATCH_DEV=${PATCH_DEV:-dilfridge}
+
+[[ -z ${PATCH_VER} ]] || SRC_URI="${SRC_URI}
+	https://dev.gentoo.org/~${PATCH_DEV}/distfiles/binutils-${PATCH_BINUTILS_VER}-patches-${PATCH_VER}.tar.xz"
+
+#
+# The cross-compile logic
+#
+export CTARGET=${CTARGET:-${CHOST}}
+if [[ ${CTARGET} == ${CHOST} ]] ; then
+	if [[ ${CATEGORY} == cross-* ]] ; then
+		export CTARGET=${CATEGORY#cross-}
+	fi
+fi
+is_cross() { [[ ${CHOST} != ${CTARGET} ]] ; }
+
+#
+# The dependencies
+#
+RDEPEND="
+	>=sys-devel/binutils-config-3
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	doc? ( sys-apps/texinfo )
+	test? ( dev-util/dejagnu )
+	nls? ( sys-devel/gettext )
+	sys-devel/flex
+	virtual/yacc
+"
+if is_cross ; then
+	# The build assumes the host has libiberty and such when cross-compiling
+	# its build tools.  We should probably make binutils itself build a local
+	# copy to use, but until then, be lazy.
+	DEPEND+=" >=sys-libs/binutils-libs-${PV}"
+fi
+
+MY_BUILDDIR=${WORKDIR}/build
+
+src_unpack() {
+	case ${PV} in
+		9999)
+			git-r3_src_unpack;
+			;;
+		*)
+			default
+			;;
+	esac
+	mkdir -p "${MY_BUILDDIR}"
+}
+
+src_prepare() {
+	if [[ ! -z ${PATCH_VER} ]] ; then
+		einfo "Applying binutils-${PATCH_BINUTILS_VER} patchset ${PATCH_VER}"
+		eapply "${WORKDIR}/patch"/*.patch
+	fi
+
+	# This check should probably go somewhere else, like pkg_pretend.
+	if [[ ${CTARGET} == *-uclibc* ]] ; then
+		if grep -qs 'linux-gnu' "${S}"/ltconfig ; then
+			die "sorry, but this binutils doesn't yet support uClibc :("
+		fi
+	fi
+
+	# Make sure our explicit libdir paths don't get clobbered. #562460
+	sed -i \
+		-e 's:@bfdlibdir@:@libdir@:g' \
+		-e 's:@bfdincludedir@:@includedir@:g' \
+		{bfd,opcodes}/Makefile.in || die
+
+	# Fix locale issues if possible #122216
+	if [[ -e ${FILESDIR}/binutils-configure-LANG.patch ]] ; then
+		einfo "Fixing misc issues in configure files"
+		for f in $(find "${S}" -name configure -exec grep -l 'autoconf version 2.13' {} +) ; do
+			ebegin "  Updating ${f/${S}\/}"
+			patch "${f}" "${FILESDIR}"/binutils-configure-LANG.patch >& "${T}"/configure-patch.log \
+				|| eerror "Please file a bug about this"
+			eend $?
+		done
+	fi
+
+	# Fix conflicts with newer glibc #272594
+	if [[ -e libiberty/testsuite/test-demangle.c ]] ; then
+		sed -i 's:\<getline\>:get_line:g' libiberty/testsuite/test-demangle.c
+	fi
+
+	# Apply things from PATCHES and user dirs
+	default
+
+	# Run misc portage update scripts
+	gnuconfig_update
+	elibtoolize --portage --no-uclibc
+}
+
+toolchain-binutils_bugurl() {
+	printf "https://bugs.gentoo.org/"
+}
+toolchain-binutils_pkgversion() {
+	printf "Gentoo ${BVER}"
+	[[ -n ${PATCH_VER} ]] && printf " p${PATCH_VER}"
+}
+
+src_configure() {
+	# Setup some paths
+	LIBPATH=/usr/$(get_libdir)/binutils/${CTARGET}/${BVER}
+	INCPATH=${LIBPATH}/include
+	DATAPATH=/usr/share/binutils-data/${CTARGET}/${BVER}
+	if is_cross ; then
+		TOOLPATH=/usr/${CHOST}/${CTARGET}
+	else
+		TOOLPATH=/usr/${CTARGET}
+	fi
+	BINPATH=${TOOLPATH}/binutils-bin/${BVER}
+
+	# Make sure we filter $LINGUAS so that only ones that
+	# actually work make it through #42033
+	strip-linguas -u */po
+
+	# Keep things sane
+	strip-flags
+
+	local x
+	echo
+	for x in CATEGORY CBUILD CHOST CTARGET CFLAGS LDFLAGS ; do
+		einfo "$(printf '%10s' ${x}:) ${!x}"
+	done
+	echo
+
+	cd "${MY_BUILDDIR}"
+	local myconf=()
+
+	# enable gold (installed as ld.gold) and ld's plugin architecture
+	if use cxx ; then
+		myconf+=( --enable-gold )
+		myconf+=( --enable-plugins )
+	fi
+
+	if use nls ; then
+		myconf+=( --without-included-gettext )
+	else
+		myconf+=( --disable-nls )
+	fi
+
+	myconf+=( --with-system-zlib )
+
+	# For bi-arch systems, enable a 64bit bfd.  This matches
+	# the bi-arch logic in toolchain.eclass. #446946
+	# We used to do it for everyone, but it's slow on 32bit arches. #438522
+	case $(tc-arch) in
+		ppc|sparc|x86) myconf+=( --enable-64-bit-bfd ) ;;
+	esac
+
+	use multitarget && myconf+=( --enable-targets=all --enable-64-bit-bfd )
+
+	[[ -n ${CBUILD} ]] && myconf+=( --build=${CBUILD} )
+
+	is_cross && myconf+=(
+		--with-sysroot="${EPREFIX}"/usr/${CTARGET}
+		--enable-poison-system-directories
+	)
+
+	# glibc-2.3.6 lacks support for this ... so rather than force glibc-2.5+
+	# on everyone in alpha (for now), we'll just enable it when possible
+	has_version ">=${CATEGORY}/glibc-2.5" && myconf+=( --enable-secureplt )
+	has_version ">=sys-libs/glibc-2.5" && myconf+=( --enable-secureplt )
+
+	# mips can't do hash-style=gnu ...
+	if [[ $(tc-arch) != mips ]] ; then
+		myconf+=( --enable-default-hash-style=gnu )
+	fi
+
+	myconf+=(
+		--prefix="${EPREFIX}"/usr
+		--host=${CHOST}
+		--target=${CTARGET}
+		--datadir="${EPREFIX}"${DATAPATH}
+		--datarootdir="${EPREFIX}"${DATAPATH}
+		--infodir="${EPREFIX}"${DATAPATH}/info
+		--mandir="${EPREFIX}"${DATAPATH}/man
+		--bindir="${EPREFIX}"${BINPATH}
+		--libdir="${EPREFIX}"${LIBPATH}
+		--libexecdir="${EPREFIX}"${LIBPATH}
+		--includedir="${EPREFIX}"${INCPATH}
+		--enable-obsolete
+		--enable-shared
+		--enable-threads
+		# Newer versions (>=2.27) offer a configure flag now.
+		--enable-relro
+		# Newer versions (>=2.24) make this an explicit option. #497268
+		--enable-install-libiberty
+		--disable-werror
+		--with-bugurl="$(toolchain-binutils_bugurl)"
+		--with-pkgversion="$(toolchain-binutils_pkgversion)"
+		$(use_enable static-libs static)
+		${EXTRA_ECONF}
+		# Disable modules that are in a combined binutils/gdb tree. #490566
+		--disable-{gdb,libdecnumber,readline,sim}
+		# Strip out broken static link flags.
+		# https://gcc.gnu.org/PR56750
+		--without-stage1-ldflags
+	)
+	echo ./configure "${myconf[@]}"
+	"${S}"/configure "${myconf[@]}" || die
+
+	# Prevent makeinfo from running if doc is unset.
+	if ! use doc ; then
+		sed -i \
+			-e '/^MAKEINFO/s:=.*:= true:' \
+			Makefile || die
+	fi
+}
+
+src_compile() {
+	cd "${MY_BUILDDIR}"
+	# see Note [tooldir hack for ldscripts]
+	emake tooldir="${EPREFIX}${TOOLPATH}" all
+
+	# only build info pages if the user wants them
+	if use doc ; then
+		emake info
+	fi
+
+	# we nuke the manpages when we're left with junk
+	# (like when we bootstrap, no perl -> no manpages)
+	find . -name '*.1' -a -size 0 -delete
+}
+
+src_test() {
+	cd "${MY_BUILDDIR}"
+	emake -k check
+}
+
+src_install() {
+	local x d
+
+	cd "${MY_BUILDDIR}"
+	# see Note [tooldir hack for ldscripts]
+	emake DESTDIR="${D}" tooldir="${EPREFIX}${LIBPATH}" install
+	rm -rf "${ED}"/${LIBPATH}/bin
+	use static-libs || find "${ED}" -name '*.la' -delete
+
+	# Newer versions of binutils get fancy with ${LIBPATH} #171905
+	cd "${ED}"/${LIBPATH}
+	for d in ../* ; do
+		[[ ${d} == ../${BVER} ]] && continue
+		mv ${d}/* . || die
+		rmdir ${d} || die
+	done
+
+	# Now we collect everything intp the proper SLOT-ed dirs
+	# When something is built to cross-compile, it installs into
+	# /usr/$CHOST/ by default ... we have to 'fix' that :)
+	if is_cross ; then
+		cd "${ED}"/${BINPATH}
+		for x in * ; do
+			mv ${x} ${x/${CTARGET}-}
+		done
+
+		if [[ -d ${ED}/usr/${CHOST}/${CTARGET} ]] ; then
+			mv "${ED}"/usr/${CHOST}/${CTARGET}/include "${ED}"/${INCPATH}
+			mv "${ED}"/usr/${CHOST}/${CTARGET}/lib/* "${ED}"/${LIBPATH}/
+			rm -r "${ED}"/usr/${CHOST}/{include,lib}
+		fi
+	fi
+	insinto ${INCPATH}
+	local libiberty_headers=(
+		# Not all the libiberty headers.  See libiberty/Makefile.in:install_to_libdir.
+		demangle.h
+		dyn-string.h
+		fibheap.h
+		hashtab.h
+		libiberty.h
+		objalloc.h
+		splay-tree.h
+	)
+	doins "${libiberty_headers[@]/#/${S}/include/}" || die
+	if [[ -d ${ED}/${LIBPATH}/lib ]] ; then
+		mv "${ED}"/${LIBPATH}/lib/* "${ED}"/${LIBPATH}/
+		rm -r "${ED}"/${LIBPATH}/lib
+	fi
+
+	# Generate an env.d entry for this binutils
+	insinto /etc/env.d/binutils
+	cat <<-EOF > "${T}"/env.d
+		TARGET="${CTARGET}"
+		VER="${BVER}"
+		LIBPATH="${EPREFIX}${LIBPATH}"
+	EOF
+	newins "${T}"/env.d ${CTARGET}-${BVER}
+
+	# Handle documentation
+	if ! is_cross ; then
+		cd "${S}"
+		dodoc README
+		docinto bfd
+		dodoc bfd/ChangeLog* bfd/README bfd/PORTING bfd/TODO
+		docinto binutils
+		dodoc binutils/ChangeLog binutils/NEWS binutils/README
+		docinto gas
+		dodoc gas/ChangeLog* gas/CONTRIBUTORS gas/NEWS gas/README*
+		docinto gprof
+		dodoc gprof/ChangeLog* gprof/TEST gprof/TODO gprof/bbconv.pl
+		docinto ld
+		dodoc ld/ChangeLog* ld/README ld/NEWS ld/TODO
+		docinto libiberty
+		dodoc libiberty/ChangeLog* libiberty/README
+		docinto opcodes
+		dodoc opcodes/ChangeLog*
+	fi
+
+	# Remove shared info pages
+	rm -f "${ED}"/${DATAPATH}/info/{dir,configure.info,standards.info}
+
+	# Trim all empty dirs
+	find "${ED}" -depth -type d -exec rmdir {} + 2>/dev/null
+}
+
+pkg_postinst() {
+	# Make sure this ${CTARGET} has a binutils version selected
+	[[ -e ${EROOT}/etc/env.d/binutils/config-${CTARGET} ]] && return 0
+	binutils-config ${CTARGET}-${BVER}
+}
+
+pkg_postrm() {
+	local current_profile=$(binutils-config -c ${CTARGET})
+
+	# If no other versions exist, then uninstall for this
+	# target ... otherwise, switch to the newest version
+	# Note: only do this if this version is unmerged.  We
+	#       rerun binutils-config if this is a remerge, as
+	#       we want the mtimes on the symlinks updated (if
+	#       it is the same as the current selected profile)
+	if [[ ! -e ${EPREFIX}${BINPATH}/ld ]] && [[ ${current_profile} == ${CTARGET}-${BVER} ]] ; then
+		local choice=$(binutils-config -l | grep ${CTARGET} | awk '{print $2}')
+		choice=${choice//$'\n'/ }
+		choice=${choice/* }
+		if [[ -z ${choice} ]] ; then
+			env -i ROOT="${ROOT}" binutils-config -u ${CTARGET}
+		else
+			binutils-config ${choice}
+		fi
+	elif [[ $(CHOST=${CTARGET} binutils-config -c) == ${CTARGET}-${BVER} ]] ; then
+		binutils-config ${CTARGET}-${BVER}
+	fi
+}
+
+# Note [slotting support]
+# -----------------------
+# Gentoo's layout for binutils files is non-standard as Gentoo
+# supports slotted installation for binutils. But many tools
+# still expect binutils to reside in known locations.
+# binutils-config package restores symlinks into known locations,
+# like:
+#    /usr/bin/${CTARGET}-<tool>
+#    /usr/bin/${CHOST}/${CTARGET}/lib/ldscrips
+#    /usr/include/
+#
+# Note [tooldir hack for ldscripts]
+# ---------------------------------
+# Build system does not ./configure to tweak evey location we need
+# for slotting binutils. This note is about SCRIPTDIR define.
+#
+# SCRIPDIR defines 'ldscripts/' directory location. SCRIPDIR value
+# is set at build-time in ld/Makefile.am as: 'scriptdir = $(tooldir)/lib'
+# and hardcoded as -DSCRIPTDIR='"$(scriptdir)"' at compile time.
+# Thus we can't just move files around after compilation finished.
+#
+# Our goal is the following:
+# - at build-time set scriptdir to point to symlinked location:
+#   ${TOOLPATH}: /usr/${CHOST} (or /usr/${CHOST}/${CTARGET} for cross-case)
+# - at install-time set scriptdir to point to slotted location:
+#   ${LIBPATH}: /usr/$(get_libdir)/binutils/${CTARGET}/${BVER}
diff --git a/sys-devel/binutils/binutils-9999.ebuild b/sys-devel/binutils/binutils-9999.ebuild
index f0c8730c8197..1c3f3623a947 100644
--- a/sys-devel/binutils/binutils-9999.ebuild
+++ b/sys-devel/binutils/binutils-9999.ebuild
@@ -146,10 +146,11 @@ src_configure() {
 	INCPATH=${LIBPATH}/include
 	DATAPATH=/usr/share/binutils-data/${CTARGET}/${BVER}
 	if is_cross ; then
-		BINPATH=/usr/${CHOST}/${CTARGET}/binutils-bin/${BVER}
+		TOOLPATH=/usr/${CHOST}/${CTARGET}
 	else
-		BINPATH=/usr/${CTARGET}/binutils-bin/${BVER}
+		TOOLPATH=/usr/${CTARGET}
 	fi
+	BINPATH=${TOOLPATH}/binutils-bin/${BVER}
 
 	# Make sure we filter $LINGUAS so that only ones that
 	# actually work make it through #42033
@@ -251,7 +252,8 @@ src_configure() {
 
 src_compile() {
 	cd "${MY_BUILDDIR}"
-	emake all
+	# see Note [tooldir hack for ldscripts]
+	emake tooldir="${EPREFIX}${TOOLPATH}" all
 
 	# only build info pages if the user wants them
 	if use doc ; then
@@ -272,6 +274,7 @@ src_install() {
 	local x d
 
 	cd "${MY_BUILDDIR}"
+	# see Note [tooldir hack for ldscripts]
 	emake DESTDIR="${D}" tooldir="${EPREFIX}${LIBPATH}" install
 	rm -rf "${ED}"/${LIBPATH}/bin
 	use static-libs || find "${ED}" -name '*.la' -delete
@@ -380,3 +383,30 @@ pkg_postrm() {
 		binutils-config ${CTARGET}-${BVER}
 	fi
 }
+
+# Note [slotting support]
+# -----------------------
+# Gentoo's layout for binutils files is non-standard as Gentoo
+# supports slotted installation for binutils. But many tools
+# still expect binutils to reside in known locations.
+# binutils-config package restores symlinks into known locations,
+# like:
+#    /usr/bin/${CTARGET}-<tool>
+#    /usr/bin/${CHOST}/${CTARGET}/lib/ldscrips
+#    /usr/include/
+#
+# Note [tooldir hack for ldscripts]
+# ---------------------------------
+# Build system does not ./configure to tweak evey location we need
+# for slotting binutils. This note is about SCRIPTDIR define.
+#
+# SCRIPDIR defines 'ldscripts/' directory location. SCRIPDIR value
+# is set at build-time in ld/Makefile.am as: 'scriptdir = $(tooldir)/lib'
+# and hardcoded as -DSCRIPTDIR='"$(scriptdir)"' at compile time.
+# Thus we can't just move files around after compilation finished.
+#
+# Our goal is the following:
+# - at build-time set scriptdir to point to symlinked location:
+#   ${TOOLPATH}: /usr/${CHOST} (or /usr/${CHOST}/${CTARGET} for cross-case)
+# - at install-time set scriptdir to point to slotted location:
+#   ${LIBPATH}: /usr/$(get_libdir)/binutils/${CTARGET}/${BVER}
diff --git a/sys-devel/boost-m4/Manifest b/sys-devel/boost-m4/Manifest
index 4f94a241d64d..e8afc889cbc0 100644
--- a/sys-devel/boost-m4/Manifest
+++ b/sys-devel/boost-m4/Manifest
@@ -3,5 +3,5 @@ DIST boost-m4-0.4.tar.gz 38871 BLAKE2B 95475d8109f13b420ee5ac95588e5756b17e923ef
 DIST boost-m4-0.4_p20160328.tar.gz 41253 BLAKE2B 47ad17f652560dce4e276b295e55e7daa8752f1c932a6c0d1bad9e4bc2ff72eb0adfaf8abc4e7c57f179f08857de255935fc530f0a4d8a26d3f6a2a0711417ac SHA512 4aecd311b21ced4a3d62fc706a9fa731c375ea490482f78756892243b5af6909cd8841c249632b37820be7f1bde41c290e842edd933d0c727e1dca76d30eb506
 EBUILD boost-m4-0.4-r1.ebuild 917 BLAKE2B c32b670293a9b5b5bd949c71c35d6bae28581db8aef36afd4532e8c7f92fe9beb58a84496e2bcc17c884ad46e3c1b8e5468579947e1008c0393e211ce4849d61 SHA512 d6fa04dca6ce327db4189f03e8e7a7239e69c1f16b9c5a91a7b8020b1dc970ea8393daa2c8dbab1f11d433e63d11858f96bc5790334f65e4260696198b0912d8
 EBUILD boost-m4-0.4.ebuild 844 BLAKE2B 5d1ab04c297ef3f76665ccf1e18a66a5018945287a7acc0874b2a32b764db1770f39cae4f814cddc2e008e13821884134d4414d0ef8838f761b5b88d6af73a11 SHA512 896b5628af4a1934c25543d564a2266bdf7afc0653ec93de84155d16b905aeaede4e4877b0dd3afde6a6bacbce266c8247a2cde9cc8f1662af53878b478161d0
-EBUILD boost-m4-0.4_p20160328.ebuild 907 BLAKE2B e08fcd2cbb5d69db9952d9dccd31c211861a43e905224afac9cfef65aaee6032c165077e44c6edbe348a2ec27e7e3ef17655c972e61015d41b21f64a9c905e41 SHA512 e1c1ed673bc9a527e20c28d8b0d6ae5ef6ccba92357aacef155023deaef3ee2aceb5e4dfc376ccf42041a47707f5a8f94ddeb3fd121d422cda4f64f43652c23f
+EBUILD boost-m4-0.4_p20160328.ebuild 906 BLAKE2B 86bada0f35bc7cafb53e15d9367eff8c9a737bb078bdf40d5406e0a3fb987eaf411956bd4364c1a5b25f5970fe58ad0c611d2c468ce0cfbccc1f5033ee6b6b8b SHA512 4384aba089115f27f7553ab6da59b819d644dc85f1895ee645ecdf2a304d464a4fa064a56d66016a4b22151c4f5efd4101b60707321f25c33cf50acf85cc5b4f
 MISC metadata.xml 222 BLAKE2B 448a1ea951952548a4400942106647671f29fd652f7cfb1c37fe9560e77f169f9ba9b68967736b542d134c111924cd0e2d84dc4db6269690234b6f0b50cac630 SHA512 5144b4eb888e33db8ccf9038a19bebaca24c0ad51a04e706f1701214adab830a39907686b4c4d655f147b827c34dc2fda9737680ee983da5f62b417ec0775557
diff --git a/sys-devel/boost-m4/boost-m4-0.4_p20160328.ebuild b/sys-devel/boost-m4/boost-m4-0.4_p20160328.ebuild
index 9cf5959f1eeb..2a6a29b45a13 100644
--- a/sys-devel/boost-m4/boost-m4-0.4_p20160328.ebuild
+++ b/sys-devel/boost-m4/boost-m4-0.4_p20160328.ebuild
@@ -9,7 +9,7 @@ SRC_URI="https://dev.gentoo.org/~soap/distfiles/${P}.tar.gz"
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="alpha amd64 ~arm ~hppa ia64 ~mips ~ppc ~ppc64 sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+KEYWORDS="alpha amd64 ~arm ~hppa ia64 ~mips ~ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
 IUSE=""
 S="${WORKDIR}/boost.m4-1489691f65aecb593e33abc3e56ac482dd67da7b"