reinit the tree, so we can have metadata

1 files changed, 69 insertions, 0 deletions

diff --git a/net-analyzer/mtr/mtr-9999.ebuild b/net-analyzer/mtr/mtr-9999.ebuild
new file mode 100644
index 000000000000..3a1ec3b3a684
--- /dev/null
+++ b/net-analyzer/mtr/mtr-9999.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils fcaps flag-o-matic git-r3
+
+DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
+HOMEPAGE="http://www.bitwizard.nl/mtr/"
+EGIT_REPO_URI="https://github.com/traviscross/mtr.git"
+SRC_URI="mirror://gentoo/gtk-2.0-for-mtr.m4.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="gtk ipv6 ncurses"
+
+RDEPEND="
+	gtk? (
+		dev-libs/glib:2
+		x11-libs/gtk+:2
+	)
+	ncurses? ( sys-libs/ncurses:0= )
+"
+DEPEND="
+	${RDEPEND}
+	sys-devel/autoconf
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS FORMATS NEWS README SECURITY TODO )
+FILECAPS=( cap_net_raw usr/sbin/mtr-packet )
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.88-tinfo.patch
+)
+
+src_unpack() {
+	git-r3_src_unpack
+	unpack ${A}
+}
+
+src_prepare() {
+	# Keep this comment and following mv, even in case ebuild does not need
+	# it: kept gtk-2.0.m4 in SRC_URI but you'll have to mv it before autoreconf
+	mv "${WORKDIR}"/gtk-2.0-for-mtr.m4 gtk-2.0.m4 || die #222909
+
+	default
+
+	AT_M4DIR="." eautoreconf
+}
+
+src_configure() {
+	# In the source's configure script -lresolv is commented out. Apparently it
+	# is still needed for 64-bit MacOS.
+	[[ ${CHOST} == *-darwin* ]] && append-libs -lresolv
+	econf \
+		$(use_enable ipv6) \
+		$(use_with gtk) \
+		$(use_with ncurses)
+}
+
+pkg_postinst() {
+	fcaps_pkg_postinst
+
+	if use prefix && [[ ${CHOST} == *-darwin* ]] ; then
+		ewarn "mtr needs root privileges to run.  To grant them:"
+		ewarn " % sudo chown root ${EPREFIX}/usr/sbin/mtr"
+		ewarn " % sudo chmod u+s ${EPREFIX}/usr/sbin/mtr"
+	fi
+}