gentoo resync : 02.06.2019

1 files changed, 54 insertions, 0 deletions

diff --git a/net-analyzer/thc-ipv6/thc-ipv6-3.2-r1.ebuild b/net-analyzer/thc-ipv6/thc-ipv6-3.2-r1.ebuild
new file mode 100644
index 000000000000..71f98da3f733
--- /dev/null
+++ b/net-analyzer/thc-ipv6/thc-ipv6-3.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+[[ ${PV} == *9999 ]] && SCM="git-r3"
+EGIT_REPO_URI="https://github.com/vanhauser-thc/thc-ipv6.git"
+EGIT_BRANCH=master
+
+inherit eutils toolchain-funcs ${SCM}
+
+DESCRIPTION="complete tool set to attack the inherent protocol weaknesses of IPV6 and ICMP6"
+HOMEPAGE="https://www.thc.org/thc-ipv6/"
+LICENSE="AGPL-3 openssl"
+SLOT="0"
+IUSE="ssl"
+
+if [[ ${PV} != *9999 ]]; then
+	SRC_URI="https://github.com/vanhauser-thc/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DEPEND="net-libs/libpcap
+	net-libs/libnetfilter_queue
+	ssl? ( dev-libs/openssl:0= )"
+RDEPEND="${DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-3.2-stdint.patch" )
+
+src_unpack() {
+	if [[ ${PV} != *9999 ]]; then
+		default_src_unpack
+	else
+		git-r3_src_unpack
+	fi
+}
+
+src_prepare() {
+	sed -e '/^CFLAGS=/s,CFLAGS=,CFLAGS?=,' \
+		-i Makefile || die
+	if ! use ssl ; then
+		sed -e '/^HAVE_SSL/s:^:#:' \
+			-i Makefile
+	fi
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="/usr" STRIP="true" install
+	dodoc CHANGES HOWTO-INJECT README
+}