gentoo resync : 22.06.2019

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-apps/s6-rc/s6-rc-0.5.0.0.ebuild b/sys-apps/s6-rc/s6-rc-0.5.0.0.ebuild
new file mode 100644
index 000000000000..6830fe022a56
--- /dev/null
+++ b/sys-apps/s6-rc/s6-rc-0.5.0.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Service manager for the s6 supervision suite"
+HOMEPAGE="https://www.skarnet.org/software/s6-rc/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="static static-libs"
+
+REQUIRED_USE="static? ( static-libs )"
+
+RDEPEND=">=dev-lang/execline-2.5.1.0:=[static-libs?]
+	>=dev-libs/skalibs-2.8.0.0:=[static-libs?]
+	>=sys-apps/s6-2.8.0.0:=[static-libs?]
+"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition; avoid overriding -fstack-protector
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' -e '/-fno-stack-protector$/d' \
+		configure || die
+}
+
+src_configure() {
+	econf \
+		--bindir=/bin \
+		--dynlibdir=/usr/$(get_libdir) \
+		--libdir=/usr/$(get_libdir)/${PN} \
+		--with-dynlib=/usr/$(get_libdir) \
+		--with-lib=/usr/$(get_libdir)/execline \
+		--with-lib=/usr/$(get_libdir)/s6 \
+		--with-lib=/usr/$(get_libdir)/skalibs \
+		--with-sysdeps=/usr/$(get_libdir)/skalibs \
+		--enable-shared \
+		$(use_enable static allstatic) \
+		$(use_enable static static-libc) \
+		$(use_enable static-libs static)
+}
+
+pkg_postinst() {
+	ewarn "Databases from ${PN}-0.3.0.0 or earlier must be manually upgraded!"
+	ewarn "See the upgrade notes at ${EROOT}/usr/share/doc/${PF}/html/upgrade.html"
+	ewarn "and the documentation for the s6-rc-format-upgrade utility."
+}