gentoo resync : 05.02.2020

2 files changed, 148 insertions, 0 deletions

diff --git a/sys-block/fio/Manifest b/sys-block/fio/Manifest
index b9a592337a33..8a11fee5c57c 100644
--- a/sys-block/fio/Manifest
+++ b/sys-block/fio/Manifest
@@ -12,6 +12,7 @@ EBUILD fio-2.15.ebuild 2693 BLAKE2B 302c54d0b33a6b4a14e1a19ff8cb1848438d87a27328
 EBUILD fio-2.16.ebuild 2907 BLAKE2B b524791f0ecea03ae3a17994295224963fb9eb10b2b339f4dbdcbb546fbafd24cf905777817878cecd22df2158f84ed1ddfc6d311909ca569bd5ef91da0f1218 SHA512 ae8bd404cddedd37a41729e1ec570df997dd9b4484daa9e77a75c4887ee0bb26d5cffbb015fd1e154103d276f2db11486bb49d09b8dbc897f3d5ba5865fb1559
 EBUILD fio-3.16-r1.ebuild 3597 BLAKE2B bf428d5695302fc3014dc0708b17c1457ec5f2bc54785f66acd54c7737ce9678fc98d96fb18784a4c8934b7a5964342493e24c98f2df116412e4acefe0658180 SHA512 b1ce7d1e31dcd2f1f2368d76459870ff1b157c3e311adfab62553105209cbea16a898b4e5ba53216eb97dedfa7b72409e072252d1931c702cc5d9ad255745aec
 EBUILD fio-3.16.ebuild 3546 BLAKE2B 95eb92a3c0e390bd9a1b4c7e02a0025031d1d3f203df1a03813e40db7f4a9550847ca36bd6b11c9aaa82b9e29afd3368ec039d1d96f1017611f965abb3462d3a SHA512 090fa98cad51a50de4120a9c61bba262fe26564dae5075d010b18d1a72f722db0a3c7630c212a2c54f5d07c8d2bb21d380268796b98e1054ca1721c2c7a5b9a7
+EBUILD fio-3.17-r1.ebuild 3954 BLAKE2B 07679b26b26d69613f78e30f26675cbfc55a96afb4091df1805828d3622cc5635332d7eb47c71ee0d8aa2d43197f333c0bb4d58a85eaf55061f7512e91bd42ec SHA512 2ab44da6d7c1fea4360ee4688302a5e3f823e0f1341168fbd35ba1942b7d225e1bfc745e09bfe8a0bd9ecd34dc340e23a2cf3fe7233872ea1c4d940af5aefba0
 EBUILD fio-3.17.ebuild 3558 BLAKE2B f99a7063106935000160b8402bdd6eb5ce06235364b68ffb05aa344fcfc73f695fdb4e5d305babb0899e1416f74703f3eb5f5efc8d75553305be0d2f0547429a SHA512 2219b427895295e6c4c5914c3eaf6c2fe71f2f1330196fc0debeef598d4d88006011172227d24a8798544ec41561ef8919663431746f05f782d115ebfbb9132b
 EBUILD fio-3.2.ebuild 2855 BLAKE2B 9496bc95ff5ad4511285897285904b352e8e5e1ba547f8eed4932bece1b98f229c7677405c3f6af7e6948ab710e13d79612b94d9442f8371f63cd2a15003b9c6 SHA512 72db1a54e4e876142a7e4c1b16fa467fc0024a1d67eda20a77c97a9685833a03d5a0acaa54b07e0e62e3e12ebd128d2e49ccd58e36758f70c62ca9df25d09bd1
 EBUILD fio-3.7.ebuild 3006 BLAKE2B 0803b0f384761f77702d0e844767152c2f23f76291a3685bc2364d2a7dd2b781ea2170ec0da781ed4017c4821953b6d7a5ff7abfd1beac65687de2487a240724 SHA512 bc261cda042724608ec4e89e5b16bd96799d3ca72e87e19d32f3d95e30f6ca36f7d5e1ece54a125aaea7ddad49a59ae96b7ef52e5177fd158b5f934a15590b91
diff --git a/sys-block/fio/fio-3.17-r1.ebuild b/sys-block/fio/fio-3.17-r1.ebuild
new file mode 100644
index 000000000000..87a629536db1
--- /dev/null
+++ b/sys-block/fio/fio-3.17-r1.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python2_7 python3_6 )
+
+inherit python-r1 toolchain-funcs
+
+MY_PV="${PV/_rc/-rc}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="Jens Axboe's Flexible IO tester"
+HOMEPAGE="https://brick.kernel.dk/snaps/"
+SRC_URI="https://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="aio curl glusterfs gnuplot gtk libressl numa python rbd rdma static tcmalloc zlib"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
+	libressl? ( curl )
+	gnuplot? ( python )"
+
+BDEPEND="virtual/pkgconfig"
+
+# GTK+:2 does not offer static libaries.
+LIB_DEPEND="aio? ( dev-libs/libaio[static-libs(+)] )
+	curl? (
+		net-misc/curl:=[static-libs(+)]
+		!libressl? ( dev-libs/openssl:0=[static-libs(+)] )
+		libressl? ( dev-libs/libressl:0=[static-libs(+)] )
+	)
+	glusterfs? ( sys-cluster/glusterfs[static-libs(+)] )
+	gtk? ( dev-libs/glib:2[static-libs(+)] )
+	numa? ( sys-process/numactl[static-libs(+)] )
+	rbd? ( sys-cluster/ceph[static-libs(+)] )
+	rdma? (
+		sys-fabric/libibverbs[static-libs(+)]
+		sys-fabric/librdmacm[static-libs(+)]
+	)
+	tcmalloc? ( dev-util/google-perftools:=[static-libs(+)] )
+	zlib? ( sys-libs/zlib[static-libs(+)] )"
+RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
+	gtk? ( x11-libs/gtk+:2 )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND} )"
+RDEPEND+="
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/pandas[${PYTHON_USEDEP}]')
+	)
+	gnuplot? ( sci-visualization/gnuplot )"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}"/fio-2.2.13-libmtd.patch
+	"${FILESDIR}"/fio-3.16-verify_only_numberio.patch
+)
+
+python_check_deps() {
+	has_version "dev-python/pandas[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+
+	sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
+
+	# Many checks don't have configure flags.
+	sed -i \
+		-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
+		-e '/if compile_prog "" "-lz" "zlib" *; *then/  '"s::if $(usex zlib true false) ; then:" \
+		-e '/if compile_prog "" "-laio" "libaio" ; then/'"s::if $(usex aio true false) ; then:" \
+		configure || die
+}
+
+src_configure() {
+	chmod g-w "${T}"
+	# not a real configure script
+	# TODO: pmem
+	set -- \
+	./configure \
+		--disable-optimizations \
+		--extra-cflags="${CFLAGS} ${CPPFLAGS}" \
+		--cc="$(tc-getCC)" \
+		--disable-pmem \
+		$(usex curl '' '--disable-http') \
+		$(usex glusterfs '' '--disable-gfapi') \
+		$(usex gtk '--enable-gfio' '') \
+		$(usex numa '' '--disable-numa') \
+		$(usex rbd '' '--disable-rbd') \
+		$(usex rdma '' '--disable-rdma') \
+		$(usex static '--build-static' '') \
+		$(usex tcmalloc '' '--disable-tcmalloc')
+	echo "$@"
+	"$@" || die 'configure failed'
+}
+
+src_compile() {
+	emake V=1 OPTFLAGS=
+}
+
+src_install() {
+	emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
+
+	local python2_7_files=(
+		"${ED}"/usr/bin/fiologparser_hist.py
+		"${ED}"/usr/bin/fiologparser.py
+	)
+	local python_files=(
+		"${python2_7_files[@]}"
+		"${ED}"/usr/bin/fio_jsonplus_clat2csv
+	)
+	if use python ; then
+		sed -i 's:python2.7:python:g' "${python2_7_files[@]}" || die
+		python_replicate_script "${python2_7_files[@]}"
+	else
+		rm "${python_files[@]}" || die
+	fi
+
+	local gnuplot_python2_7_files=(
+		"${ED}"/usr/bin/fio2gnuplot
+	)
+	local gnuplot_files=(
+		"${gnuplot_python2_7_files[@]}"
+		"${ED}"/usr/bin/fio_generate_plots
+		"${ED}"/usr/share/man/man1/fio_generate_plots.1
+		"${ED}"/usr/share/man/man1/fio2gnuplot.1
+		"${ED}"/usr/share/fio/*.gpm
+	)
+	if use gnuplot ; then
+		sed -i 's:python2.7:python:g' "${gnuplot_python2_7_files[@]}" || die
+		python_replicate_script "${gnuplot_python2_7_files[@]}"
+	else
+		rm "${gnuplot_files[@]}" || die
+		rmdir "${ED}"/usr/share/fio/ || die
+	fi
+
+	# This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
+	rm "${ED}"/usr/bin/genfio || die
+
+	dodoc README REPORTING-BUGS HOWTO
+	docinto examples
+	dodoc examples/*
+}