gentoo resync : 28.04.2019

1 files changed, 90 insertions, 0 deletions

diff --git a/net-libs/nghttp2/nghttp2-1.38.0.ebuild b/net-libs/nghttp2/nghttp2-1.38.0.ebuild
new file mode 100644
index 000000000000..23ae1e8d57ba
--- /dev/null
+++ b/net-libs/nghttp2/nghttp2-1.38.0.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# TODO: Add python support.
+
+EAPI=7
+
+inherit autotools multilib-minimal
+
+if [[ ${PV} == 9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/nghttp2/nghttp2.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/nghttp2/nghttp2/releases/download/v${PV}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+# 675772
+SRC_URI+=" https://dev.gentoo.org/~polynomial-c/${PN}-1.38.0-unbundle_http_parser.patch.xz"
+
+DESCRIPTION="HTTP/2 C Library"
+HOMEPAGE="https://nghttp2.org/"
+
+LICENSE="MIT"
+SLOT="0/1.14" # <C++>.<C> SONAMEs
+IUSE="cxx debug hpack-tools jemalloc libressl static-libs test +threads utils xml"
+
+SSL_DEPEND="
+	!libressl? ( >=dev-libs/openssl-1.0.2:0=[-bindist,${MULTILIB_USEDEP}] )
+	libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+"
+RDEPEND="
+	cxx? (
+		${SSL_DEPEND}
+		dev-libs/boost:=[${MULTILIB_USEDEP},threads]
+		>=net-libs/http-parser-2.9.1:=[${MULTILIB_USEDEP}]
+	)
+	hpack-tools? (
+		>=dev-libs/jansson-2.5
+		>=net-libs/http-parser-2.9.1:=
+	)
+	jemalloc? ( dev-libs/jemalloc[${MULTILIB_USEDEP}] )
+	utils? (
+		${SSL_DEPEND}
+		>=dev-libs/libev-4.15[${MULTILIB_USEDEP}]
+		>=sys-libs/zlib-1.2.3[${MULTILIB_USEDEP}]
+		net-dns/c-ares:=[${MULTILIB_USEDEP}]
+	)
+	xml? ( >=dev-libs/libxml2-2.7.7:2[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( >=dev-util/cunit-2.1[${MULTILIB_USEDEP}] )"
+
+PATCHES=(
+	"${WORKDIR}/${PN}-1.38.0-unbundle_http_parser.patch" # 675772
+	"${FILESDIR}/${P}-boost-1.70.0.patch" #683368
+)
+
+src_prepare() {
+	default
+	# Remove bundled stuff
+	rm -r third-party/http-parser || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-examples
+		--disable-failmalloc
+		--disable-python-bindings
+		--disable-werror
+		--without-bundled-http_parser
+		--without-cython
+		$(use_enable cxx asio-lib)
+		$(use_enable debug)
+		$(multilib_native_use_enable hpack-tools)
+		$(use_enable static-libs static)
+		$(use_enable threads)
+		$(multilib_native_use_enable utils app)
+		$(multilib_native_use_with jemalloc)
+		$(multilib_native_use_with xml libxml2)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	if ! use static-libs ; then
+		find "${ED}"/usr -name '*.la' -delete || die
+	fi
+}