gentoo resync : 07.05.2019

1 files changed, 54 insertions, 0 deletions

diff --git a/net-dns/libidn2/libidn2-2.1.1a-r1.ebuild b/net-dns/libidn2/libidn2-2.1.1a-r1.ebuild
new file mode 100644
index 000000000000..c6f5d3489584
--- /dev/null
+++ b/net-dns/libidn2/libidn2-2.1.1a-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib-minimal
+
+DESCRIPTION="An implementation of the IDNA2008 specifications (RFCs 5890, 5891, 5892, 5893)"
+HOMEPAGE="https://www.gnu.org/software/libidn/#libidn2 https://gitlab.com/libidn/libidn2"
+SRC_URI="
+	mirror://gnu/libidn/${P}.tar.gz
+"
+
+LICENSE="GPL-2+ LGPL-3+"
+SLOT="0/2"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 ~riscv s390 sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/libunistring[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/perl
+	sys-apps/help2man
+"
+S=${WORKDIR}/${P/a/}
+
+src_prepare() {
+	default
+
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		# Darwin ar chokes when TMPDIR doesn't exist (as done for some
+		# reason in the Makefile)
+		sed -i -e '/^TMPDIR = /d' Makefile.in || die
+		export TMPDIR="${T}"
+	fi
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--disable-doc \
+		--disable-gcc-warnings \
+		--disable-gtk-doc \
+		--disable-silent-rules
+}
+
+multilib_src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}