gentoo auto-resync : 22:08:2023 - 21:47:11

1 files changed, 43 insertions, 0 deletions

diff --git a/sys-devel/clang-crossdev-wrappers/clang-crossdev-wrappers-18.ebuild b/sys-devel/clang-crossdev-wrappers/clang-crossdev-wrappers-18.ebuild
new file mode 100644
index 000000000000..6cce67ad5210
--- /dev/null
+++ b/sys-devel/clang-crossdev-wrappers/clang-crossdev-wrappers-18.ebuild
@@ -0,0 +1,43 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit crossdev
+
+DESCRIPTION="Symlinks to a Clang crosscompiler"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:LLVM"
+SRC_URI=""
+S=${WORKDIR}
+
+LICENSE="public-domain"
+SLOT="${PV}"
+KEYWORDS=""
+PROPERTIES="live"
+
+RDEPEND="
+	sys-devel/clang:${SLOT}
+"
+
+src_install() {
+	local llvm_path="${EPREFIX}/usr/lib/llvm/${SLOT}"
+	into "${llvm_path}"
+
+	for exe in "clang" "clang++" "clang-cpp"; do
+		newbin - "${CTARGET}-${exe}" <<-EOF
+		#!/bin/sh
+		exec ${exe}-${SLOT} --no-default-config --config="/etc/clang/cross/${CTARGET}.cfg" \${@}
+		EOF
+	done
+
+	local tools=(
+		${CTARGET}-clang-${SLOT}:${CTARGET}-clang
+		${CTARGET}-clang-cpp-${SLOT}:${CTARGET}-clang-cpp
+		${CTARGET}-clang++-${SLOT}:${CTARGET}-clang++
+	)
+
+	local t
+	for t in "${tools[@]}"; do
+		dosym "${t#*:}" "${llvm_path}/bin/${t%:*}"
+	done
+}