gentoo resync : 22.10.2018

1 files changed, 44 insertions, 0 deletions

diff --git a/net-dns/s6-dns/s6-dns-2.3.0.1.ebuild b/net-dns/s6-dns/s6-dns-2.3.0.1.ebuild
new file mode 100644
index 000000000000..de60beb85347
--- /dev/null
+++ b/net-dns/s6-dns/s6-dns-2.3.0.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="suite of DNS client programs and libraries for Unix systems"
+HOMEPAGE="https://www.skarnet.org/software/s6-dns/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="static static-libs"
+
+REQUIRED_USE="static? ( static-libs )"
+
+DEPEND=">=dev-libs/skalibs-2.7.0.0[static-libs?]"
+RDEPEND="!static? ( >=dev-libs/skalibs-2.7.0.0:= )"
+
+HTML_DOCS="doc/*"
+
+src_prepare() {
+	default
+
+	# Remove QA warning about LDFLAGS addition
+	sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
+
+	# configure overrides gentoo's -fstack-protector default
+	sed -i "/^tryflag CFLAGS_AUTO -fno-stack-protector$/d" "${S}/configure" || die
+}
+
+src_configure() {
+	econf \
+		--bindir=/bin \
+		--dynlibdir=/$(get_libdir) \
+		--libdir=/usr/$(get_libdir)/${PN} \
+		--with-dynlib=/$(get_libdir) \
+		--with-lib=/usr/$(get_libdir)/skalibs \
+		--with-sysdeps=/usr/$(get_libdir)/skalibs \
+		--enable-shared \
+		$(use_enable static allstatic) \
+		$(use_enable static static-libc) \
+		$(use_enable static-libs static)
+}