gentoo auto-resync : 07:04:2023 - 17:30:27

1 files changed, 41 insertions, 0 deletions

diff --git a/media-libs/svt-av1/svt-av1-1.4.1.ebuild b/media-libs/svt-av1/svt-av1-1.4.1.ebuild
new file mode 100644
index 000000000000..03e68027a60a
--- /dev/null
+++ b/media-libs/svt-av1/svt-av1-1.4.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="Scalable Video Technology for AV1 (SVT-AV1 Encoder and Decoder)"
+HOMEPAGE="https://gitlab.com/AOMediaCodec/SVT-AV1"
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/AOMediaCodec/SVT-AV1.git"
+else
+	SRC_URI="https://gitlab.com/AOMediaCodec/SVT-AV1/-/archive/v${PV}/SVT-AV1-v${PV}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	S="${WORKDIR}/SVT-AV1-v${PV}"
+fi
+
+# Also see "Alliance for Open Media Patent License 1.0"
+LICENSE="BSD-2 Apache-2.0 BSD ISC LGPL-2.1+ MIT"
+SLOT="0"
+
+BDEPEND="amd64? ( dev-lang/yasm )"
+
+multilib_src_configure() {
+	append-ldflags -Wl,-z,noexecstack
+
+	local mycmakeargs=(
+		# Tests require linking against https://github.com/Cidana-Developers/aom/tree/av1-normative ?
+		# undefined reference to `ifd_inspect'
+		# https://github.com/Cidana-Developers/aom/commit/cfc5c9e95bcb48a5a41ca7908b44df34ea1313c0
+		# .. and https://gitlab.com/AOMediaCodec/SVT-AV1/-/blob/master/.gitlab/workflows/linux/.gitlab-ci.yml implies it's all quite manual?
+		-DBUILD_TESTING=OFF
+		-DCMAKE_OUTPUT_DIRECTORY="${BUILD_DIR}"
+	)
+
+	[[ ${ABI} != amd64 ]] && mycmakeargs+=( -DCOMPILE_C_ONLY=ON )
+
+	cmake_src_configure
+}