gentoo resync : 18.11.2018

1 files changed, 52 insertions, 0 deletions

diff --git a/net-libs/libhubbub/libhubbub-0.3.5-r1.ebuild b/net-libs/libhubbub/libhubbub-0.3.5-r1.ebuild
new file mode 100644
index 000000000000..d0a20d7641ec
--- /dev/null
+++ b/net-libs/libhubbub/libhubbub-0.3.5-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="HTML5 compliant parsing library, written in C"
+HOMEPAGE="http://www.netsurf-browser.org/projects/hubbub/"
+SRC_URI="https://download.netsurf-browser.org/libs/releases/${P}-src.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~m68k-mint"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-libs/libparserutils-0.2.1-r1
+	!net-libs/hubbub"
+DEPEND="${RDEPEND}
+	dev-util/netsurf-buildsystem
+	virtual/pkgconfig
+	test? (
+		dev-lang/perl
+		>=dev-libs/json-c-0.10-r1
+	)"
+
+DOCS=( README docs/{Architecture,Macros,Todo,Treebuilder,Updated} )
+
+src_prepare() {
+	default
+	sed -e '1i#pragma GCC diagnostic ignored "-Wimplicit-fallthrough"' \
+		-i test/tree2.c || die
+}
+
+_emake() {
+	source /usr/share/netsurf-buildsystem/gentoo-helpers.sh
+	netsurf_define_makeconf
+	emake "${NETSURF_MAKECONF[@]}" COMPONENT_TYPE=lib-shared $@
+}
+
+src_compile() {
+	_emake
+}
+
+src_test() {
+	_emake test
+}
+
+src_install() {
+	_emake DESTDIR="${ED}" install
+}