gentoo auto-resync : 07:03:2024 - 01:06:26

1 files changed, 55 insertions, 0 deletions

diff --git a/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.11.ebuild b/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.11.ebuild
new file mode 100644
index 000000000000..4f94e1575de1
--- /dev/null
+++ b/kde-plasma/kde-gtk-config/kde-gtk-config-5.27.11.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="Syncs KDE Plasma theme settings to GTK applications"
+HOMEPAGE="https://invent.kde.org/plasma/kde-gtk-config"
+
+LICENSE="GPL-3"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	dev-libs/glib:2
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	gnome-base/gsettings-desktop-schemas
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-plasma/kdecoration-${PVCUT}:5
+	x11-libs/gtk+:3[X]
+"
+RDEPEND="${DEPEND}
+	>=kde-plasma/kde-cli-tools-${PVCUT}:*
+	x11-misc/xsettingsd
+"
+BDEPEND="dev-lang/sassc"
+
+PATCHES=( "${FILESDIR}/${P}-revert-6b3865a7.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDATA_INSTALL_DIR="${EPREFIX}/usr/share"
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	elog "If you notice missing icons in your GTK applications, you may have to install"
+	elog "the corresponding themes for GTK. A good guess would be x11-themes/oxygen-gtk"
+	elog "for example."
+}