gentoo resync : 22.10.2018

1 files changed, 68 insertions, 0 deletions

diff --git a/sci-electronics/drahnr-oregano/drahnr-oregano-0.84.40.ebuild b/sci-electronics/drahnr-oregano/drahnr-oregano-0.84.40.ebuild
new file mode 100644
index 000000000000..2ce8945195d8
--- /dev/null
+++ b/sci-electronics/drahnr-oregano/drahnr-oregano-0.84.40.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit gnome2-utils python-any-r1 waf-utils xdg-utils
+
+DESCRIPTION="Application for the schematic capturing and simulation of electrical circuits"
+HOMEPAGE="https://github.com/drahnr/oregano"
+SRC_URI="https://github.com/drahnr/oregano/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+S="${WORKDIR}/oregano-${PV}"
+
+COMMON_DEP="dev-libs/glib:2
+	dev-libs/libxml2:2
+	x11-libs/goocanvas:2.0
+	x11-libs/gtk+:3
+	x11-libs/gtksourceview:3.0"
+
+DEPEND="${COMMON_DEP}
+	${PYTHON_DEPS}
+	virtual/pkgconfig"
+
+RDEPEND="${COMMON_DEP}
+	|| ( gnome-base/dconf gnome-base/gconf )
+	sci-electronics/electronics-menu"
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]] ; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_configure() { waf-utils_src_configure; }
+
+src_install() {
+	waf-utils_src_install --no-xdg --no-install-gschema
+	docompress -x /usr/share/doc/${PF}/{dev-docs,sequence}
+	dodoc -r docs/{dev-docs,sequence,user-docs}
+	insinto /usr/share/glib-2.0/schemas
+	doins data/settings/io.ahoi.oregano.gschema.xml
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+
+	elog "Note: You'll need to emerge your prefered simulation backend"
+	elog "such as sci-electronics/ngspice (preferred) or sci-electronics/gnucap"
+	elog "for simulation to work."
+	elog "As an alternative generate a netlist and use sci-electronics/spice"
+	elog "from the command line for simulation."
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}