gentoo auto-resync : 05:04:2023 - 17:25:42

2 files changed, 0 insertions, 311 deletions

diff --git a/media-video/mpv/Manifest b/media-video/mpv/Manifest
index 9826a633c520..0e8223dd98d7 100644
--- a/media-video/mpv/Manifest
+++ b/media-video/mpv/Manifest
@@ -1,7 +1,5 @@
 AUX mpv-0.35.1-yt-dlp-edl-fragments.patch 2446 BLAKE2B f43d78be7d9914abf87c3c34f99c8cb84fd463dac7b4f4cfa96268d4351006580454a2c609a655d3d036d4a72c534205d226fd4ecf8334c9a0ff016b7eecc1c0 SHA512 0cd0415dcd06f4732e87ca52f9d43ec1cbef7fab531d4f3ba7398f7a80718dc5e0b373850c5324fe9a151c3edb31a4a624854c2e09b19ab91a3c655e84261866
-DIST mpv-0.35.0.tar.gz 3365752 BLAKE2B 9b8dca943fc60a68f8474549d75c021dd9157195253c5ec09721969e500b2756c033e86975499f5632f0c943ac7bb54699f47340f0dee73d7284668d4419b17f SHA512 d5c1f734057f6b6c27e7f59de43cf7c0e7f813d842b8c7fd2ae1073dbe649c8187b7686df4efe928db2952e9f1efc171245e6f8780c1d9f174f4d7abff1e073a
 DIST mpv-0.35.1.tar.gz 3367913 BLAKE2B 706a2031a2ca973eb3a092ec7f62ba40ca4dfd78e3ffe5d6e432486b0018852b034152a21805be594054178ccb17856dafe2b860cddcc22d27df895d163871de SHA512 42f3564a9ed4d972d14b2c697b0163f06a8bb68a0606a86c34935181247c783e3cb62286b445799998def0919fb13fce8b8f6453f82652d5bfaea5929119127a
-EBUILD mpv-0.35.0-r1.ebuild 7715 BLAKE2B 697a5320c5f572b7932894656313661c99d0ccc8824ba40d23de535824ae4a48ba93dc34f64f341e901f190a5fa8d32b8303839bb10eab9f7a9891da899180ad SHA512 6bb601e58c4c5cbc161d6dc71f253557c17359d7c1bb0505d0db407fda2b259c519cd98eb268608ba8054034c2ff9312596505044c1d75d85b3d51160da73e1f
 EBUILD mpv-0.35.1-r1.ebuild 7582 BLAKE2B f455eccfbec767e9401397445f8e40efb99bc38b8a9d246e582849adf9e6ec967f3aaf2268e8b6b2e5b5e871e03cbc7d3690032a85a8af01b5f2eab537db54f8 SHA512 62112e18bb28c64b7487094474745da2fb0e2975ed7443664bf3c0b3c5cbb1ac56750325a726e518dd5bf46d45ee7f95a2a57a3500d0ed56becccff143ad6fe6
 EBUILD mpv-9999.ebuild 7059 BLAKE2B eafd7d301a94da85208c892ddee697cca7ae4dea34cfa1766fb7be9c2a633afc8887f39a3d60a3d31604dadf9f54623e42e60462f3fe965fde313836ffdb3b78 SHA512 66aaa50887feb967503c51e424d0ba91812b202c50e5379c243a381aa72e81f80b8e5c94886fb8af2fdce558fea50341288cbff628f4b6a4e8b096bd2b95107b
 MISC metadata.xml 2400 BLAKE2B 28019423d987f5b809f657d21be087958ab8663e8765e2e56b5cb7eb48e34c249a8093790b69b40dfc9595b9c78eb512064a808d49bf8cd74879900482a3dd85 SHA512 d631048fafbe6d0a9450a221e4d1b4464c37d147e9def6b9ef25d24b40c27131296c9de272dc3c6d8cabfdbcd0adeb9d2568a5c3c75f1df0da6aaa775b32d0fc
diff --git a/media-video/mpv/mpv-0.35.0-r1.ebuild b/media-video/mpv/mpv-0.35.0-r1.ebuild
deleted file mode 100644
index 355a3f826dcd..000000000000
--- a/media-video/mpv/mpv-0.35.0-r1.ebuild
+++ /dev/null
@@ -1,309 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-1 luajit )
-PYTHON_COMPAT=( python3_{9..11} )
-inherit edo flag-o-matic lua-single meson optfeature pax-utils python-single-r1 xdg
-
-if [[ ${PV} == 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
-else
-	SRC_URI="https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 ~arm ~arm64 ~loong ppc ppc64 ~riscv x86 ~amd64-linux"
-fi
-
-DESCRIPTION="Media player for the command line"
-HOMEPAGE="https://mpv.io/"
-
-LICENSE="LGPL-2.1+ GPL-2+ BSD ISC MIT" #506946
-SLOT="0/2" # soname
-IUSE="
-	+X +alsa aqua archive bluray cdda +cli coreaudio debug +drm dvb
-	dvd +egl gamepad +iconv jack javascript jpeg lcms libcaca +libmpv
-	+libplacebo +lua mmal nvenc openal opengl pipewire pulseaudio
-	raspberry-pi rubberband sdl selinux sixel sndio test tools +uchardet
-	vaapi vdpau vulkan wayland +xv zimg zlib"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	|| ( cli libmpv )
-	egl? ( || ( X drm wayland ) )
-	libplacebo? ( || ( egl opengl vulkan ) )
-	lua? ( ${LUA_REQUIRED_USE} )
-	nvenc? ( || ( egl opengl vulkan ) )
-	opengl? ( || ( X aqua ) )
-	test? ( cli )
-	tools? ( cli )
-	uchardet? ( iconv )
-	vaapi? (
-		|| ( X egl libplacebo wayland )
-		wayland? ( drm )
-	)
-	vdpau? ( X )
-	vulkan? ( || ( X wayland ) libplacebo )
-	xv? ( X )"
-RESTRICT="!test? ( test )"
-
-# raspberry-pi: default to -bin given non-bin is known broken (bug #893422)
-COMMON_DEPEND="
-	media-libs/libass:=[fontconfig]
-	media-video/ffmpeg:=[encode,threads,vaapi?,vdpau?]
-	X? (
-		x11-libs/libX11
-		x11-libs/libXScrnSaver
-		x11-libs/libXext
-		x11-libs/libXinerama
-		x11-libs/libXpresent
-		x11-libs/libXrandr
-		xv? ( x11-libs/libXv )
-	)
-	alsa? ( media-libs/alsa-lib )
-	archive? ( app-arch/libarchive:= )
-	bluray? ( media-libs/libbluray:= )
-	cdda? (
-		dev-libs/libcdio-paranoia:=
-		dev-libs/libcdio:=
-	)
-	drm? (
-		media-libs/mesa[gbm(+)]
-		x11-libs/libdrm
-	)
-	dvd? (
-		media-libs/libdvdnav
-		media-libs/libdvdread:=
-	)
-	egl? ( media-libs/libglvnd )
-	gamepad? ( media-libs/libsdl2[joystick] )
-	iconv? (
-		virtual/libiconv
-		uchardet? ( app-i18n/uchardet )
-	)
-	jack? ( virtual/jack )
-	javascript? ( dev-lang/mujs:= )
-	jpeg? ( media-libs/libjpeg-turbo:= )
-	lcms? ( media-libs/lcms:2 )
-	libcaca? ( media-libs/libcaca )
-	libplacebo? (
-		>=media-libs/libplacebo-4.202:=[opengl?,vulkan?]
-		egl? ( media-libs/libplacebo[opengl] )
-	)
-	lua? ( ${LUA_DEPS} )
-	openal? ( media-libs/openal )
-	opengl? ( media-libs/libglvnd[X?] )
-	pipewire? ( media-video/pipewire:= )
-	pulseaudio? ( media-libs/libpulse )
-	raspberry-pi? (
-		|| (
-			media-libs/raspberrypi-userland-bin
-			media-libs/raspberrypi-userland
-		)
-	)
-	rubberband? ( media-libs/rubberband )
-	sdl? ( media-libs/libsdl2[sound,threads,video] )
-	sixel? ( media-libs/libsixel )
-	sndio? ( media-sound/sndio:= )
-	vaapi? ( media-libs/libva:=[X?,drm(+)?,wayland?] )
-	vdpau? ( x11-libs/libvdpau )
-	vulkan? (
-		media-libs/shaderc
-		media-libs/vulkan-loader[X?,wayland?]
-	)
-	wayland? (
-		dev-libs/wayland
-		dev-libs/wayland-protocols
-		x11-libs/libxkbcommon
-	)
-	zimg? ( media-libs/zimg )
-	zlib? ( sys-libs/zlib:= )"
-RDEPEND="
-	${COMMON_DEPEND}
-	selinux? ( sec-policy/selinux-mplayer )
-	tools? ( ${PYTHON_DEPS} )"
-DEPEND="
-	${COMMON_DEPEND}
-	X? ( x11-base/xorg-proto )
-	dvb? ( virtual/linuxtv-dvb-headers )
-	nvenc? ( media-libs/nv-codec-headers )
-	wayland? ( dev-libs/wayland-protocols )"
-BDEPEND="
-	${PYTHON_DEPS}
-	virtual/pkgconfig
-	cli? ( dev-python/docutils )
-	wayland? ( dev-util/wayland-scanner )"
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	sed -i "s/'rst2html/&.py/" meson.build || die
-}
-
-src_configure() {
-	if use !debug; then
-		if use test; then
-			einfo "Skipping -DNDEBUG due to USE=test"
-		else
-			append-cppflags -DNDEBUG # treated specially
-		fi
-	fi
-
-	if use raspberry-pi; then
-		append-cflags -I"${ESYSROOT}"/opt/vc/include
-		append-ldflags -L"${ESYSROOT}"/opt/vc/lib
-	fi
-
-	mpv_feature_multi() {
-		local use set
-		for use in ${1} ${2}; do
-			use ${use} || set=disabled
-		done
-		echo -D${3-${2}}=${set-enabled}
-	}
-
-	local emesonargs=(
-		$(meson_use cli cplayer)
-		$(meson_use libmpv)
-		$(meson_use test tests)
-
-		$(meson_feature cli html-build)
-		$(meson_feature cli manpage-build)
-		-Dpdf-build=disabled
-
-		-Dbuild-date=false
-
-		# misc options
-		$(meson_feature archive libarchive)
-		$(meson_feature bluray libbluray)
-		$(meson_feature cdda)
-		-Dcplugins=enabled
-		$(meson_feature dvb dvbin)
-		$(meson_feature dvd dvdnav)
-		$(meson_feature gamepad sdl2-gamepad)
-		$(meson_feature iconv)
-		$(meson_feature javascript)
-		-Dlibavdevice=enabled
-		$(meson_feature lcms lcms2)
-		-Dlua=$(usex lua "${ELUA}" disabled)
-		$(meson_feature rubberband)
-		-Dsdl2=$(use gamepad || use sdl && echo enabled || echo disabled) #857156
-		$(meson_feature uchardet)
-		-Dvapoursynth=disabled # only available in overlays
-		$(meson_feature zimg)
-		$(meson_feature zlib)
-
-		# audio output
-		$(meson_feature alsa)
-		$(meson_feature coreaudio)
-		$(meson_feature jack)
-		$(meson_feature openal)
-		$(meson_feature pipewire)
-		$(meson_feature pulseaudio pulse)
-		$(meson_feature sdl sdl2-audio)
-		$(meson_feature sndio)
-
-		# video output
-		$(meson_feature X x11)
-		$(meson_feature aqua cocoa)
-		$(meson_feature drm)
-		$(meson_feature drm gbm)
-		$(meson_feature jpeg)
-		$(meson_feature libcaca caca)
-		$(meson_feature libplacebo)
-		$(meson_feature mmal rpi-mmal)
-		$(meson_feature sdl sdl2-video)
-		$(meson_feature sixel)
-		$(meson_feature wayland)
-		$(meson_feature xv)
-
-		-Dgl=$(use egl || use libmpv || use opengl || use raspberry-pi &&
-			echo enabled || echo disabled)
-		$(meson_feature egl)
-		$(mpv_feature_multi egl X egl-x11)
-		$(mpv_feature_multi egl drm egl-drm)
-		$(mpv_feature_multi egl wayland egl-wayland)
-		$(meson_feature libmpv plain-gl)
-		$(mpv_feature_multi opengl X gl-x11)
-		$(mpv_feature_multi opengl aqua gl-cocoa)
-		$(meson_feature raspberry-pi rpi)
-
-		$(meson_feature vulkan)
-		$(meson_feature vulkan shaderc)
-
-		# hardware decoding
-		$(meson_feature nvenc cuda-hwaccel)
-		$(meson_feature nvenc cuda-interop)
-
-		$(meson_feature vaapi)
-		$(mpv_feature_multi vaapi X vaapi-x11)
-		$(mpv_feature_multi 'vaapi X' egl vaapi-x-egl)
-		$(mpv_feature_multi 'vaapi egl' drm vaapi-drm)
-		$(mpv_feature_multi 'vaapi egl' wayland vaapi-wayland)
-
-		$(meson_feature vdpau)
-		$(mpv_feature_multi vdpau opengl vdpau-gl-x11)
-
-		$(mpv_feature_multi aqua opengl videotoolbox-gl)
-	)
-
-	meson_src_configure
-}
-
-src_test() {
-	# https://github.com/mpv-player/mpv/blob/master/DOCS/man/options.rst#debugging
-	local tests=($("${BUILD_DIR}"/mpv --no-config --unittest=help | tail -n +2; assert))
-	(( ${#tests[@]} )) || die "failed to gather any tests"
-
-	local skip=(
-		all-simple
-
-		# fails on non-issue minor inconsistencies (bug #888639)
-		img_format
-		repack_sws
-	)
-
-	local test
-	for test in "${tests[@]}"; do
-		[[ ${test} == @($(IFS='|'; echo "${skip[*]}")) ]] ||
-			edo "${BUILD_DIR}"/mpv -v --no-config --unittest="${test}"
-	done
-}
-
-src_install() {
-	meson_src_install
-
-	if use lua; then
-		insinto /usr/share/${PN}
-		doins -r TOOLS/lua
-
-		if use cli && use lua_single_target_luajit; then
-			pax-mark -m "${ED}"/usr/bin/${PN}
-		fi
-	fi
-
-	if use tools; then
-		dobin TOOLS/{mpv_identify.sh,umpv}
-		newbin TOOLS/idet.sh mpv_idet.sh
-		python_fix_shebang "${ED}"/usr/bin/umpv
-	fi
-
-	if use cli; then
-		dodir /usr/share/doc/${PF}/html
-		mv "${ED}"/usr/share/doc/{mpv,${PF}/html}/mpv.html || die
-		mv "${ED}"/usr/share/doc/{mpv,${PF}/examples} || die
-	fi
-
-	local GLOBIGNORE=*/*build*:*/*policy*
-	dodoc RELEASE_NOTES DOCS/*.{md,rst}
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "URL support with USE=lua" net-misc/yt-dlp
-}