gentoo resync : 28.04.2018

1 files changed, 50 insertions, 0 deletions

diff --git a/media-libs/libmygpo-qt/libmygpo-qt-1.1.0.ebuild b/media-libs/libmygpo-qt/libmygpo-qt-1.1.0.ebuild
new file mode 100644
index 000000000000..5aae16cca567
--- /dev/null
+++ b/media-libs/libmygpo-qt/libmygpo-qt-1.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Qt/C++ library wrapping the gpodder.net webservice"
+HOMEPAGE="http://wiki.gpodder.org/wiki/Libmygpo-qt"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/gpodder/libmygpo-qt.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/gpodder/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="amd64 x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="test"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	test? ( dev-qt/qttest:5 )
+"
+
+PATCHES=( "${FILESDIR}/${P}-qt-5.11b3.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT4=OFF
+		-DMYGPO_BUILD_TESTS=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	# bug: 653312
+	local myctestargs=(
+		-E "(JsonCreatorTest-test)"
+	)
+
+	cmake-utils_src_test
+}