gentoo auto-resync : 28:10:2022 - 22:00:04

3 files changed, 234 insertions, 0 deletions

diff --git a/sci-visualization/Manifest.gz b/sci-visualization/Manifest.gz
index e80a5322e7db..96131a03e0bd 100644
--- a/sci-visualization/Manifest.gz
+++ b/sci-visualization/Manifest.gz
diff --git a/sci-visualization/paraview/Manifest b/sci-visualization/paraview/Manifest
index ee3e7441d246..b242f2c0dc25 100644
--- a/sci-visualization/paraview/Manifest
+++ b/sci-visualization/paraview/Manifest
@@ -1,6 +1,8 @@
 AUX paraview-5.5.0-allow_custom_build_type.patch 1036 BLAKE2B ff00093034196935e9075c5751f8a64027da009679de5c3f5b941681e65df9b91b0a05a3f0201a873313d859f029596739b1c5d705a1c35ae3cc83251312774e SHA512 0c79315d28b98d4cf45bfd48198dbb3315ebf6ffbd05e9720b35e7bdea05bd98c086dbb02cd7ac6d9580f504c7d29f498244d2b30d9e2932e881261a78b020c7
 DIST ParaView-v5.10.1.tar.xz 70218088 BLAKE2B 3134c5df35994a3a153ebd97770066b9963911ae7fb1877681135e01a19c4a879306ae844ef3a29719be5cd509f35117f74eb3c264f1a101fa19180d9a126011 SHA512 1feb855432ea7bc40f77ee214e5877d5170e4f31f520dc7198d72a271506b65a4bc79922875d2c176e54219818a428497c606390a2b9da2770de403bd1593e6c
 DIST ParaView-v5.11.0-RC1.tar.xz 80100552 BLAKE2B 16968e643c8436f9b9c1b5356b42175904fdb8dbc88685420fa7bb6f94833661f0ec03eb4183cabc67348ba11afcbf50c62f18a38929133ac21a5492b0971c5d SHA512 d948b9ee91bb2c3b657ba22103dfed4ce92798266fdfd5aaf596225fb6f0859ecb636145c932ac5fefc64763cfa98ebeef639453b2c7cb73dda82741b6e52478
+DIST ParaView-v5.11.0-RC2.tar.xz 79802928 BLAKE2B 5aefec385f479bfd4709175dce7c98528532068ba576f1f256fe86612f5119576318c4ef73f71e4d0f55c43d4a39ccda2773ec7fd3461acc41a0b9399f4c16fa SHA512 3bbc73d7e6fdd55adc29bdd05caf78d6db1fbd3f295ce63c2c60fa4870880fe4c8534ab5c1ae7cc8748f874b2ffca15cff38bcca2392d14e95ba81fcb9b8a9e5
 EBUILD paraview-5.10.1-r2.ebuild 5699 BLAKE2B e0e4aa3e4903b4c15e7a5d2e0ed1dbb19378e778f76c37ac3ee27f881227e68d55c9013f3b9866613144f19fb7c0f58756d8e891323cdb8ead32ed74fc878e34 SHA512 bc76f88c2e1a220ee4dc9195fd9257312a13877106bfed7b54000889ed6af9498d5e013f712dfd76fe8b61da1be818dc8a8e209e7e490e7518339ef1989f8002
 EBUILD paraview-5.11.0_rc1.ebuild 5805 BLAKE2B 84efe0320c0e4b26020e8c97d4766d62c2f0bf1467d836713785840fb0cf6d248d4dcbc2d33f88535699f8a67c567198f31fd22f56989ae9c7dc778a71f14e92 SHA512 859b39c2145b9b938237edfb674e009ed2887dd39c9c723eef3b02a8c187b642a638c8a8f6fe8e8a620b6a3c6b8fd4bd4b36a3ab6a774a5ee40d411358465196
+EBUILD paraview-5.11.0_rc2.ebuild 5805 BLAKE2B b23d1d12106e7c95cc9b964d1b768df1d5f1453de6e980a888d229999300381f08f843a9f96447611a4ab0175bff3d20352e373feff37bf912540c468e0d1941 SHA512 ef105d87003521bd8bae305c24d32e3a03bb02099392e0d8ffcbafed15c0791e2fb492f86db3fc2ea6e15a0fd8dc5283aab443ff1b8c5f22acc5610eb9e086e0
 MISC metadata.xml 683 BLAKE2B 28b4017609ac733ac1c1ff4cb4ac3b5341f72180f487542b9db3b8bee59357ac9fed25bc0287a2f8c93f7429d098d1b26c74741b86b943564a4caafd7ee8450e SHA512 0bd4a1c8331532529d405f36c4556f57caecc299ceddd4ca8ff23138d96bd450c1d4fade7f02edddd8f9b3062d6b31bcb9a7696b2b628494c1d1b60d0312bc91
diff --git a/sci-visualization/paraview/paraview-5.11.0_rc2.ebuild b/sci-visualization/paraview/paraview-5.11.0_rc2.ebuild
new file mode 100644
index 000000000000..702e265d4b09
--- /dev/null
+++ b/sci-visualization/paraview/paraview-5.11.0_rc2.ebuild
@@ -0,0 +1,232 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Python3.11 does not have longintrepr.h causing compile failure
+PYTHON_COMPAT=( python3_{8..10} )
+DOCS_BUILDER="doxygen"
+inherit cmake desktop docs python-single-r1 qmake-utils toolchain-funcs xdg
+
+MAIN_PV=$(ver_cut 0-1)
+MAJOR_PV=$(ver_cut 1-2)
+MY_PN="ParaView"
+MY_PV="${PV//_rc2}-RC2"
+
+DESCRIPTION="Powerful scientific data visualization application"
+HOMEPAGE="https://www.paraview.org"
+SRC_URI="https://www.paraview.org/files/v${MAJOR_PV}/${MY_PN}-v${MY_PV}.tar.xz"
+S="${WORKDIR}/${MY_PN}-v${MY_PV}"
+
+# TODO: check licenses of plugins (USE=plugins)
+LICENSE="BSD MIT PSF-2 VTK"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost cg examples ffmpeg mpi nvcontrol openmp offscreen plugins python +qt5 +sqlite test tk +webengine"
+
+RESTRICT="mirror test"
+
+REQUIRED_USE="
+	python? ( mpi ${PYTHON_REQUIRED_USE} )
+	webengine? ( qt5 )
+	qt5? ( sqlite )
+	?? ( offscreen qt5 )"
+
+# TODO: Verify that these two are not needed any more for the catalyst
+# module:
+#  - dev-python/PyQt5
+#  - dev-qt/qtgui:5[-gles2-only]
+RDEPEND="
+	app-arch/lz4
+	dev-libs/expat
+	dev-libs/jsoncpp:=
+	dev-libs/libxml2:2
+	dev-libs/protobuf:=
+	dev-libs/pugixml
+	media-libs/freetype
+	media-libs/glew:0
+	media-libs/libpng:0
+	media-libs/libtheora
+	media-libs/tiff:0=
+	sci-libs/cgnslib
+	sci-libs/hdf5:=[mpi=]
+	>=sci-libs/netcdf-4.2[hdf5]
+	>=sci-libs/netcdf-cxx-4.2:3
+	sys-libs/zlib
+	virtual/glu
+	media-libs/libjpeg-turbo:=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXt
+	ffmpeg? ( media-video/ffmpeg )
+	mpi? ( virtual/mpi[cxx,romio] )
+	offscreen? ( >=media-libs/mesa-18.3.6[osmesa] )
+	!offscreen? ( virtual/opengl )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/constantly[${PYTHON_USEDEP}]
+			dev-python/incremental[${PYTHON_USEDEP}]
+			dev-python/matplotlib[${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sip:5[${PYTHON_USEDEP}]
+			dev-python/six[${PYTHON_USEDEP}]
+			dev-python/twisted[${PYTHON_USEDEP}]
+			dev-python/zope-interface[${PYTHON_USEDEP}]
+			mpi? ( dev-python/mpi4py )
+			qt5? ( dev-python/PyQt5[opengl,${PYTHON_USEDEP}] )
+		')
+	)
+	qt5? (
+		dev-qt/designer:5
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qthelp:5
+		dev-qt/qtopengl:5[-gles2-only]
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qttest:5
+		dev-qt/qtx11extras:5
+		dev-qt/qtxmlpatterns:5
+	)
+	sqlite? ( dev-db/sqlite:3 )
+	tk? ( dev-lang/tk:0= )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	boost? (
+		$(python_gen_cond_dep '
+			dev-libs/boost[mpi?,python,${PYTHON_USEDEP}]
+		')
+	)
+"
+
+BDEPEND="
+	openmp? ( virtual/fortran )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.5.0-allow_custom_build_type.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	use python && python-single-r1_pkg_setup
+	PVLIBDIR=$(get_libdir)/${PN}-${MAJOR_PV}
+}
+
+src_prepare() {
+	# Bug #661812
+	mkdir -p Plugins/StreamLinesRepresentation/doc || die
+
+	cmake_src_prepare
+
+	# lib64 fixes
+	sed -i \
+		-e "s:/lib/python:/$(get_libdir)/python:g" \
+		VTK/ThirdParty/xdmf3/vtkxdmf3/CMakeLists.txt || die
+	sed -i \
+		-e "s:lib/paraview-:$(get_libdir)/paraview-:g" \
+		Remoting/Application/vtkInitializationHelper.cxx || die
+}
+
+src_configure() {
+	# Make sure qmlplugindump is in path:
+	export PATH="$(qt5_get_bindir):${PATH}"
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="${PVLIBDIR}"
+		-UBUILD_SHARED_LIBS
+		-DPARAVIEW_BUILD_SHARED_LIBS=ON
+		-DCMAKE_VERBOSE_MAKEFILE=ON
+
+		# boost
+		-DVTK_MODULE_ENABLE_VTK_IOInfovis="$(usex boost YES NO)"
+
+		# doc
+		-DPARAVIEW_BUILD_DEVELOPER_DOCUMENTATION="$(usex doc)"
+
+		# examples
+		-DBUILD_EXAMPLES="$(usex examples)"
+
+		# ffmpeg
+		-DPARAVIEW_ENABLE_FFMPEG="$(usex ffmpeg)"
+
+		# mpi
+		-DPARAVIEW_USE_MPI="$(usex mpi)"
+		-DXDMF_BUILD_MPI="$(usex mpi)"
+		-DVTK_GROUP_ENABLE_MPI="$(usex mpi YES NO)"
+
+		# offscreen
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+
+		# plugins
+		-DPARAVIEW_PLUGINS_DEFAULT="$(usex plugins)"
+
+		# python
+		-DModule_pqPython="$(usex python)"
+		-DPARAVIEW_USE_PYTHON="$(usex python)"
+
+		# qt5
+		-DPARAVIEW_USE_QT="$(usex qt5)"
+		-DModule_pqPython="$(usex qt5 "$(usex python)" "off")"
+		-DVTK_USE_NVCONTROL="$(usex nvcontrol)"
+		-DVTK_GROUP_ENABLE_Qt="$(usex qt5 YES NO)"
+		-DCMAKE_INSTALL_QMLDIR="${EPREFIX}/usr/$(get_libdir)/qt5/qml"
+
+		# sqlite
+		-DVTK_MODULE_ENABLE_VTK_sqlite="$(usex sqlite YES NO)"
+
+		# test
+		-DBUILD_TESTING="$(usex test)"
+
+		# tk
+		-DVTK_USE_TK="$(usex tk)"
+		-DVTK_GROUP_ENABLE_Tk="$(usex tk YES NO)"
+
+		# webengine
+		-DPARAVIEW_USE_QTWEBENGINE="$(usex webengine)"
+		-DVTK_GROUP_ENABLE_Web="$(usex webengine YES NO)"
+	)
+
+	if use openmp; then
+		mycmakeargs+=( -DVTK_SMP_IMPLEMENTATION_TYPE=OpenMP )
+	fi
+
+	if use qt5; then
+		mycmakeargs+=(
+			-DOPENGL_gl_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGL.so
+			-DOPENGL_glu_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGLU.so
+			-DQT_MOC_EXECUTABLE="$(qt5_get_bindir)/moc"
+			-Dqt_xmlpatterns_executable="$(qt5_get_bindir)/xmlpatterns"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove wrapper binaries and put the actual executable in place
+	for i in {paraview-config,pvserver,pvdataserver,pvrenderserver,pvbatch,pvpython,paraview}; do
+		if [ -f "${ED}"/usr/lib/"$i" ]; then
+			mv "${ED}"/usr/lib/"$i" "${ED}"/usr/bin/"$i" || die
+		fi
+	done
+
+	# set up the environment
+	echo "LDPATH=${EPREFIX}/usr/${PVLIBDIR}" > "${T}"/40${PN} || die
+	doenvd "${T}"/40${PN}
+
+	newicon "${S}"/Clients/ParaView/pvIcon-96x96.png paraview.png
+	make_desktop_entry paraview "Paraview" paraview
+
+	use python && python_optimize "${ED}/usr/$(get_libdir)/${PN}-${MAJOR_PV}"
+}