gentoo resync : 19.01.2018

1 files changed, 85 insertions, 0 deletions

diff --git a/media-libs/opencolorio/opencolorio-1.1.0-r1.ebuild b/media-libs/opencolorio/opencolorio-1.1.0-r1.ebuild
new file mode 100644
index 000000000000..82a5b17acd9e
--- /dev/null
+++ b/media-libs/opencolorio/opencolorio-1.1.0-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Compatibility with Python 3 is declared by upstream, but it is broken in fact, check on bump
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit cmake-utils python-single-r1 vcs-snapshot
+
+DESCRIPTION="A color management framework for visual effects and animation"
+HOMEPAGE="http://opencolorio.org/"
+
+SRC_URI="https://github.com/imageworks/OpenColorIO/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 doc opengl python static-libs test"
+REQUIRED_USE="
+	doc? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	opengl? (
+		media-libs/lcms:2
+		media-libs/openimageio
+		media-libs/glew:=
+		media-libs/freeglut
+		virtual/opengl
+	)
+	python? ( ${PYTHON_DEPS} )
+	>=dev-cpp/yaml-cpp-0.5
+	dev-libs/tinyxml"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Restricting tests, bugs #439790 and #447908
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-compile-error-with-Lut1DOp.cpp.patch"
+	"${FILESDIR}/${P}-use-GNUInstallDirs-and-fix-cmake-install-location.patch"
+	"${FILESDIR}/${P}-remove-building-of-bundled-programs.patch"
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	use python && python_fix_shebang .
+}
+
+src_configure() {
+	# Missing features:
+	# - Truelight and Nuke are not in portage for now, so their support are disabled
+	# - Java bindings was not tested, so disabled
+	# Notes:
+	# - OpenImageIO is required for building ociodisplay and ocioconvert (USE opengl)
+	# - OpenGL, GLUT and GLEW is required for building ociodisplay (USE opengl)
+	local mycmakeargs=(
+		-DOCIO_BUILD_JNIGLUE=OFF
+		-DOCIO_BUILD_NUKE=OFF
+		-DOCIO_BUILD_SHARED=ON
+		-DOCIO_BUILD_STATIC=$(usex static-libs)
+		-DOCIO_STATIC_JNIGLUE=OFF
+		-DOCIO_BUILD_TRUELIGHT=OFF
+		-DUSE_EXTERNAL_LCMS=ON
+		-DUSE_EXTERNAL_TINYXML=ON
+		-DUSE_EXTERNAL_YAML=ON
+		-DOCIO_BUILD_DOCS=$(usex doc)
+		-DOCIO_BUILD_APPS=$(usex opengl)
+		-DOCIO_BUILD_PYGLUE=$(usex python)
+		-DOCIO_USE_SSE=$(usex cpu_flags_x86_sse2)
+		-DOCIO_BUILD_TESTS=$(usex test)
+		-DCMAKE_INSTALL_DOCDIR="share/doc/${PF}"
+		-DCMAKE_DISABLE_FIND_PACKAGE_LATEX=ON # They don't build
+	)
+	cmake-utils_src_configure
+}