gentoo resync : 15.06.2021

1 files changed, 39 insertions, 0 deletions

diff --git a/sci-physics/yoda/yoda-1.9.0.ebuild b/sci-physics/yoda/yoda-1.9.0.ebuild
new file mode 100644
index 000000000000..eccb09af10af
--- /dev/null
+++ b/sci-physics/yoda/yoda-1.9.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit bash-completion-r1
+
+DESCRIPTION="Yet more Objects for (High Energy Physics) Data Analysis"
+HOMEPAGE="https://yoda.hepforge.org/"
+SRC_URI="https://yoda.hepforge.org/downloads?f=${P^^}.tar.bz2 -> ${P^^}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="root"
+
+RDEPEND="root? ( sci-physics/root:= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${P^^}"
+
+src_configure() {
+	econf \
+		--disable-pyext \
+		--disable-static \
+		$(use_enable root)
+}
+
+src_test() {
+	# PYTESTS and SHTESTS both require python tools
+	emake check PYTESTS= SHTESTS=
+}
+
+src_install() {
+	default
+
+	newbashcomp "${ED}"/etc/bash_completion.d/yoda-completion yoda
+	rm "${ED}"/etc/bash_completion.d/yoda-completion || die
+}