gentoo resync : 05.04.2018

3 files changed, 150 insertions, 0 deletions

diff --git a/net-irc/Manifest.gz b/net-irc/Manifest.gz
index 67ec45f66467..0039af306fa3 100644
--- a/net-irc/Manifest.gz
+++ b/net-irc/Manifest.gz
diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 2679f8ffb572..efac93afc3de 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,8 +1,10 @@
 DIST kvirc-5.0_pre20171001143427.tar.gz 6035319 BLAKE2B 764b079b2d991f3b80b48eaf4119ac9cbfef3429d97e990fdc9c95a23561d3efc553c876a8eac17465cf14533f3230af24695f834dd985d73f89d45103457eb2 SHA512 ccf9b032737ce24cc98c23f3e1363b7ad874452837805b9a240dfd0d5e067da556dcd6003398f3cb2826f144656540592189e7f88d68608d6fbb2e8294535640
 DIST kvirc-5.0_pre20171211100641.tar.gz 6035018 BLAKE2B 0da30cbd0ac7443b994f4f8f4b8b39255219d99a34dd026cc59d119bec11985e261f281928f817ffe0865427a2f59b2a25abbe20d9d4a391086c26c507f83074 SHA512 599ea40faac97ad0604e29fe8f77a92f36a9f52fdee118dead712e1cea8d03d2b2791cb121dcd7efd39d5719e9133ff79e45ea1ffefa5886b0b11709ae41f814
 DIST kvirc-5.0_pre20180209140255.tar.gz 6035048 BLAKE2B 1141fb73b2498f931b8e2b28368cbae8b94d6268e2f5548e38f5a5a6c0776a9ffe4c7c2d5139eda7166c1cae73fb61ebc894cc085ec1ad20edc1f53136a21492 SHA512 c9dc3d257dcb9446c91be07d490fc76418eaaa93bd133dfec5b659949baae68383e04cbfbab9624db8bf6f1908fd93a190a74f95b6d1b929a75739c3032f82e6
+DIST kvirc-5.0_pre20180401054732.tar.gz 6040980 BLAKE2B fa023ef84f5c84e92b11ed043be0a2e52316fc92f206c41bcb7216760e0473e13e118398445137aeafd657c856cdccfa2f5202f9534904771d8a049d5139f41a SHA512 6d3a9bb06018e2d54369139bbf0a768d3c4e39754b908c1e4294c79707c8b5b751141ae10bdf8456465bd9bf6e4e426a91bc6bef5a1c3563bf32adecc10582eb
 EBUILD kvirc-5.0_pre20171001143427.ebuild 3846 BLAKE2B eb9572bdde0e10d7758987cf8b8f047499c1143b90e317d7b67b0a22cc6bcf76a04f8fb032e1a63a0fa18ae31d9deb641498869a22cf75431cb0f24af9418f71 SHA512 7986bde6410f1125c28cc05899ce155a9614b3ebba0fc4402035ef80868dc25c1a62be4f9685aea4a0f7ea7eb2e36a78abaff68167be908c3126afcf748d8122
 EBUILD kvirc-5.0_pre20171211100641.ebuild 3846 BLAKE2B aa287984c675d7a17f14ff03a118e4ee2378a826f81f309065b33c4583b83d5a3e441b44dbd9d0eefeea5c4b46044b8b02a8bc0040dca6be30f2226ec18b3756 SHA512 f714f2c7646f85bb4f8aa9125e4651e44b47bb09c045d6078d36cee356ff26023916646c584100fb3040e72964532dbb6b0ae93c39ee2228725afaa7644e17e3
 EBUILD kvirc-5.0_pre20180209140255.ebuild 3846 BLAKE2B a6aabafde47401e190308dc180f2c12e09344a5b9b3c282a412fca70e8ed0a6bc384d252e2f5ae498d04f42f2c9ab7256f112bbc2281aa6841fe03465398cfea SHA512 41022eedbf2eac3fc82dce6f56d9652823a1d284e48d14c7457ce7d299a3880e4a2d9b771d56854cfd79f82c02ce2e1ff12b950154eb370859da874778b3af64
+EBUILD kvirc-5.0_pre20180401054732.ebuild 3848 BLAKE2B 1ce648c715257966f3147178411df5ca628e2b0d5b9c6d116f6e247366bcf5041ad7bd19b027cc66a5d1e0d4eef69d3605086eaac75c143b9558bddd4b77a10d SHA512 a4942b049de2b62181fd490de898af628bd77f402d40f1fc4ee5f42e3cda65070f3cf6b71b8071589895880fe0b96092a499bc03a8548a5e2465a71e2d9f6b71
 EBUILD kvirc-9999.ebuild 3785 BLAKE2B aa2a973fd69e83e8ae14f51a5a7ffc2048428f72618b9171c486bb9c6cad565460efce1b0e076f07f38d3881d4733e0884e2ebec6c28c6bd9e2d266fcaf98594 SHA512 c867319c4d13c8a88a6fb1eb9076340542372e763441bcef5c3ac4f99a77b8c786eac38b5b91c2667322fbf6e923e545ad29373cd783f7a148e1f05d6ea5aa0b
 MISC metadata.xml 618 BLAKE2B 5a6a28876a22cedbca154051a389fed0e7ef25039319786ed2303b580b1e421b648038237e0157678fb96e1b45839e725299e56584bcb770593f60f305932145 SHA512 af08ad67affb8dbe4ae6afbb2a251e5bd44e5fb30f9332dddebbb6dd504fa25b449b5b4c3a5c1f0337c6a7751b2395eb049cf94206a44cce2a7ab1df1d1b3eae
diff --git a/net-irc/kvirc/kvirc-5.0_pre20180401054732.ebuild b/net-irc/kvirc/kvirc-5.0_pre20180401054732.ebuild
new file mode 100644
index 000000000000..37a0e7d775e3
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20180401054732.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic gnome2-utils multilib python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="e6915e5ed77aef19080aeab5ca76a61faf1d4e41"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:0= )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+
+DOCS=(ChangeLog doc/FAQ)
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_CRYPT=yes
+		-DWANT_DCC_VOICE=yes
+		-DWANT_IPC=yes
+		-DWANT_IPV6=yes
+		-DWANT_TRANSPARENCY=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}