reinit the tree, so we can have metadata

1 files changed, 44 insertions, 0 deletions

diff --git a/media-libs/libshout/libshout-2.4.1.ebuild b/media-libs/libshout/libshout-2.4.1.ebuild
new file mode 100644
index 000000000000..d91491a7d46f
--- /dev/null
+++ b/media-libs/libshout/libshout-2.4.1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="library for connecting and sending data to icecast servers"
+HOMEPAGE="http://www.icecast.org/"
+SRC_URI="http://downloads.xiph.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="libressl speex static-libs theora"
+
+RDEPEND=">=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}]
+	>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl )
+	speex? ( >=media-libs/speex-1.2_rc1-r1[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[${MULTILIB_USEDEP}] )
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-medialibs-20130224-r6
+		!app-emulation/emul-linux-x86-medialibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.4.1-underlinking.patch
+	eautoreconf
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable static-libs static) \
+		$(use_enable theora) \
+		$(use_enable speex)
+}
+
+multilib_src_install_all() {
+	dodoc README examples/example.c
+	rm -rf "${ED}"/usr/share/doc/${PN}
+	prune_libtool_files
+}