reinit the tree, so we can have metadata

1 files changed, 51 insertions, 0 deletions

diff --git a/net-dns/libidn2/libidn2-2.0.4.ebuild b/net-dns/libidn2/libidn2-2.0.4.ebuild
new file mode 100644
index 000000000000..7b64e993d3ac
--- /dev/null
+++ b/net-dns/libidn2/libidn2-2.0.4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils flag-o-matic multilib-minimal
+
+DESCRIPTION="An implementation of the IDNA2008 specifications (RFCs 5890, 5891, 5892, 5893)"
+HOMEPAGE="https://www.gnu.org/software/libidn/#libidn2 https://gitlab.com/jas/libidn2"
+SRC_URI="
+	mirror://gnu/libidn/${P}.tar.gz
+"
+
+LICENSE="GPL-2+ LGPL-3+"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 hppa ia64 ~m68k ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/libunistring[${MULTILIB_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	dev-lang/perl
+	sys-apps/help2man
+"
+
+src_prepare() {
+	default
+
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		# Darwin ar chokes when TMPDIR doesn't exist (as done for some
+		# reason in the Makefile)
+		sed -i -e '/^TMPDIR = /d' Makefile.in || die
+		export TMPDIR="${T}"
+	fi
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--disable-doc \
+		--disable-gtk-doc
+}
+
+multilib_src_install() {
+	default
+
+	prune_libtool_files
+}