gentoo auto-resync : 24:11:2022 - 07:10:12

1 files changed, 74 insertions, 0 deletions

diff --git a/net-misc/radvd/radvd-2.19-r5.ebuild b/net-misc/radvd/radvd-2.19-r5.ebuild
new file mode 100644
index 000000000000..339fa3d60deb
--- /dev/null
+++ b/net-misc/radvd/radvd-2.19-r5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools readme.gentoo-r1 systemd toolchain-funcs
+
+DESCRIPTION="Linux IPv6 Router Advertisement Daemon"
+HOMEPAGE="https://v6web.litech.org/radvd/"
+SRC_URI="https://v6web.litech.org/radvd/dist/${P}.tar.xz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="selinux test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	test? ( dev-libs/check )
+"
+RDEPEND="
+	acct-group/radvd
+	acct-user/radvd
+	selinux? ( sec-policy/selinux-radvd )
+"
+
+DOCS=( CHANGES README TODO radvd.conf.example )
+
+PATCHES=(
+	"${FILESDIR}"/${P}-musl-include.patch
+	"${FILESDIR}"/${P}-clang16.patch
+)
+
+src_prepare() {
+	default
+
+	# Drop once clang16 patch is in a release
+	eautoreconf
+}
+
+src_configure() {
+	econf --with-pidfile=/run/radvd/radvd.pid \
+		--with-systemdsystemunitdir=no \
+		$(use_with test check)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+
+	docinto html
+	dodoc INTRO.html
+
+	newinitd "${FILESDIR}"/${PN}-2.15.init ${PN}
+	newconfd "${FILESDIR}"/${PN}.conf ${PN}
+
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	readme.gentoo_create_doc
+}
+
+DISABLE_AUTOFORMATTING=1
+DOC_CONTENTS="Please create a configuration file ${ROOT}/etc/radvd.conf.
+See ${ROOT}/usr/share/doc/${PF} for an example.
+
+grsecurity users should allow a specific group to read /proc
+and add the radvd user to that group, otherwise radvd may
+segfault on startup."