gentoo resync : 12.05.2022

1 files changed, 0 insertions, 87 deletions

diff --git a/sys-devel/mold/mold-1.1.1.ebuild b/sys-devel/mold/mold-1.1.1.ebuild
deleted file mode 100644
index 5ea54e0926db..000000000000
--- a/sys-devel/mold/mold-1.1.1.ebuild
+++ /dev/null
@@ -1,87 +0,0 @@
-# Copyright 2021-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit toolchain-funcs
-
-DESCRIPTION="A Modern Linker"
-HOMEPAGE="https://github.com/rui314/mold"
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/rui314/mold.git"
-	inherit git-r3
-else
-	SRC_URI="https://github.com/rui314/mold/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
-fi
-
-LICENSE="AGPL-3"
-SLOT="0"
-
-RDEPEND=">=dev-cpp/tbb-2021.4.0:=
-	sys-libs/zlib
-	!kernel_Darwin? (
-		>=dev-libs/mimalloc-2:=
-		dev-libs/openssl:=
-	)"
-# As of 1.1, xxhash is now a header-only dep, but it's now bundled :(
-# TODO: restore SYSTEM_XXHASH upstream?
-DEPEND="${RDEPEND}"
-
-pkg_pretend() {
-	# Requires a c++20 compiler, see #831473
-	if [[ ${MERGE_TYPE} != binary ]]; then
-		if tc-is-gcc && [[ $(gcc-major-version) -lt 10 ]]; then
-			die "${PN} needs at least gcc 10"
-		elif tc-is-clang && [[ $(clang-major-version) -lt 12 ]]; then
-			die "${PN} needs at least clang 12"
-		fi
-	fi
-}
-
-src_prepare() {
-	default
-
-	# Needs unpackaged dwarfdump
-	rm test/elf/{compress-debug-sections,compressed-debug-info}.sh || die
-
-	# Sandbox sadness
-	rm test/elf/run.sh || die
-	sed -i 's|$mold-wrapper.so|"& ${LD_PRELOAD}"|' \
-		test/elf/mold-wrapper{,2}.sh || die
-
-	# static-pie tests require glibc built with static-pie support
-	if ! has_version -d 'sys-libs/glibc[static-pie(+)]'; then
-		rm test/elf/{hello,ifunc}-static-pie.sh || die
-	fi
-}
-
-src_compile() {
-	tc-export CC CXX
-
-	emake \
-		CFLAGS="${CFLAGS}" \
-		CXXFLAGS="${CXXFLAGS}" \
-		SYSTEM_TBB=1 \
-		SYSTEM_MIMALLOC=1 \
-		STRIP="true" \
-		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
-}
-
-src_test() {
-	emake \
-		SYSTEM_TBB=1 \
-		SYSTEM_MIMALLOC=1 \
-		check
-}
-
-src_install() {
-	emake \
-		SYSTEM_TBB=1 \
-		SYSTEM_MIMALLOC=1 \
-		DESTDIR="${D}" \
-		PREFIX="${EPREFIX}/usr" \
-		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
-		STRIP="true" \
-		install
-}