gentoo auto-resync : 01:09:2022 - 19:24:10

3 files changed, 331 insertions, 84 deletions

diff --git a/media-gfx/gimp/Manifest b/media-gfx/gimp/Manifest
index a97d789f1c4f..43ad184fa073 100644
--- a/media-gfx/gimp/Manifest
+++ b/media-gfx/gimp/Manifest
@@ -1,7 +1,9 @@
 AUX gimp-2.10_fix_test-appdata.patch 902 BLAKE2B 2b1a131d874d65422d8bdd44732b9843d89a570a1ea3c058cdb2a424a7791c686aa0e2ae2a0b472f333f2465f6e1a26750a532e9003933c5dffa1af32343c1dc SHA512 2983e8572f5e8113c9e2f564d31c1a5fe7e11ef273c50d2be739089124c6ec1a457da28222020bbd6015b2cbbcbf403b88d8660b9b35241800deb4fb3ad79067
 DIST gimp-2.10.32.tar.bz2 31397425 BLAKE2B 3887e2e29ebfd5dcfa671a9d1549180d11bd5e3656c6854ff4130c6c6e6ca9479df075981e09b9b6b97e47dd1fcd939fea726ca09c08c040ebd1998d80e61771 SHA512 aa999c1ec388154965f84d995a9b5517e9c38608d03a0d0bb6ec9fa55de946f9da106e7d6f7c02052b61d2b6806e7a378e786539f0de5b5ffaa2fcd1bbd9c7f1
 DIST gimp-2.99.10.tar.bz2 26782056 BLAKE2B 103e7fa2d04b1989e59fb03964a122891831d122cdc6dd3b7637f06cff28310e12d9a79678ac477b56728f4ceb53292001c53f026e94be417db76dd7e14740ab SHA512 898c1e1ffd2270ccc965db9a8263e04d95455535361b47f92256b4028808e1e91eb1924cf6cef7ff9e988194ebbc67535bd9cfbf0243159824e58551a2b91ba3
+DIST gimp-2.99.12.tar.xz 24282140 BLAKE2B 2174e1d50941071ea6e96f0e3f315484867aa90ae06cbcdc7b30914f959c1a15a7e7ea34ba22ce09a973b29acf1277e3a4519d744140c3fcabc59f31dc3ebf43 SHA512 4b87dd40eccc39c560e69a90b4042b1b19506e9ae52e5079ace442325b54bf7c47477662197da8f7655c12aad16e08bae60d11cf269684b8aa291e978d246917
 EBUILD gimp-2.10.32.ebuild 5649 BLAKE2B ed0b99850166d7d0a464d16aa74faa18aea2a92e5dab1ae8680bf813e9eed1323a2fb042c08b3a6fec416fa9e5cc83c14591e785931ecf7ffaf5ab3a404cc271 SHA512 ed4a2a0a1f4c3eb0188d97cc8527996cfe5c18279cbbe7577c14435229261aeb7e77d7ec87b4295fdb9e298bb7e91d767f5bc5048ffaa9e6cb21d0b95bc4f5fd
 EBUILD gimp-2.99.10-r1.ebuild 6613 BLAKE2B 2883d26916fa9a54d5037c7524f141b47faeba5816dcf086e549f0c5eadcd607e591c655bce0ae8322ba9d69f14f20a7f816ad732fc7cc0ba063715e3286e1d0 SHA512 17e79ffad687a53ce0da2280c628b2309245aff2935997a6817e2297435291992216b934ece01bdbef69633744740849faf1115e6230e92053ef6c19621835f9
-EBUILD gimp-9999.ebuild 6713 BLAKE2B 9b6170cb161ff5f4db607dd7bb76e3bc7f30c696e90596d091b55a23172ad4bbe9d30d159cff1126e0a961bb7360eca103d949579b863537a80617a85ab33352 SHA512 e0520374ff0bf3670a75fed61a188dd69881a140d283df87796c384ef113a92454f4b4946e7dfd41da07248841484faac4c50aa29fa8bf5d24841006f668fd3f
+EBUILD gimp-2.99.12.ebuild 6801 BLAKE2B 8e3539c9d455cf4d440aacfd5917a560c31c84158087326f69d84017b758945f36933ffa07ad7a40701f6462086043eb3f391f47d71846c752dde391708da2c3 SHA512 a2371421e9c4aac2b44ea03eefeba2e8f53dd808491d5b7d862aad2e96db1bb52af51a28de6e27532622a6a3744c9b566f18a89a5ef3967a343b60841fda7694
+EBUILD gimp-9999.ebuild 6714 BLAKE2B 027a7b3582dc93f251c6efe6150990e5a13ed4173f6923717052b9fbd28494d031af1cabb7a8bd3d6cd2b26dd403dd8d4cf1ba2ca81491017c83903b667cd54b SHA512 dda911c6d56ec16cd67387beb4199a47d9d9e7d081afb7b6cf44b2d92280f5a2e57be1dd1ad91a74a3b984ce7eb98e86dd476a8ae074ef2fb629e9d6de582536
 MISC metadata.xml 646 BLAKE2B 167cb95fb064b2470cdbb6b625f7d6e24aacac57081a1177fdc9e878b4cf1a20c6b86a7e621530b45bc7db5f07e173a47829fd5be9dde6f9b9fcf54a39f24236 SHA512 9f6501b6a14f860be69e29baaace61fe4c964413b8c43882bf06144406333f4d69d6adaa315503dc83fbdb467cd47e3d752ed6abe4b78bd5cb32fb9f3be1ac1d
diff --git a/media-gfx/gimp/gimp-2.99.12.ebuild b/media-gfx/gimp/gimp-2.99.12.ebuild
new file mode 100644
index 000000000000..5a97b3f4724a
--- /dev/null
+++ b/media-gfx/gimp/gimp-2.99.12.ebuild
@@ -0,0 +1,250 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( luajit )
+PYTHON_COMPAT=( python3_{8..11} )
+VALA_MIN_API_VERSION="0.50"
+VALA_USE_DEPEND=vapigen
+
+inherit lua-single meson python-single-r1 vala xdg
+
+DESCRIPTION="GNU Image Manipulation Program"
+HOMEPAGE="https://www.gimp.org/"
+SRC_URI="mirror://gimp/v2.99/${P}.tar.xz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0/3"
+
+IUSE="X aalib alsa doc gnome heif javascript jpeg2k jpegxl lua mng openexr postscript python test udev unwind vala vector-icons webp wmf xpm"
+REQUIRED_USE="
+	lua? ( ${LUA_REQUIRED_USE} )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+RESTRICT="!test? ( test )"
+
+# media-libs/{babl,gegl} are required to be built with USE="introspection"
+# to fix the compilation checking of /usr/share/gir-1.0/{Babl-0.1gir,Gegl-0.4.gir}
+COMMON_DEPEND="
+	>=app-text/poppler-0.90.1[cairo]
+	>=app-text/poppler-data-0.4.9
+	>=dev-libs/appstream-glib-0.7.16
+	>=dev-libs/atk-2.34.1
+	>=dev-libs/glib-2.68.0:2
+	>=dev-libs/json-glib-1.4.4
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/librsvg-2.40.21:2
+	>=media-gfx/mypaint-brushes-2.0.2:=
+	>=media-libs/babl-0.1.96[introspection,lcms,vala?]
+	>=media-libs/fontconfig-2.12.6
+	>=media-libs/freetype-2.10.2
+	>=media-libs/gegl-0.4.38:0.4[cairo,introspection,lcms,vala?]
+	>=media-libs/gexiv2-0.14.0
+	>=media-libs/harfbuzz-2.6.5:=
+	>=media-libs/lcms-2.9:2
+	media-libs/libjpeg-turbo
+	>=media-libs/libmypaint-1.6.1:=
+	>=media-libs/libpng-1.6.37:0=
+	>=media-libs/tiff-4.1.0:0
+	net-libs/glib-networking[ssl]
+	sys-libs/zlib
+	>=x11-libs/cairo-1.16.0
+	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
+	>=x11-libs/gtk+-3.24.16:3[introspection]
+	>=x11-libs/pango-1.44.7
+	aalib? ( media-libs/aalib )
+	alsa? ( >=media-libs/alsa-lib-1.0.0 )
+	heif? ( >=media-libs/libheif-1.9.1:= )
+	javascript? ( dev-libs/gjs )
+	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
+	jpegxl? ( >=media-libs/libjxl-0.6.1:= )
+	lua? (
+		${LUA_DEPS}
+		$(lua_gen_cond_dep '
+			dev-lua/lgi[${LUA_USEDEP}]
+		')
+	)
+	mng? ( media-libs/libmng:= )
+	openexr? ( >=media-libs/openexr-2.3.0:= )
+	postscript? ( app-text/ghostscript-gpl )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+		')
+	)
+	udev? ( >=dev-libs/libgudev-167:= )
+	unwind? ( >=sys-libs/libunwind-1.1.0:= )
+	webp? ( >=media-libs/libwebp-0.6.0:= )
+	wmf? ( >=media-libs/libwmf-0.2.8 )
+	X? ( x11-libs/libXcursor )
+	xpm? ( x11-libs/libXpm )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	x11-themes/hicolor-icon-theme
+	gnome? ( gnome-base/gvfs )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	test? ( x11-misc/xvfb-run )
+	vala? ( $(vala_depend) )
+"
+
+# TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
+BDEPEND="
+	>=dev-lang/perl-5.30.3
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.21
+	doc? (
+		app-text/yelp-tools
+		dev-libs/gobject-introspection[doctool]
+		dev-util/gi-docgen
+	)
+	virtual/pkgconfig
+"
+
+DOCS=( "AUTHORS" "devel-docs/CODING_STYLE.md" "devel-docs/HACKING.md" "NEWS" "README" "README.i18n" )
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' meson.build || die #737794
+
+	# Fix (typo) MMX and SSE support detection
+	sed -i -e "s/'-mmx'/'-mmmx'/" -e "s/'-sse'/'-msse'/" meson.build || die
+
+	# Fix Gimp  and GimpUI devel doc installation paths
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp/meson.build || die
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp-ui/meson.build || die
+
+	# Fix pygimp.interp python implementation path.
+	# Meson @PYTHON_PATH@ use sandbox path e.g.:
+	# '/var/tmp/portage/media-gfx/gimp-2.99.12/temp/python3.10/bin/python3'
+	sed -i -e 's:@PYTHON_PATH@:'${EPYTHON}':' plug-ins/python/pygimp.interp.in || die
+}
+
+_adjust_sandbox() {
+	# Bugs #569738 and #591214
+	local nv
+	for nv in /dev/nvidia-uvm /dev/nvidiactl /dev/nvidia{0..9} ; do
+		# We do not check for existence as they may show up later
+		# https://bugs.gentoo.org/show_bug.cgi?id=569738#c21
+		addwrite "${nv}"
+	done
+
+	addwrite /dev/dri/  # bugs #574038 and #684886
+	addwrite /dev/ati/  # bug #589198
+	addwrite /proc/mtrr  # bug #589198
+}
+
+src_configure() {
+	_adjust_sandbox
+
+	use vala && vala_setup
+
+	local emesonargs=(
+		-Denable-default-bin=true
+
+		-Dcheck-update=no
+		-Denable-multiproc=true
+		-Dappdata-test=disabled
+		-Dbug-report-url=https://bugs.gentoo.org/
+		-Dlibbacktrace=false
+		-Dwebkit-unmaintained=false
+		$(meson_feature aalib aa)
+		$(meson_feature alsa)
+		$(meson_feature doc gi-docgen)
+		$(meson_feature heif)
+		$(meson_feature jpeg2k jpeg2000)
+		$(meson_feature jpegxl jpeg-xl)
+		$(meson_feature mng)
+		$(meson_feature openexr)
+		$(meson_feature postscript ghostscript)
+		$(meson_feature test headless-tests)
+		$(meson_feature udev gudev)
+		$(meson_feature vala vala-plugins)
+		$(meson_feature webp)
+		$(meson_feature wmf)
+		$(meson_feature X xcursor)
+		$(meson_feature xpm)
+		$(meson_use doc g-ir-doc)
+		$(meson_use javascript)
+		$(meson_use lua)
+		$(meson_use python)
+		$(meson_use unwind libunwind)
+		$(meson_use vector-icons)
+	)
+
+	meson_src_configure
+}
+
+src_compile() {
+	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
+	meson_src_compile
+}
+
+# for https://bugs.gentoo.org/664938
+_rename_plugins() {
+	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
+	local prename=gimp-org-
+	(
+		cd "${ED}"/usr/$(get_libdir)/gimp/2.99/plug-ins || exit 1
+		for plugin_slash in $(ls -d1 */); do
+			plugin=${plugin_slash%/}
+			if [[ -f ${plugin}/${plugin} ]]; then
+				# NOTE: Folder and file name need to match for Gimp to load that plug-in
+				#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
+				mv ${plugin}/{,${prename}}${plugin} || exit 1
+				mv {,${prename}}${plugin} || exit 1
+			fi
+		done
+	)
+}
+
+src_install() {
+	meson_src_install
+
+	if use python; then
+		python_optimize
+	fi
+
+	# Workaround for bug #321111 to give GIMP the least
+	# precedence on PDF documents by default
+	mv "${ED}"/usr/share/applications/{,zzz-}gimp.desktop || die
+
+	find "${D}" -name '*.la' -type f -delete || die
+
+	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
+	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
+
+	# Create symlinks for Gimp exec in /usr/bin
+	dosym "${ESYSROOT}"/usr/bin/gimp-2.99 /usr/bin/gimp
+	dosym "${ESYSROOT}"/usr/bin/gimp-console-2.99 /usr/bin/gimp-console
+	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
+	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-2.99 /usr/bin/gimp-test-clipboard
+	dosym "${ESYSROOT}"/usr/bin/gimptool-2.99 /usr/bin/gimptool
+
+	_rename_plugins || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+}
diff --git a/media-gfx/gimp/gimp-9999.ebuild b/media-gfx/gimp/gimp-9999.ebuild
index 0f655ffb58a9..04935142f351 100644
--- a/media-gfx/gimp/gimp-9999.ebuild
+++ b/media-gfx/gimp/gimp-9999.ebuild
@@ -4,12 +4,11 @@
 EAPI=8
 
 LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{8..10} )
-GNOME2_EAUTORECONF=yes
+PYTHON_COMPAT=( python3_{8..11} )
 VALA_MIN_API_VERSION="0.50"
 VALA_USE_DEPEND=vapigen
 
-inherit git-r3 gnome2 lua-single python-single-r1 toolchain-funcs vala virtualx
+inherit git-r3 lua-single meson python-single-r1 vala xdg
 
 DESCRIPTION="GNU Image Manipulation Program"
 HOMEPAGE="https://www.gimp.org/"
@@ -18,7 +17,7 @@ SRC_URI=""
 LICENSE="GPL-3 LGPL-3"
 SLOT="0/3"
 
-IUSE="aalib alsa aqua doc gnome heif javascript jpeg2k jpegxl lua mng openexr postscript python udev unwind vala vector-icons webp wmf xpm cpu_flags_ppc_altivec cpu_flags_x86_mmx cpu_flags_x86_sse"
+IUSE="X aalib alsa doc gnome heif javascript jpeg2k jpegxl lua mng openexr postscript python test udev unwind vala vector-icons webp wmf xpm"
 REQUIRED_USE="
 	lua? ( ${LUA_REQUIRED_USE} )
 	python? ( ${PYTHON_REQUIRED_USE} )
@@ -39,10 +38,10 @@ COMMON_DEPEND="
 	dev-libs/libxslt
 	>=gnome-base/librsvg-2.40.21:2
 	>=media-gfx/mypaint-brushes-2.0.2:=
-	>=media-libs/babl-0.1.92[introspection,lcms,vala?]
+	>=media-libs/babl-0.1.96[introspection,lcms,vala?]
 	>=media-libs/fontconfig-2.12.6
 	>=media-libs/freetype-2.10.2
-	>=media-libs/gegl-0.4.36:0.4[cairo,introspection,lcms,vala?]
+	>=media-libs/gegl-0.4.38:0.4[cairo,introspection,lcms,vala?]
 	>=media-libs/gexiv2-0.14.0
 	>=media-libs/harfbuzz-2.6.5:=
 	>=media-libs/lcms-2.9:2
@@ -55,11 +54,9 @@ COMMON_DEPEND="
 	>=x11-libs/cairo-1.16.0
 	>=x11-libs/gdk-pixbuf-2.40.0:2[introspection]
 	>=x11-libs/gtk+-3.24.16:3[introspection]
-	x11-libs/libXcursor
 	>=x11-libs/pango-1.44.7
 	aalib? ( media-libs/aalib )
 	alsa? ( >=media-libs/alsa-lib-1.0.0 )
-	aqua? ( >=x11-libs/gtk-mac-integration-2.0.0 )
 	heif? ( >=media-libs/libheif-1.9.1:= )
 	javascript? ( dev-libs/gjs )
 	jpeg2k? ( >=media-libs/openjpeg-2.3.1:2= )
@@ -83,6 +80,7 @@ COMMON_DEPEND="
 	unwind? ( >=sys-libs/libunwind-1.1.0:= )
 	webp? ( >=media-libs/libwebp-0.6.0:= )
 	wmf? ( >=media-libs/libwmf-0.2.8 )
+	X? ( x11-libs/libXcursor )
 	xpm? ( x11-libs/libXpm )
 "
 
@@ -94,20 +92,22 @@ RDEPEND="
 
 DEPEND="
 	${COMMON_DEPEND}
-	>=dev-lang/perl-5.30.3
-	dev-util/gdbus-codegen
-	dev-util/gtk-update-icon-cache
-	>=dev-util/intltool-0.51.0
-	>=sys-devel/autoconf-2.54
-	>=sys-devel/automake-1.11
-	>=sys-devel/gettext-0.21
-	>=sys-devel/libtool-2.4.6
-	doc? ( dev-util/gi-docgen )
+	test? ( x11-misc/xvfb-run )
 	vala? ( $(vala_depend) )
 "
 
 # TODO: there are probably more atoms in DEPEND which should be in BDEPEND now
-BDEPEND="virtual/pkgconfig"
+BDEPEND="
+	>=dev-lang/perl-5.30.3
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.21
+	doc? (
+		app-text/yelp-tools
+		dev-libs/gobject-introspection[doctool]
+		dev-util/gi-docgen
+	)
+	virtual/pkgconfig
+"
 
 DOCS=( "AUTHORS" "devel-docs/CODING_STYLE.md" "devel-docs/HACKING.md" "NEWS" "README" "README.i18n" )
 
@@ -120,19 +120,18 @@ pkg_setup() {
 }
 
 src_prepare() {
-#	sed -i -e '/validate/s:${GIMP_TESTING:--no-net ${GIMP_TESTING:' desktop/test-appdata.sh.in || die # Bug 685210 (and duplicate 691070)
-
-	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' configure.ac || die #737794
-
-	sed -i -e 's/== "xquartz"/= "xquartz"/' configure.ac || die #494864
-	sed 's:-DGIMP_DISABLE_DEPRECATED:-DGIMP_protect_DISABLE_DEPRECATED:g' -i configure.ac || die #615144
+	default
 
-	gnome2_src_prepare  # calls eautoreconf
+	sed -i -e 's/mypaint-brushes-1.0/mypaint-brushes-2.0/' meson.build || die #737794
 
-	sed 's:-DGIMP_protect_DISABLE_DEPRECATED:-DGIMP_DISABLE_DEPRECATED:g' -i configure || die #615144
-	grep -F -q GIMP_DISABLE_DEPRECATED configure || die #615144, self-test
+	# Fix Gimp  and GimpUI devel doc installation paths
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp/meson.build || die
+	sed -i -e "s/'doc'/'gtk-doc'/" devel-docs/reference/gimp-ui/meson.build || die
 
-	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
+	# Fix pygimp.interp python implementation path.
+	# Meson @PYTHON_PATH@ use sandbox path e.g.:
+	# '/var/tmp/portage/media-gfx/gimp-2.99.12/temp/python3.10/bin/python3'
+	sed -i -e 's:@PYTHON_PATH@:'${EPYTHON}':' plug-ins/python/pygimp.interp.in || die
 }
 
 _adjust_sandbox() {
@@ -154,78 +153,67 @@ src_configure() {
 
 	use vala && vala_setup
 
-	local myconf=(
-		GEGL="${EPREFIX}"/usr/bin/gegl-0.4
-		GDBUS_CODEGEN="${EPREFIX}"/usr/bin/gdbus-codegen
-
-		--enable-default-binary
-
-		--disable-check-update
-		--enable-mp
-		--with-bug-report-url=https://bugs.gentoo.org/
-		--with-pdbgen
-		--with-xmc
-		--without-appdata-test
-		--without-libbacktrace
-		--without-webkit
-		--without-xvfb-run
-		$(use_enable cpu_flags_ppc_altivec altivec)
-		$(use_enable cpu_flags_x86_mmx mmx)
-		$(use_enable cpu_flags_x86_sse sse)
-		$(use_enable doc gi-docgen)
-		$(use_enable vector-icons)
-		$(use_with aalib aa)
-		$(use_with alsa)
-		$(use_with !aqua x)
-		$(use_with heif libheif)
-		$(use_with javascript)
-		$(use_with jpeg2k jpeg2000)
-		$(use_with jpegxl)
-		$(use_with lua)
-		$(use_with mng libmng)
-		$(use_with openexr)
-		$(use_with postscript gs)
-		$(use_with python)
-		$(use_with udev gudev)
-		$(use_with unwind libunwind)
-		$(use_with vala)
-		$(use_with webp)
-		$(use_with wmf)
-		$(use_with xpm libxpm)
+	local emesonargs=(
+		-Denable-default-bin=true
+
+		-Dcheck-update=no
+		-Denable-multiproc=true
+		-Dappdata-test=disabled
+		-Dbug-report-url=https://bugs.gentoo.org/
+		-Dlibbacktrace=false
+		-Dwebkit-unmaintained=false
+		$(meson_feature aalib aa)
+		$(meson_feature alsa)
+		$(meson_feature doc gi-docgen)
+		$(meson_feature heif)
+		$(meson_feature jpeg2k jpeg2000)
+		$(meson_feature jpegxl jpeg-xl)
+		$(meson_feature mng)
+		$(meson_feature openexr)
+		$(meson_feature postscript ghostscript)
+		$(meson_feature test headless-tests)
+		$(meson_feature udev gudev)
+		$(meson_feature vala vala-plugins)
+		$(meson_feature webp)
+		$(meson_feature wmf)
+		$(meson_feature X xcursor)
+		$(meson_feature xpm)
+		$(meson_use doc g-ir-doc)
+		$(meson_use javascript)
+		$(meson_use lua)
+		$(meson_use python)
+		$(meson_use unwind libunwind)
+		$(meson_use vector-icons)
 	)
 
-	gnome2_src_configure "${myconf[@]}"
+	meson_src_configure
 }
 
 src_compile() {
 	export XDG_DATA_DIRS="${EPREFIX}"/usr/share  # bug 587004
-	gnome2_src_compile
+	meson_src_compile
 }
 
 # for https://bugs.gentoo.org/664938
 _rename_plugins() {
 	einfo 'Renaming plug-ins to not collide with pre-2.10.6 file layout (bug #664938)...'
-	local prepend=gimp-org-
+	local prename=gimp-org-
 	(
 		cd "${ED}"/usr/$(get_libdir)/gimp/2.99/plug-ins || exit 1
 		for plugin_slash in $(ls -d1 */); do
-		    plugin=${plugin_slash%/}
-		    if [[ -f ${plugin}/${plugin} ]]; then
-			# NOTE: Folder and file name need to match for Gimp to load that plug-in
-			#       so "file-svg/file-svg" becomes "${prepend}file-svg/${prepend}file-svg"
-			mv ${plugin}/{,${prepend}}${plugin} || exit 1
-			mv {,${prepend}}${plugin} || exit 1
-		    fi
+			plugin=${plugin_slash%/}
+			if [[ -f ${plugin}/${plugin} ]]; then
+				# NOTE: Folder and file name need to match for Gimp to load that plug-in
+				#       so "file-svg/file-svg" becomes "${prename}file-svg/${prename}file-svg"
+				mv ${plugin}/{,${prename}}${plugin} || exit 1
+				mv {,${prename}}${plugin} || exit 1
+			fi
 		done
 	)
 }
 
-src_test() {
-	virtx emake check
-}
-
 src_install() {
-	gnome2_src_install
+	meson_src_install
 
 	if use python; then
 		python_optimize
@@ -240,13 +228,20 @@ src_install() {
 	# Prevent dead symlink gimp-console.1 from downstream man page compression (bug #433527)
 	mv "${ED}"/usr/share/man/man1/gimp-console{-*,}.1 || die
 
+	# Create symlinks for Gimp exec in /usr/bin
+	dosym "${ESYSROOT}"/usr/bin/gimp-2.99 /usr/bin/gimp
+	dosym "${ESYSROOT}"/usr/bin/gimp-console-2.99 /usr/bin/gimp-console
+	dosym "${ESYSROOT}"/usr/bin/gimp-script-fu-interpreter-3.0 /usr/bin/gimp-script-fu-interpreter
+	dosym "${ESYSROOT}"/usr/bin/gimp-test-clipboard-2.99 /usr/bin/gimp-test-clipboard
+	dosym "${ESYSROOT}"/usr/bin/gimptool-2.99 /usr/bin/gimptool
+
 	_rename_plugins || die
 }
 
 pkg_postinst() {
-	gnome2_pkg_postinst
+	xdg_desktop_database_update
 }
 
 pkg_postrm() {
-	gnome2_pkg_postrm
+	xdg_desktop_database_update
 }