gentoo auto-resync : 06:08:2022 - 02:09:04

2 files changed, 79 insertions, 0 deletions

diff --git a/sys-devel/lld/Manifest b/sys-devel/lld/Manifest
index 6910a90ae92e..c0faa0299c74 100644
--- a/sys-devel/lld/Manifest
+++ b/sys-devel/lld/Manifest
@@ -4,4 +4,5 @@ DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69b
 EBUILD lld-13.0.1.ebuild 1871 BLAKE2B b6acf1ff04dd34f58e6113c318d1dfd991f60df2dbcbe02ebf2cad37be07cf676b36113fec0d8d6c3752eb98ec9a459dc214a0f28a4244dacfdaf8ff762ea405 SHA512 c3991a3e337477cbefadd221fa3ee640abe21b6fb51521051e387fb29314ca8f0d83dff5bd35f93e01b80e05823527d6b20c8223f86be9d0d879dba9fbe9d055
 EBUILD lld-14.0.6.ebuild 1883 BLAKE2B bd1e28b7f7717b51207b6a2bb7bda0bfd2003fb6e1b92cfb416be1bcdbc36445f8d2305b7144caaae69197446cdf863ab492e0061bc9b72f4d4440e30db2a17b SHA512 de39399cbb6bc8c60961f61fe47d22d7a7c85d8bf54aca86b60399b1d2a321d16875a19cf0aab6dc8a8786d81bd243ac57221c034edb090a2b6df424559371d7
 EBUILD lld-15.0.0.9999.ebuild 1846 BLAKE2B 8c305b9447a7fa1ae7388b62ad4f2e28c51438ed01304a39fe00683b28b2bbc84a549b6a9ea33fc0b1fe5f5974813fa8d8667b002346fa3d76bd1b709e23ec4f SHA512 3c2eb3b5c2764016c352809e9c466a67add7caffbad10f93961ec000e297a0a54789afcdbf3bbb83bb4b252231a5fe4b6208b9e4d787c1399df12a7e4e9f0540
+EBUILD lld-16.0.0.9999.ebuild 1846 BLAKE2B 8c305b9447a7fa1ae7388b62ad4f2e28c51438ed01304a39fe00683b28b2bbc84a549b6a9ea33fc0b1fe5f5974813fa8d8667b002346fa3d76bd1b709e23ec4f SHA512 3c2eb3b5c2764016c352809e9c466a67add7caffbad10f93961ec000e297a0a54789afcdbf3bbb83bb4b252231a5fe4b6208b9e4d787c1399df12a7e4e9f0540
 MISC metadata.xml 299 BLAKE2B 2feead2cd1b35b3a43335ddd7711f8181b52bc63ee7166608914260c67528add5251349063afbef4f8cf0ec09b2cd4c3ffdd90f2c14ed60bb69ebc03888f6333 SHA512 cd745c54ab18d25bdaff18582105072574103a36cfe7c175ef740f266d00e9fc6f44c332904d23b911c939cf5bdf52973b388923099d8dd5dfef3c283b5cb685
diff --git a/sys-devel/lld/lld-16.0.0.9999.ebuild b/sys-devel/lld/lld-16.0.0.9999.ebuild
new file mode 100644
index 000000000000..019425b4e1fa
--- /dev/null
+++ b/sys-devel/lld/lld-16.0.0.9999.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit cmake flag-o-matic llvm llvm.org python-any-r1
+
+DESCRIPTION="The LLVM linker (link editor)"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	~sys-devel/llvm-${PV}
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		>=dev-util/cmake-3.16
+		$(python_gen_any_dep "~dev-python/lit-${PV}[\${PYTHON_USEDEP}]")
+	)
+"
+
+LLVM_COMPONENTS=( lld cmake libunwind/include/mach-o )
+LLVM_TEST_COMPONENTS=( llvm/utils/{lit,unittest} )
+llvm.org_set_globals
+
+python_check_deps() {
+	has_version -b "dev-python/lit[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	use test && python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	llvm.org_src_unpack
+
+	# Directory ${WORKDIR}/llvm does not exist with USE="-test",
+	# but LLVM_MAIN_SRC_DIR="${WORKDIR}/llvm" is set below,
+	# and ${LLVM_MAIN_SRC_DIR}/../libunwind/include is used by build system
+	# (lld/MachO/CMakeLists.txt) and is expected to be resolvable
+	# to existent directory ${WORKDIR}/libunwind/include.
+	mkdir -p "${WORKDIR}/llvm" || die
+}
+
+src_configure() {
+	# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	use elibc_musl && append-ldflags -Wl,-z,stack-size=2097152
+
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DLLVM_INCLUDE_TESTS=$(usex test)
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=ON
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lld
+}