gentoo resync : 04.01.2022

1 files changed, 41 insertions, 0 deletions

diff --git a/sci-geosciences/gshhs/gshhs-1.13-r1.ebuild b/sci-geosciences/gshhs/gshhs-1.13-r1.ebuild
new file mode 100644
index 000000000000..14c8c92d67cb
--- /dev/null
+++ b/sci-geosciences/gshhs/gshhs-1.13-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Global Self-consistent, Hierarchical, High-resolution Shoreline programs"
+HOMEPAGE="https://www.ngdc.noaa.gov/mgg/shorelines/gshhs.html"
+SRC_URI="ftp://ftp.soest.hawaii.edu/pwessel/gshhs/gshhs_1.13_src.zip"
+S="${WORKDIR}/${PN}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+data"
+
+RDEPEND="sci-libs/netcdf:=
+	sci-libs/gdal:=
+	data? ( sci-geosciences/gshhs-data )"
+DEPEND="${RDEPEND}"
+BDEPEND="app-arch/unzip
+	virtual/pkgconfig"
+
+src_compile() {
+	local p
+	for p in gshhs gshhs_dp gshhstograss; do
+		$(tc-getCC) ${CFLAGS} ${CPPFLAGS} \
+			$($(tc-getPKG_CONFIG) --cflags netcdf) \
+			${LDFLAGS} ${p}.c \
+			$($(tc-getPKG_CONFIG) --libs netcdf) -lgdal -lm -o ${p} \
+			|| die
+	done
+}
+
+src_install() {
+	dobin gshhs gshhs_dp gshhstograss
+	insinto /usr/include
+	doins gshhs.h
+	dodoc README.gshhs
+}