reinit the tree, so we can have metadata

6 files changed, 230 insertions, 0 deletions

diff --git a/sci-libs/lrslib/Manifest b/sci-libs/lrslib/Manifest
new file mode 100644
index 000000000000..f937669f0b93
--- /dev/null
+++ b/sci-libs/lrslib/Manifest
@@ -0,0 +1,10 @@
+DIST lrslib-042c.tar.gz 168765 SHA256 53f99b5271397bb5f317c96fa365edc1ac71fa7cba0295c8bd79e0882f5c3a4a SHA512 a5fdd65b2c4e4cadd5fb9679e0e94ddc6b3564cdb9bdfcb7304351fec943527d2dccf117148d8d418ad8bd4577c9f69dabd6ca07107c1c1555c8c6d17f38fa60 WHIRLPOOL 4c3c1d5a72f8ac91e3d6698a8409578f5c0a940562704adea6631e5f9fb738a24414806a4d4b3aedf4e32de49a8c09ec74058baef61e121ce54db7ef5d2f5c01
+DIST lrslib-051.tar.gz 179396 SHA256 500893df61631944bac14a76c6e13fc08e6e729727443fa5480b2510de0db635 SHA512 65e4752ae75f06bccb74b0e12e0b03943654cba048d54dbcf93a36bea7f73b32826babe066d5fe20d3c6609548dc957063558633affe64d795c240c1fe748927 WHIRLPOOL 54877f0432fef43989b5d7591cef6692dbb555fb0ccb8a634b82eefb06a20d478bbb1a62b2ef241c8cda74328da29bcbcdcf8031640d1e0455a1e57bf839125e
+DIST lrslib-062.tar.gz 292745 SHA256 adf92f9c7e70c001340b9c28f414208d49c581df46b550f56ab9a360348e4f09 SHA512 1d644a7798580457ff266730f42f6fac317ec8cdf2509ad6028e7a838e5c4c948bd0f9499b840c227bad4269f7144ff72b87fe3a19bdb9ad0925ebe4a7bc4f9f WHIRLPOOL b1deb2df5f0dc73112e94c85789ef68056c6f62de2a6681f28efde65b4cec1c3d20fa93943fbdb70d458d706872ef04744ba8a1f322a33cd14c7ac570b259037
+EBUILD lrslib-042c-r1.ebuild 1161 SHA256 00b7ff7ffaa49c2a3281c098bfea356059af28db7ba0b558ed54e95a95809e59 SHA512 f90699a8429b03b524ab66b0cb7496d4fff367cc46c6be87d9db2430f445f198082df1f67d7f045926c69b9f7b85dd05d2078e81cb03fbc81d1ebf480d337da0 WHIRLPOOL b0669ddc68101230adb4c7c09b97e060dd705b23650ef299762b3e96b08386aa778a6228fee5cd9dc76c9ef6e197bb34c9e4ed9400c9c79f9bd18bf5656e3f90
+EBUILD lrslib-042c-r2.ebuild 1312 SHA256 c42c9a66805a8a8135098a4bf36d077f0f5ce7709e7aab8d4e754e72ae83156b SHA512 3d9dc22227f77784303922d1fb693ddd7ccd8b588743b2270243c584f1dbac97b633cab7bc4fcd5c2176fd4c6d29841f6a6eec589e8fbdf6f4420fb284bc9b79 WHIRLPOOL 6d16bc4be234a27ecdf4cfc6ab0ccf703ad30d1dddcfe030ac1871896300ea0eb5b06156aa43bfddcafc1bc177e0147052124c12caddbebef8c859939c3f5c1a
+EBUILD lrslib-051.ebuild 915 SHA256 f0c2d0ce4f375cc1b7782258e5e7148392db5e5cd82f01d66795f973bf86a415 SHA512 f557d6681656fa4bc6243a88575f3ae14eb5b6264e8c409b898cc23423eb80107cc311a5ad01cb4338f87dc059a96536b23bf0b0e6cb4981014383310aea00e2 WHIRLPOOL 1fcdf7b903bde69d0f581cf4f0c0958650bc11e94900840fd5a41d9ac3f7f09cd5a56c0a15d12ff1eb415396dca26940d0ab81d1ffc5101ee78e759420f39701
+EBUILD lrslib-062.ebuild 1114 SHA256 27b0c903bf6baea7e15e1029d3e733d7a223a72e69c540af10c2767b02f5cd2e SHA512 6e29d90108ae11e1cc5143406ecb7636277395fa3ebfbaa02eb8cd11e5f2f5a0f43877a75e52bbfddc5ea6104f4524b87daa8f092bfa02a20f13733d38d2492e WHIRLPOOL c2a72fad56e8ac3daf7590dc3afbbdd0b628b58a81262872ce0d80ab656f2dff46fac04c242b508220d28304280176cd1527ac8e9aa2980e08407745c427fcd3
+MISC ChangeLog 2823 SHA256 b64e0cc4d29f7f5f08751cca9bba35a162db598535fc14cee476b3c9a9183ce8 SHA512 e4979b5357897481c518f36e064f0e1a65822859d3ded43d79d5cc31000ab3169b906713568207fa71f6a6208868c38fb98a082d516506d5a1fa67cf2eef1952 WHIRLPOOL 1f59232f49c72a7a40a567f07765c9be136d0bc4fbee7b224bdca86473eda26db7aeb1a1b1f67b524faf617ee9bad0b14df422f63ededf90d1e211aa571d93f6
+MISC ChangeLog-2015 1441 SHA256 cf5273648fd0f2b72e658844390620a12492c32b61919ac08a014b4c2dff05b7 SHA512 c37d9d788ae3e6c5ccf950aaacea9e99f52cdd67f9e97a6e7cb83fc1c9008fecdb9223727148d06518b0559359711a32933a243394c4f78c8f5ce58fce1579ca WHIRLPOOL bcf17d2ea299e1eefd6453999016f58a7f456772cc8c8139bafb7d5a98ebcf55448d94c67cbcfbc983512db478c36760d0cc46089914fefa1d365c1a1bff8f81
+MISC metadata.xml 769 SHA256 ded5d63425a5d6d1c6ed779ecb6ccf188696b83acc84963a9eb89a6b876b83eb SHA512 f604771858909c1fb3f4f4c47094e9d6b16c1294575026246008c927a4d99aae6a2bdad45d66fe87c8be68b5a5a23f6fdfa72ec26a00a2a48a2ae7fe64cfb57d WHIRLPOOL 156fe5114dab6874996b335e0554b77b6a58fea612cc24366794089b6d41cbc8b6a4464f6b30291547d6eef9b956a2472865ba6764ffa40aaa6a05e0148a7829
diff --git a/sci-libs/lrslib/lrslib-042c-r1.ebuild b/sci-libs/lrslib/lrslib-042c-r1.ebuild
new file mode 100644
index 000000000000..b1fba3a5f344
--- /dev/null
+++ b/sci-libs/lrslib/lrslib-042c-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=2
+
+inherit toolchain-funcs
+
+DESCRIPTION="self-contained ANSI C implementation of the reverse search algorithm"
+HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
+SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="gmp"
+
+DEPEND="gmp? ( dev-libs/gmp )"
+RDEPEND="${DEPEND}"
+
+src_prepare(){
+	sed -i "s/gcc/$(tc-getCC)/g" makefile || die
+	sed -i "s/-O3/${CFLAGS} ${LDFLAGS}/g" makefile || die
+}
+
+src_compile () {
+	if use amd64 ; then
+		emake all64 || die "make failed"
+	else
+		emake || die "make failed"
+	fi
+	if use gmp ; then
+		emake gmp || die "make failed"
+	fi
+}
+
+src_install() {
+	dobin lrs redund redund1 || die
+	# Collides with sys-block/buffer
+	newbin buffer lrsbuffer || die
+	if use x86; then
+		dobin nash setupnash setupnash2 2nash || die
+		# Prevent clash with cddlib:
+		newbin fourier lrsfourier || die
+	fi
+	if use gmp; then
+		dobin glrs gredund gfourier || die
+		# Clash with www-plugins/gnash
+		newbin gnash lrsgnash || die
+	fi
+	dodoc readme || die
+	dohtml lrslib.html || die
+}
diff --git a/sci-libs/lrslib/lrslib-042c-r2.ebuild b/sci-libs/lrslib/lrslib-042c-r2.ebuild
new file mode 100644
index 000000000000..8fafdff0cba2
--- /dev/null
+++ b/sci-libs/lrslib/lrslib-042c-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=4
+
+inherit toolchain-funcs
+
+DESCRIPTION="self-contained ANSI C implementation of the reverse search algorithm"
+HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
+SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="gmp"
+
+DEPEND="gmp? ( dev-libs/gmp )"
+RDEPEND="${DEPEND}"
+
+src_prepare(){
+	sed -i "s/gcc/$(tc-getCC)/g" makefile || die
+	sed -i "s/-O3/${CFLAGS} ${LDFLAGS}/g" makefile || die
+	# We don't like static linking to gmp or anywhere.
+	if use amd64 ; then
+		# This macro may only change messages that the
+		# binary outputs, but just in case... (Bug 384195)
+		sed -i "s/-static/-DB64/g" makefile || die
+	else
+		sed -i "s/-static//g" makefile || die
+	fi
+}
+
+src_compile () {
+	if use amd64 ; then
+		emake all64
+	else
+		emake
+	fi
+	if use gmp ; then
+		emake gmp
+	fi
+}
+
+src_install() {
+	dobin lrs redund redund1
+	# Collides with sys-block/buffer
+	newbin buffer lrsbuffer
+	if use x86; then
+		dobin nash setupnash setupnash2 2nash
+		# Prevent clash with cddlib:
+		newbin fourier lrsfourier
+	fi
+	if use gmp; then
+		dobin glrs gredund gfourier
+		# Clash with www-plugins/gnash
+		newbin gnash lrsgnash
+	fi
+	dodoc readme
+	dohtml lrslib.html
+}
diff --git a/sci-libs/lrslib/lrslib-051.ebuild b/sci-libs/lrslib/lrslib-051.ebuild
new file mode 100644
index 000000000000..8c8e791b7941
--- /dev/null
+++ b/sci-libs/lrslib/lrslib-051.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+inherit toolchain-funcs
+
+DESCRIPTION="self-contained ANSI C implementation of the reverse search algorithm"
+HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
+SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="gmp"
+
+DEPEND="gmp? ( dev-libs/gmp:0= )"
+RDEPEND="${DEPEND}"
+
+src_prepare(){
+	sed -i "s/gcc/$(tc-getCC)/g" makefile || die
+	sed -i "s/-O3/${CFLAGS} ${LDFLAGS}/g" makefile || die
+	# Prefix for install
+	sed -i "s,/usr/local,/usr,g" makefile || die
+}
+
+src_compile () {
+	if use gmp ; then
+		emake all
+		emake all-shared
+	else
+		emake allmp
+	fi
+}
+
+src_install() {
+	dodoc readme
+	# Library
+	if use gmp ; then
+		emake DESTDIR="${D}" install-shared
+	fi
+	# Install default set of binaries
+	emake DESTDIR="${D}" install-common
+}
diff --git a/sci-libs/lrslib/lrslib-062.ebuild b/sci-libs/lrslib/lrslib-062.ebuild
new file mode 100644
index 000000000000..1df9b43c7019
--- /dev/null
+++ b/sci-libs/lrslib/lrslib-062.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs eutils
+
+DESCRIPTION="Self-contained C implementation of the reverse search algorithm"
+HOMEPAGE="http://cgm.cs.mcgill.ca/~avis/C/lrs.html"
+SRC_URI="http://cgm.cs.mcgill.ca/~avis/C/lrslib/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="gmp mpi"
+
+RDEPEND="gmp? ( dev-libs/gmp:0=
+			  mpi? ( virtual/mpi ) )"
+DEPEND="${RDEPEND}"
+
+src_prepare(){
+	default
+	tc-export CC
+	sed -e "s/gcc/$(tc-getCC)/g" \
+		-e "s/g++/$(tc-getCXX)/g" \
+		-e "s/-O3/${CFLAGS}/g" \
+		-e 's/$(CC) -shared/$(CC) $(LDFLAGS) -shared/' \
+		-e "s,/usr/local,${EPREFIX}/usr,g" \
+		-e "s,/lib,/$(get_libdir),g" \
+		-i makefile || die
+}
+
+src_compile () {
+	if use gmp ; then
+		emake
+		emake all-shared
+		use mpi && emake mplrs
+	else
+		emake allmp
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" prefix="${EPREFIX}/usr" install-common
+	if use gmp; then
+		emake DESTDIR="${D}" install-shared prefix="${EPREFIX}/usr"
+		use mpi && dobin mplrs
+	fi
+	dodoc README
+}
diff --git a/sci-libs/lrslib/metadata.xml b/sci-libs/lrslib/metadata.xml
new file mode 100644
index 000000000000..8b97646ef0f3
--- /dev/null
+++ b/sci-libs/lrslib/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@gentoo.org</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <longdescription>lrslib is a self-contained ANSI C implementation as a callable library of the
+  reverse search algorithm for vertex enumeration/convex hull problems and comes with a choice of
+  three arithmetic packages. Input file formats are compatible with Komei Fukuda's cdd package. All
+  computations are done exactly in either multiple precision or fixed integer arithmetic. Output is
+  not stored in memory, so even problems with very large output sizes can sometimes be
+  solved.</longdescription>
+</pkgmetadata>