gentoo resync : 15.06.2021

1 files changed, 67 insertions, 0 deletions

diff --git a/net-misc/ipv6calc/ipv6calc-3.1.1.ebuild b/net-misc/ipv6calc/ipv6calc-3.1.1.ebuild
new file mode 100644
index 000000000000..80ba906c239b
--- /dev/null
+++ b/net-misc/ipv6calc/ipv6calc-3.1.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="IPv6 address calculator"
+HOMEPAGE="https://www.deepspace6.net/projects/ipv6calc.html"
+SRC_URI="https://github.com/pbiering/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="geoip test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:=
+	geoip? ( >=dev-libs/geoip-1.4.7 )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-perl/Digest-SHA1 )
+"
+
+#dev-perl/URI is needed for web interface, that is not installed now
+
+src_configure() {
+	# These options are broken.  You can't disable them.  That's
+	# okay because we want then force enabled.
+	# --disable-db-as-registry
+	# --disable-db-cc-registry
+	if use geoip; then
+		myconf=$(use_enable geoip)
+		myconf+=" --with-geoip-db=${EPREFIX}/usr/share/GeoIP"
+	fi
+	econf \
+		--disable-bundled-getopt \
+		--disable-bundled-md5 \
+		--enable-shared \
+		--enable-dynamic-load \
+		--enable-db-ieee \
+		--enable-db-ipv4 \
+		--enable-db-ipv6 \
+		--disable-dbip \
+		--disable-dbip2 \
+		--disable-external \
+		--disable-ip2location \
+		${myconf}
+}
+
+src_compile() {
+	emake distclean
+	# Disable default CFLAGS (-O2 and -g)
+	emake DEFAULT_CFLAGS=""
+}
+
+src_test() {
+	if [[ ${EUID} -eq 0 ]]; then
+		# Disable tests that fail as root
+		echo true > ipv6logstats/test_ipv6logstats.sh
+	fi
+	default
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc ChangeLog CREDITS README TODO USAGE
+}