gentoo resync : 29.12.2022

1 files changed, 40 insertions, 0 deletions

diff --git a/media-libs/svt-av1/svt-av1-1.1.0.ebuild b/media-libs/svt-av1/svt-av1-1.1.0.ebuild
new file mode 100644
index 000000000000..cbcd3fc47133
--- /dev/null
+++ b/media-libs/svt-av1/svt-av1-1.1.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake-multilib flag-o-matic
+
+DESCRIPTION="Scalable Video Technology for AV1 (SVT-AV1 Encoder and Decoder)"
+HOMEPAGE="https://gitlab.com/AOMediaCodec/SVT-AV1"
+
+if [[ ${PV} = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/AOMediaCodec/SVT-AV1.git"
+else
+	SRC_URI="https://gitlab.com/AOMediaCodec/SVT-AV1/-/archive/v${PV}/SVT-AV1-v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	S="${WORKDIR}/SVT-AV1-v${PV}"
+fi
+
+# Also see "Alliance for Open Media Patent License 1.0"
+LICENSE="BSD-2 Apache-2.0 BSD ISC LGPL-2.1+ MIT"
+SLOT="0"
+
+BDEPEND="amd64? ( dev-lang/yasm )"
+
+multilib_src_configure() {
+	append-ldflags -Wl,-z,noexecstack
+
+	local mycmakeargs=(
+		# Tests require linking against https://github.com/Cidana-Developers/aom/tree/av1-normative ?
+		# undefined reference to `ifd_inspect'
+		# https://github.com/Cidana-Developers/aom/commit/cfc5c9e95bcb48a5a41ca7908b44df34ea1313c0
+		-DBUILD_TESTING=OFF
+		-DCMAKE_OUTPUT_DIRECTORY="${BUILD_DIR}"
+	)
+
+	[[ ${ABI} != amd64 ]] && mycmakeargs+=( -DCOMPILE_C_ONLY=ON )
+
+	cmake_src_configure
+}