gentoo auto-resync : 18:10:2022 - 01:55:31

3 files changed, 291 insertions, 0 deletions

diff --git a/media-sound/Manifest.gz b/media-sound/Manifest.gz
index 15e197353b86..cc0cc3b561de 100644
--- a/media-sound/Manifest.gz
+++ b/media-sound/Manifest.gz
diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index 97e68c4af519..721f746c50f5 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,7 +1,9 @@
 AUX mpd-0.21.1.logrotate 120 BLAKE2B 2111ba897a77a766adf0827c4da7132d5315c7c13ba8e29d582f1030a902492945b0bad6781bbf551e83afd38b957e953215674c669aa2745c1dfa004b20d4b6 SHA512 4a610d4805c32989673d6295fdf4290dc29b11e5b5f3baa2aa957ef9334566f13fa1937e70dc6fe414277e6a026442e4c7e4b406aaf424b96b392da0200ec732
 AUX mpd-0.21.4.init 767 BLAKE2B 74879e5f52365f987ac53a8ee154f29b4d7f5287cb2a965b180b3ed4a17dcdc68acea5dbe0b3adc99869270fb93a3f68e6728fad0776b9ce500efb6206f4db3c SHA512 36f3246835d6476e8f4f26795f8148f46b04015141894cdf849bfdd04b1cf5aa7a3d5960587f00e2c7d0f71568ca20fee619b95415df4cd0e4978ce95ca5f897
 DIST mpd-0.22.11.tar.xz 737184 BLAKE2B b47dcbd1e01812b66c81f33a53fc0838ddb8b7a145763744d1cf1aacc7ca38e763b723498f3ab7360f49637bc80c0ada5a69c7d619f3cf167071a7bec2440d20 SHA512 c53d386d42c2360502aad5e7574ae5ff76a20df037696989f9e1700f9cffb88afdd329cce758067356c59308d0cbcf3ba3ccf6f013e2fcec54ddf08bd0212b43
+DIST mpd-0.23.10.tar.xz 774196 BLAKE2B 6b648971412a5f83fe9ff2694c030b451393c415de9c34cbea9894555ac7ea87c5a991edfdd41c7cd76511ae0680ecab35eb36ceae5e372900518c9cf5e9c55c SHA512 15e51a1fab2e187529141ebb25f0bb6cc9c2ad5127c1a9f4c40d1a944ed5bc4e7e76b26eb71f659ddd8a5ce448089e6d3dcf0c302ced8a4d08951ef1b1f09c49
 DIST mpd-0.23.9.tar.xz 774156 BLAKE2B 2c045c86ecbe2267d032ebfd4a18835e9b1323860eb348b047d0900a284f5457ca4f18fdd50ea2f678e07a63817b4e4e3245cf0d3948e1f14cf3539d47b314d2 SHA512 67db093e35693f79267f955463ecaa284773b5e47a38f1548a0d16c9ba82aecc3434fd805e224b78782c5978c07e16d26f7632823e536f5304f557985f028d6e
 EBUILD mpd-0.22.11-r1.ebuild 8426 BLAKE2B 74a9c64d3dcc4a4b97e338e8ba21415e56650e8bf10ba0ee23f555d34483af17094b96fbf6e68c770d6c46ba58962f4c063077f97d51f0ddb1840463d63f1bf0 SHA512 cc680e2be4a3819c0ce980f1335805cd8c8f67b25ec38d11d6e29feb323e1f1305243506c65da839e954ebed61dca3d52b77a17181c37e887666db125a664d2d
+EBUILD mpd-0.23.10.ebuild 7829 BLAKE2B a1c29a9d5873d2eac20a453fc6fb948a66e038a9791fd8fac073621970088977d84ab14fbc212ca79528d1122749b1cfe4f379548b8e8e847b12211627ce7a6b SHA512 27ea69e730cfe9ea5f4d6545e6b777f47a49b48755c82f8aefc13fd0778c08e7512905c8d5da561ec05f855118dff37c1337408548cee0c4b8a92ca5d2aa6450
 EBUILD mpd-0.23.9-r1.ebuild 7818 BLAKE2B 87f87088224425a560f4a2f259a85cec204f768f0bf40290e7945c48b51d62a6d138d87d4474c9fcf9c0d10f4ef369b5097d51c43696006d49926fa2faf25133 SHA512 3c0f67fdb303eecbf3157a73aa43e2fdea376c9556558353dfd185f3bc2c7719da55d9467b90ab2e9e23ec73b16d17e218eb89829baf9c46acbb509b240d1ef2
 MISC metadata.xml 2676 BLAKE2B 8ed7eaefb3d937019a36dd816d5472caf7d4c4209eb943dfdf1caef2f24cd7b530919cdd46999aac5402c929a8f4f437129edbfa78b301e6951e0b04338b7f30 SHA512 44110bae4781092d6fbdd972e8369efe45067e7ce5c505294f677a55b3f4bafb0746b17ef552f01b0b23d5453c10b5a4710d65f4cf9578184d3388b4b873ed0e
diff --git a/media-sound/mpd/mpd-0.23.10.ebuild b/media-sound/mpd/mpd-0.23.10.ebuild
new file mode 100644
index 000000000000..16cbd10a4647
--- /dev/null
+++ b/media-sound/mpd/mpd-0.23.10.ebuild
@@ -0,0 +1,289 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info meson systemd xdg
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
+	+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
+	jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
+	modplug mpg123 musepack +network nfs openal openmpt opus oss pipe pipewire pulseaudio qobuz
+	recorder samba selinux sid signalfd snapcast sndfile sndio soundcloud sqlite systemd
+	test twolame udisks vorbis wavpack webdav wildmidi upnp
+	zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pipewire pulseaudio snapcast sndio recorder"
+DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack opus openmpt flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	qobuz? ( curl soundcloud )
+	soundcloud? ( curl qobuz )
+	udisks? ( dbus )
+	upnp? ( curl expat )
+	webdav? ( curl expat )
+"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/mpd
+	dev-libs/libfmt:=
+	dev-libs/libpcre2
+	media-libs/libogg
+	sys-libs/liburing:=
+	alsa? (
+		media-libs/alsa-lib
+		media-sound/alsa-utils
+	)
+	ao? ( media-libs/libao:=[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile:= )
+	bzip2? ( app-arch/bzip2 )
+	cdio? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	chromaprint? ( media-libs/chromaprint )
+	curl? ( net-misc/curl )
+	dbus? ( sys-apps/dbus )
+	doc? ( dev-python/sphinx )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac:= )
+	fluidsynth? ( media-sound/fluidsynth )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? (
+		dev-libs/icu:=
+		virtual/libiconv
+	)
+	id3tag? ( media-libs/libid3tag:= )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	libsoxr? ( media-libs/soxr )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2.4.0 )
+	nfs? ( net-fs/libnfs )
+	openal? ( media-libs/openal )
+	openmpt? ( media-libs/libopenmpt )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	pipewire? ( media-video/pipewire:= )
+	qobuz? ( dev-libs/libgcrypt:0 )
+	samba? ( net-fs/samba )
+	selinux? ( sec-policy/selinux-mpd )
+	sid? ( || (
+		media-libs/libsidplay:2
+		media-libs/libsidplayfp
+	) )
+	snapcast? ( media-sound/snapcast )
+	sndfile? ( media-libs/libsndfile )
+	sndio? ( media-sound/sndio )
+	soundcloud? ( >=dev-libs/yajl-2:= )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd:= )
+	twolame? ( media-sound/twolame )
+	udisks? ( sys-fs/udisks:2 )
+	upnp? ( net-libs/libupnp:0 )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib:= )
+	zlib? ( sys-libs/zlib:= )"
+
+DEPEND="${RDEPEND}
+	dev-libs/boost:=
+	test? ( dev-cpp/gtest )"
+
+BDEPEND="virtual/pkgconfig"
+
+pkg_setup() {
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via ${EROOT}/etc/init.d/mpd, please make sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	 sed -i \
+		-e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+		-e 's:^#user.*$:user "mpd":' \
+		-e 's:^#bind_to_address.*any.*$:bind_to_address "localhost":' \
+		-e 's:^#bind_to_address.*$:bind_to_address "/var/lib/mpd/socket":' \
+		-e 's:^#music_directory.*$:music_directory "/var/lib/mpd/music":' \
+		-e 's:^#playlist_directory.*$:playlist_directory "/var/lib/mpd/playlists":' \
+		-e 's:^#db_file.*$:db_file "/var/lib/mpd/database":' \
+		-e 's:^#log_file.*$:log_file "/var/lib/mpd/log":' \
+		-e 's:^#pid_file.*$:pid_file "/var/lib/mpd/pid":' \
+		-e 's:^#state_file.*$:state_file "/var/lib/mpd/state":' \
+		doc/mpdconf.example || die
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature bzip2)
+		$(meson_feature cdio cdio_paranoia)
+		$(meson_feature chromaprint)
+		$(meson_use cue)
+		$(meson_feature curl)
+		$(meson_feature dbus)
+		$(meson_use eventfd)
+		$(meson_feature expat)
+		$(meson_feature icu)
+		$(meson_feature id3tag)
+		$(meson_use inotify)
+		-Dipv6=enabled
+		$(meson_feature cdio iso9660)
+		$(meson_feature libmpdclient)
+		$(meson_feature libsamplerate)
+		$(meson_feature mms)
+		$(meson_feature nfs)
+		$(meson_use signalfd)
+		$(meson_feature samba smbclient)
+		$(meson_feature libsoxr soxr)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test)
+		$(meson_feature udisks)
+		-Dupnp=$(usex upnp pupnp disabled)
+		$(meson_feature webdav)
+		-Dzeroconf=$(usex zeroconf avahi disabled)
+		$(meson_feature zlib)
+		$(meson_feature zip zzip)
+	)
+
+	emesonargs+=(
+		$(meson_feature alsa)
+		$(meson_feature ao)
+		$(meson_use fifo)
+		$(meson_feature jack)
+		$(meson_feature openal)
+		$(meson_feature oss)
+		$(meson_use pipe)
+		$(meson_feature pipewire)
+		$(meson_feature pulseaudio pulse)
+		$(meson_use recorder)
+		$(meson_use snapcast)
+		$(meson_feature sndio)
+	)
+
+	if use samba || use upnp; then
+		emesonargs+=( -Dneighbor=true )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/sidplay/builders"
+
+	if use network; then
+		emesonargs+=(
+			-Dshine=disabled
+			-Dshout=enabled
+			$(meson_feature vorbis vorbisenc)
+			-Dhttpd=true
+			$(meson_feature lame)
+			$(meson_feature twolame)
+			$(meson_use audiofile wave_encoder)
+		)
+	fi
+
+	emesonargs+=(
+		# media-libs/adplug is not packaged anymore
+		-Dadplug=disabled
+		$(meson_feature audiofile)
+		$(meson_feature faad)
+		$(meson_feature ffmpeg)
+		$(meson_feature flac)
+		$(meson_feature fluidsynth)
+		$(meson_feature gme)
+		$(meson_feature mad)
+		$(meson_feature mikmod)
+		$(meson_feature modplug)
+		$(meson_feature musepack mpcdec)
+		$(meson_feature mpg123)
+		$(meson_feature openmpt)
+		$(meson_feature opus)
+		$(meson_feature sid sidplay)
+		$(meson_feature sndfile)
+		$(meson_feature vorbis)
+		$(meson_feature wavpack)
+		$(meson_feature wildmidi)
+		$(meson_feature qobuz)
+		$(meson_feature soundcloud)
+
+		--libdir="/usr/$(get_libdir)"
+		$(meson_feature doc documentation)
+		-Dsolaris_output=disabled
+
+		-Ddatabase=true
+		-Ddsd=true
+		-Dio_uring=enabled
+		-Dtcp=true
+
+		-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+
+		$(meson_feature icu iconv)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
+
+	sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' "${ED}"/etc/mpd.conf || die "sed failed"
+
+	keepdir /var/lib/mpd
+	keepdir /var/lib/mpd/music
+	keepdir /var/lib/mpd/playlists
+
+	rm -r "${ED}"/usr/share/doc/mpd || die
+
+	fowners mpd:audio -R /var/lib/mpd
+}