reinit the tree, so we can have metadata

1 files changed, 51 insertions, 0 deletions

diff --git a/sys-cluster/libqb/libqb-1.0.1.ebuild b/sys-cluster/libqb/libqb-1.0.1.ebuild
new file mode 100644
index 000000000000..748d05368bf3
--- /dev/null
+++ b/sys-cluster/libqb/libqb-1.0.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+
+inherit autotools-utils
+
+DESCRIPTION="Library providing high performance logging, tracing, ipc, and poll"
+HOMEPAGE="https://github.com/ClusterLabs/libqb"
+SRC_URI="https://github.com/ClusterLabs/${PN}/releases/download/v${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="debug doc examples static-libs test"
+
+RDEPEND="dev-libs/glib:2"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	test? ( dev-libs/check )
+	doc? ( app-doc/doxygen[dot] )"
+
+DOCS=(README.markdown ChangeLog)
+
+src_prepare() {
+	sed -e '/dist_doc_DATA/d' -i Makefile.am || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_enable debug)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	autotools-utils_src_compile
+	use doc && autotools-utils_src_compile doxygen
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${AUTOTOOLS_BUILD_DIR}/docs/html/")
+	autotools-utils_src_install
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.c
+	fi
+}