gentoo resync : 03.09.2021

2 files changed, 144 insertions, 0 deletions

diff --git a/net-im/telegram-desktop/Manifest b/net-im/telegram-desktop/Manifest
index a486151b8370..82d766267eff 100644
--- a/net-im/telegram-desktop/Manifest
+++ b/net-im/telegram-desktop/Manifest
@@ -6,6 +6,8 @@ AUX tdesktop-2.8.9-webview-fix-glib.patch 1838 BLAKE2B 16b861f0fda72ba1725779880
 AUX tdesktop-2.9.3-jemalloc-only-telegram.patch 988 BLAKE2B 487ce32454a5bfb51a081c7bd6803ff6cc956b349569d5ddf17d2abb7d7d5f0714002de654e149d8aefe6880e6b827c2ffb42c22e3ffa3fc6f10286c3e805463 SHA512 a1645bac4b715bad17a78226b9e76e30117f64715b1833df17950c882940a2ebbf18c70ab9ec628002408859292b57b9c4a48f9212bd15d9d2903867012eb3cf
 DIST tdesktop-2.8.11-full.tar.gz 37105468 BLAKE2B 1ec5a0003bd1b948b45213509fa0649dfde5ec8e3dff097bf45aa0951c7963930788b0bee853f286d04b008b78704c464b6614b8391350767affebc2623b25af SHA512 a553313b04fbb562745be2381a84117657172952e46e280980a73c9fcfe2a7cf29c0e012e4b1259816d1e6652418e7a1ddfc4e394544fcc3aeb33704cbe80860
 DIST tdesktop-2.9.3-full.tar.gz 37335782 BLAKE2B 197583ba6568c455218c51f590c1ba1a3f10c390caa4fd03657098f499ce113a4f5f57ca9dd53bc4baba31992d4229768ed35e68ad6b0685010bc335817edcac SHA512 810cfac5d7e6ce9413b1b2406927e89c1383ea5b725233a68b2cb29dd374b4c3386c22186640afde4492c844516c88889a5db8e5b167a09d6d6c1270ac965ac4
+DIST tdesktop-3.0.0-full.tar.gz 37531734 BLAKE2B 0def1fe0b34cde30c7b2a0afb3b6cc10cd44a64a5145fee4ff44e1b507c11cebd6b8752bd5c3b6a23798ef0755e26630813c65092e2793efd3ea95a987195738 SHA512 2439de9e11fa6150f4306a0da79a20b1552e4432cf669764669e4bf2eca7311b031e8b22c23cde1efe640e1ef2ac71916fd7151d31b475cbaabc78d79ee50415
 EBUILD telegram-desktop-2.8.11-r2.ebuild 4623 BLAKE2B 8726574359a9c4f222f10a676f27f2fa2e0870fefec15598393f6933b899a2bd3a71c5467a02ef021deb50ad468a50901a18a43199fe099a7b535e61c8e1ce84 SHA512 57a93a202b69851b37ddaf7a54e4ec8c02464eb297bf4716ec291e43bd58d84ee6749cf34222a3e494b9dc3b387b9f6b768aa020cbcb2408788073d087a8703c
 EBUILD telegram-desktop-2.9.3.ebuild 4280 BLAKE2B 12525c38e8c2dc09fe79115576fc88ca4cc98a085ef06cd89f9924d680a287bfd3bc13d8dd68722e766e261ff26185ce349ebd2a3f76cb5a033d1fe5dbf5a603 SHA512 67367fe897db0914777063092d810540126a3366ac7f4ad86e36391aa65ec1944e54bbb6197a9c36dc832b6dcac18f56beea1ecc25fdfb2a9efc079f39952a33
+EBUILD telegram-desktop-3.0.0.ebuild 4216 BLAKE2B 3c74c83e74625be07b36b867bd7c6722c1dc7003e724aaa2bfc40ce824783cb2cb1659865fb068ba2940b9dc35aa5953f0431b5d676c55aac86919bcfd021665 SHA512 8f21fdb4bab4fca0636ea0da87f7ba2ab5f90601e20b67862852fdcf6150ad62e89c3c5994b67d0d2757658b238ec3efde620c6cf170d5e7a18a066109bf5603
 MISC metadata.xml 708 BLAKE2B 9aab7bce0728ac85db3d20f58d0f4360e01f133570d42145a43e2eb0b41e275888764fd7da0a749dd37ce72c6e0286f47be36c57adc6330e74a36308197fc202 SHA512 cad9265a882e0c9cda070cebdbcd5c6c096f2b7242772a1e9877eb0a4210a98768c8de75f197a1649e08f68010aa450d043a9decfaf976d90bf147458fbbb086
diff --git a/net-im/telegram-desktop/telegram-desktop-3.0.0.ebuild b/net-im/telegram-desktop/telegram-desktop-3.0.0.ebuild
new file mode 100644
index 000000000000..4c3ae78f28d6
--- /dev/null
+++ b/net-im/telegram-desktop/telegram-desktop-3.0.0.ebuild
@@ -0,0 +1,142 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit xdg cmake python-any-r1 flag-o-matic
+
+DESCRIPTION="Official desktop client for Telegram"
+HOMEPAGE="https://desktop.telegram.org"
+
+MY_P="tdesktop-${PV}-full"
+SRC_URI="https://github.com/telegramdesktop/tdesktop/releases/download/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="BSD GPL-3-with-openssl-exception LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE="+dbus enchant +gtk +hunspell screencast +spell wayland webkit +X"
+REQUIRED_USE="
+	spell? (
+		^^ ( enchant hunspell )
+	)
+	gtk? ( dbus )
+	webkit? ( dbus )
+"
+
+RDEPEND="
+	!net-im/telegram-desktop-bin
+	app-arch/lz4:=
+	dev-cpp/glibmm:2
+	dev-libs/jemalloc:=[-lazy-lock]
+	dev-libs/xxhash
+	>=dev-qt/qtcore-5.15:5
+	>=dev-qt/qtgui-5.15:5[dbus?,jpeg,png,wayland?,X?]
+	>=dev-qt/qtimageformats-5.15:5
+	>=dev-qt/qtnetwork-5.15:5[ssl]
+	>=dev-qt/qtsvg-5.15:5
+	>=dev-qt/qtwidgets-5.15:5[png,X?]
+	media-fonts/open-sans
+	media-libs/fontconfig:=
+	~media-libs/libtgvoip-2.4.4_p20210302
+	>=media-libs/libtgvoip-2.4.4_p20210302-r2
+	media-libs/openal
+	media-libs/opus:=
+	media-libs/rnnoise
+	~media-libs/tg_owt-0_pre20210626[screencast=,X=]
+	media-video/ffmpeg:=[opus]
+	sys-libs/zlib:=[minizip]
+	dbus? (
+		dev-qt/qtdbus:5
+		dev-libs/libdbusmenu-qt[qt5(+)]
+	)
+	enchant? ( app-text/enchant:= )
+	gtk? ( x11-libs/gtk+:3[X?,wayland?] )
+	hunspell? ( >=app-text/hunspell-1.7:= )
+	wayland? ( kde-frameworks/kwayland:= )
+	webkit? ( net-libs/webkit-gtk:= )
+	X? ( x11-libs/libxcb:= )
+"
+DEPEND="${RDEPEND}
+	dev-cpp/range-v3
+	=dev-cpp/ms-gsl-3*
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/cmake-3.16
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/tdesktop-2.9.3-jemalloc-only-telegram.patch"
+)
+
+pkg_pretend() {
+	if has ccache ${FEATURES}; then
+		ewarn
+		ewarn "ccache does not work with ${PN} out of the box"
+		ewarn "due to usage of precompiled headers"
+		ewarn "check bug https://bugs.gentoo.org/715114 for more info"
+		ewarn
+	fi
+}
+
+src_prepare() {
+	# no explicit toggle, doesn't build with the system one #752417
+	sed -i 's/DESKTOP_APP_USE_PACKAGED/NO_ONE_WILL_EVER_SET_THIS/' \
+		cmake/external/rlottie/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	# gtk is really needed for image copy-paste due to https://bugreports.qt.io/browse/QTBUG-56595
+	local mycmakeargs=(
+		-DTDESKTOP_LAUNCHER_BASENAME="${PN}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_tl-expected=ON  # header only lib, some git version. prevents warnings.
+
+		-DDESKTOP_APP_DISABLE_X11_INTEGRATION=$(usex X no yes)
+		-DDESKTOP_APP_DISABLE_WAYLAND_INTEGRATION=$(usex wayland no yes)
+		-DDESKTOP_APP_DISABLE_DBUS_INTEGRATION=$(usex dbus no yes)
+		-DDESKTOP_APP_DISABLE_GTK_INTEGRATION=$(usex gtk no yes)
+		-DDESKTOP_APP_DISABLE_WEBKITGTK=$(usex webkit no yes)
+		-DDESKTOP_APP_DISABLE_SPELLCHECK=$(usex spell no yes)  # enables hunspell (recommended)
+		-DDESKTOP_APP_USE_ENCHANT=$(usex enchant)  # enables enchant and disables hunspell
+	)
+
+	if [[ -n ${MY_TDESKTOP_API_ID} && -n ${MY_TDESKTOP_API_HASH} ]]; then
+		einfo "Found custom API credentials"
+		mycmakeargs+=(
+			-DTDESKTOP_API_ID="${MY_TDESKTOP_API_ID}"
+			-DTDESKTOP_API_HASH="${MY_TDESKTOP_API_HASH}"
+		)
+	else
+		# https://github.com/telegramdesktop/tdesktop/blob/dev/snap/snapcraft.yaml
+		# Building with snapcraft API credentials by default
+		# Custom API credentials can be obtained here:
+		# https://github.com/telegramdesktop/tdesktop/blob/dev/docs/api_credentials.md
+		# After getting credentials you can export variables:
+		#  export MY_TDESKTOP_API_ID="17349""
+		#  export MY_TDESKTOP_API_HASH="344583e45741c457fe1862106095a5eb"
+		# and restart the build"
+		# you can set above variables (without export) in /etc/portage/env/net-im/telegram-desktop
+		# portage will use custom variable every build automatically
+		mycmakeargs+=(
+			-DTDESKTOP_API_ID="611335"
+			-DTDESKTOP_API_HASH="d524b414d21f4d37f08684c1df41ac9c"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use gtk || elog "enable the 'gtk' useflag if you have image copy-paste problems"
+	if ! use X && ! use screencast; then
+		elog "both the 'X' and 'screencast' useflags are disabled, screen sharing won't work!"
+	fi
+}