gentoo auto-resync : 28:01:2023 - 14:51:38

2 files changed, 112 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 25cc9d768943..ae02c4195aa7 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,5 +1,6 @@
 DIST Remmina-v1.4.27.tar.bz2 1975470 BLAKE2B 09ce4cd29f476a307dce4c35d8304b8383db016b63646375d50a86051f6dd99fb4775700e3d8887dbbbece72b90dcbc5987b0705e2fe8f5b0840bba1cb29c92e SHA512 44bc067eaf2c4c10e42182aa7c3ec2aa18ec5c0ce51a2fc765884cbfc11261d3c0db537b1674424aa092caf171e647714dcc8af6d813273f7b96876a251e0575
 DIST Remmina-v1.4.29.tar.bz2 2014832 BLAKE2B a5e3a54d510c74fd8399116dfd1cc67aaafdf93e3217a20ad77a2c959597b7be51cf187ffb459eb5cabe0a30f985f649aa59dba1397d7a8b3a0c10ea997b3fdf SHA512 8fbe822d07ec800bb739579b373003ee56cbc661fd0b635e5a7af0369d2e5450e7116907a87c34e82704c2aab790ac501ee6331946751660321c917ffd9a183e
 EBUILD remmina-1.4.27.ebuild 2702 BLAKE2B c481ef70b489d8d35fcc94baba872cdfa21b1111ad853bf15a5928ab4d35da724aafd968803ef824cd13736d523973fa1db0bc01ed6c0d85168c82f149d40293 SHA512 454453b963eeeeb1be58aac6db22ad4909672b0d1ab238cd911e101aeb5883776ab609951422345b2ae4b7b9691a90209e07505c195ce6619f01baf91fa55ecb
+EBUILD remmina-1.4.29-r1.ebuild 2706 BLAKE2B dd15edd37d77276438e44bfd08895d9bf30ac2aead365d0e7a7556b0bb83a86ee8c38fc1c3bdc32f9f962fc58209b3239eb6688e4e7b7fc3b4b3fbb3c16dca0c SHA512 b46a5027b4a0eea624e8a5206746fa2bcdde075184d81b90c56220886cf6d2f53f453f81981c7f9f41b5a7788ece6e3e0e1f13f4efac46956e9b11c3c2b0b175
 EBUILD remmina-1.4.29.ebuild 2700 BLAKE2B 0189ecd073daab151c4dd42e0d7c4edafeeead44e2c8fd17f3bc26dfc6dd38e828463bd4d5a6c738be31f463c8620373f00ad290d9e0b7c228910672e1ca5b75 SHA512 dd26f3906654ad7c822e9282249172713da221a4abe3d694b7a04e322a1700539558248a8e70fc049a31d2e6ddcbee4b8b3045892c04d849cbe2bf7c16f2a727
 MISC metadata.xml 1123 BLAKE2B 658714c247c6fbec6118a88bc5493a67aca30e949249407d421592b956c15b439b6d96c682d2d6d7cc9f1eb2dfdcc902c4c463c6a208af4bb9196656723f220a SHA512 cbf00348e2da27acbe9890ac2d6b19d5731496cf1aab303d64f036700fb779587cb7fe81a95d3a25f9ec5dcb79e2e7e880e345fc1ac267acd25da89844ab6f21
diff --git a/net-misc/remmina/remmina-1.4.29-r1.ebuild b/net-misc/remmina/remmina-1.4.29-r1.ebuild
new file mode 100644
index 000000000000..901a4cac14ff
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.29-r1.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake optfeature python-single-r1 xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples gnome-keyring gvnc kwallet nls python spice ssh rdp telemetry vnc wayland webkit zeroconf"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[wayland?]
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libayatana-appindicator )
+	crypt? ( dev-libs/libgcrypt:0= )
+	gnome-keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+}