gentoo resync : 16.06.2018

2 files changed, 202 insertions, 0 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index f2570203987d..7e4b43044ab1 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -9,8 +9,10 @@ AUX gimp-2.8.22-cve-2017-17787.patch 1058 BLAKE2B baeffda42385b552709781a772ef59
 AUX gimp-2.8.22-cve-2017-17788.patch 1012 BLAKE2B 90bc17b66dd40426073a2581c20e68551b1c80378e055704d36ad56cc0a2b7448c847b847aacded6b8033ee86b3bb42e679845a46c65c1ea2d3af8c90aeb53f8 SHA512 82231c53664535c66d70b4e129b24afa31a50d465968f1012e20420ee71842435acf7d43de78cdac81602d80b89a927c03f9d60159c89c41d4b88e6851ed8acc
 AUX gimp-2.8.22-cve-2017-17789.patch 1245 BLAKE2B 14d519b8b024e51b452806b4acb6f00231e535ba3502875e8e90350e62c2cd0ff634ab1b38f16bb098670dd1e9d21c88aa64e19c3f81600acc7ea448e8f22b90 SHA512 f2f4aff0f0478356513a1f6da0732c5d0986ef1deb7b8e68bd283b7259887cf9a4d4785f00e48f03892cc86aa715b9764302640b2b891ab16617ef595ab779b8
 AUX gimp-2.9.8-cve-2017-17784.patch 1087 BLAKE2B 2398e735ccd7b0a5cc393f297b60d4a51038aeb146779268f78fb2f0a24ef912468510de2a0f640c5f905fe9959581686f55bccc022633b6f2a3a93ab3f12848 SHA512 5bc928860b2f2b53cc72c9c3caf6a532cf7e61b02e0716ee99a5166a07b01bdd46edfeae7bf6e333ce14ca11b5fcb963cbd42005e02f914d909431bf201dc6d5
+DIST gimp-2.10.2.tar.bz2 30863771 BLAKE2B a3525f7266ffe35be1daf973bee4ea107d9e7384e0c85a792f2fc69bd29fa8ee3d19409586b9b1e1bf36a1be4e30719c7ed945e5de9b7cb4be4f81be06ea1468 SHA512 6e351294e018a9f879993700355bdf5f10bccc6862604ae1950c4d235d32cdfcd6a0195b37377819adeef53ab3d24f32ed1de60cba6bafe58608ed0906a6fbcf
 DIST gimp-2.8.22.tar.bz2 20873278 BLAKE2B 673246fd2354f1cecc74bf389df698f594b7553cc88a1d2679ae410ad39923abae843dfe9623ec195b4f967b5eccd199769a6300bf028ae04b8df4932df11505 SHA512 84a78d428282538b606b3cd1ff571e52c3d828fceade171b2012bc1cdcb85919fc7734e7e6c45ed3a8683657fa580412b32c1b511b8a512172a8c1df930493e6
 DIST gimp-2.9.8.tar.bz2 26161474 BLAKE2B f00a58d33848a818a2cb3b74920b33156330a26423a2b567cd8372258f87b44ae1ad812f2b3ee9a093b919d022e8b71ef518d40b76ab94c616f9916b3d1effec SHA512 897092aa823961e6ed5dac47eaadd3a25c419364d6ca791987d99e495d0d4eba1d75e08c809dfa305e8feec9da606193b608e3470e0ef18fcfaa98ee8aedfe02
+EBUILD gimp-2.10.2.ebuild 5296 BLAKE2B 2ab4fe7a79d779f93d62f95a83fb754dca40dd6f8490e660766b722e216cc956a03ff73f118c24bd8d356925a9a688f093da23b81cf0a9de62d4ca3b209715a3 SHA512 c9c70bc7f093dbe9cad2d9324c0ce2269cb0aaa6c022590cb01538fb14ada2a1885151e4d610596b39ea5fa556abb4872a68a389fa0496c0186ae906c5c22e2c
 EBUILD gimp-2.8.22-r1.ebuild 5186 BLAKE2B 10a8d7c1074b14a4a7b79ec2e157a189597d16caaa1c225704f3c1c7a348cfaa53e711e7e8977f5eb21bf36d5bb2e465e4218e17402858484592c5c10a3b699b SHA512 ccfc14a7e358d66e100a5a4d2d47818a049eb93f64c01ec67f431e7113c4b23355420524413981d68ea4fd53545c9f126867201f0bebe57abfdf7ab3ee337d56
 EBUILD gimp-2.9.8-r1.ebuild 5734 BLAKE2B a176bcbabc8298b9e29b755f7d3dbdc26c3e6a77335e826762c6ce0273aeea38341378bc719df8e617a69bd6f8570442e46f92116119fd40043669201ecdcf50 SHA512 2778c83c74d87fd8492a1107b1b64aab8114ea167aaf8d7ca2290cec314ed9640d60096a04c7834b718159f242cf3e2a2c46c6293a03927d8084d834bc415ff5
 EBUILD gimp-9999.ebuild 5375 BLAKE2B 1a33e0b4106e98872afaf1c664b72a8b88c813575121d1538fd63fa3b52b6915868f1b432d85e51cf0800bc12aff6adaa8ad84015015e25616ef325703faeace SHA512 b9c0c738acebae699385af18cfdfd9f200a616cb48e565b40768f96d5bbce80914a81a1066de5116ba750d46a2ad3c3b51dc04604dd8e3eaf77aab3084dfd2e5
diff --git a/media-gfx/gimp/gimp-2.10.2.ebuild b/media-gfx/gimp/gimp-2.10.2.ebuild
new file mode 100644
index 000000000000..bbc9b522552f
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.10.2.ebuild
@@ -0,0 +1,200 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 )
+GNOME2_EAUTORECONF=yes
+
+MY_PV="${PV/_rc/-RC}"
+MY_P="${PN}-${MY_PV}"
+
+inherit versionator virtualx autotools gnome2 multilib python-single-r1 ltprune
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
+LICENSE="GPL-3 LGPL-3"
+SLOT="2"
+KEYWORDS="~amd64 ~x86"
+
+LANGS="am ar ast az be bg br ca ca@valencia cs csb da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka kk km kn ko lt lv mk ml ms my nb nds ne nl nn oc pa pl pt pt_BR ro ru rw si sk sl sr sr@latin sv ta te th tr tt uk vi xh yi zh_CN zh_HK zh_TW"
+IUSE="alsa aalib altivec aqua debug doc openexr gnome postscript jpeg2k cpu_flags_x86_mmx mng python smp cpu_flags_x86_sse udev vector-icons webp wmf xpm"
+
+RDEPEND=">=dev-libs/glib-2.54.2:2
+	>=dev-libs/atk-2.2.0
+	>=x11-libs/gtk+-2.24.10:2
+	>=x11-libs/gdk-pixbuf-2.31:2
+	>=x11-libs/cairo-1.12.2
+	>=x11-libs/pango-1.29.4
+	xpm? ( x11-libs/libXpm )
+	>=media-libs/freetype-2.1.7
+	>=media-libs/harfbuzz-0.9.19
+	>=media-libs/gexiv2-0.10.6
+	>=media-libs/libmypaint-1.3.0[gegl]
+	>=media-gfx/mypaint-brushes-1.3.0
+	>=media-libs/fontconfig-2.12.4
+	sys-libs/zlib
+	dev-libs/libxml2
+	dev-libs/libxslt
+	x11-themes/hicolor-icon-theme
+	>=media-libs/babl-0.1.50
+	>=media-libs/gegl-0.4.2:0.4[cairo]
+	>=dev-libs/glib-2.43
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	aqua? ( x11-libs/gtk-mac-integration )
+	gnome? ( gnome-base/gvfs )
+	virtual/jpeg:0
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2= )
+	>=media-libs/lcms-2.8:2
+	mng? ( media-libs/libmng )
+	openexr? ( >=media-libs/openexr-1.6.1 )
+	>=app-text/poppler-0.44[cairo]
+	>=app-text/poppler-data-0.4.7
+	>=media-libs/libpng-1.6.25:0=
+	python?	(
+		${PYTHON_DEPS}
+		>=dev-python/pygtk-2.10.4:2[${PYTHON_USEDEP}]
+		>=dev-python/pycairo-1.0.2[${PYTHON_USEDEP}]
+	)
+	>=media-libs/tiff-3.5.7:0
+	>=gnome-base/librsvg-2.40.6:2
+	webp? ( >=media-libs/libwebp-0.6.0 )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	net-libs/glib-networking[ssl]
+	x11-libs/libXcursor
+	sys-libs/zlib
+	app-arch/bzip2
+	>=app-arch/xz-utils-5.0.0
+	postscript? ( app-text/ghostscript-gpl )
+	udev? ( virtual/libgudev:= )"
+DEPEND="${RDEPEND}
+	>=dev-lang/perl-5.10.0
+	dev-libs/appstream-glib
+	dev-util/gtk-update-icon-cache
+	sys-apps/findutils
+	virtual/pkgconfig
+	>=dev-util/intltool-0.40.1
+	>=sys-devel/gettext-0.19
+	doc? ( >=dev-util/gtk-doc-1 )
+	>=sys-devel/libtool-2.2
+	>=sys-devel/automake-1.11
+	dev-util/gtk-doc-am"
+
+DOCS="AUTHORS ChangeLog* HACKING NEWS README*"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
+	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+
+	gnome2_src_prepare  # calls eautoreconf
+
+	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
+	fgrep -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+}
+
+src_configure() {
+	local myconf=(
+		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
+		GDBUS_CODEGEN="${EPREFIX}"/bin/false
+
+		--enable-default-binary
+		--disable-silent-rules
+
+		$(use_with !aqua x)
+		$(use_with aalib aa)
+		$(use_with alsa)
+		$(use_enable altivec)
+		--with-appdata-test
+		--with-bug-report-url=https://bugs.gentoo.org/
+		--without-webkit
+		$(use_with jpeg2k jpeg2000)
+		$(use_with postscript gs)
+		$(use_enable cpu_flags_x86_mmx mmx)
+		$(use_with mng libmng)
+		$(use_with openexr)
+		$(use_with webp)
+		--without-libheif
+		$(use_enable python)
+		$(use_enable smp mp)
+		$(use_enable cpu_flags_x86_sse sse)
+		$(use_with udev gudev)
+		$(use_with wmf)
+		--with-xmc
+		$(use_with xpm libxpm)
+		$(use_enable vector-icons)
+		--without-xvfb-run
+	)
+
+	gnome2_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+	addwrite /dev/dri/  # bug #574038
+	addwrite /dev/ati/  # bug 589198
+	addwrite /proc/mtrr  # bug 589198
+
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	gnome2_src_compile
+}
+
+_clean_up_locales() {
+	[[ -z ${LINGUAS+set} ]] && return
+	einfo "Cleaning up locales..."
+	for lang in ${LANGS}; do
+		has ${lang} ${LINGUAS} && {
+			einfo "- keeping ${lang}"
+			continue
+		}
+		rm -Rf "${ED%/}"/usr/share/locale/"${lang}"
+	done
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED%/}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	prune_libtool_files --all
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	local gimp_app_version=$(get_version_component_range 1-2)
+	mv "${ED%/}"/usr/share/man/man1/gimp-console{-${gimp_app_version},}.1 || die
+
+	_clean_up_locales
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+}