gentoo auto-resync : 27:11:2022 - 19:17:39

1 files changed, 58 insertions, 0 deletions

diff --git a/kde-misc/colord-kde/colord-kde-22.11.90.ebuild b/kde-misc/colord-kde/colord-kde-22.11.90.ebuild
new file mode 100644
index 000000000000..da1281f177c7
--- /dev/null
+++ b/kde-misc/colord-kde/colord-kde-22.11.90.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_CATEGORY=graphics
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org
+
+DESCRIPTION="Provides interfaces and session daemon to colord"
+HOMEPAGE="https://invent.kde.org/graphics/colord-kde"
+
+LICENSE="GPL-2+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="X"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	media-libs/lcms:2
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+		x11-libs/libxcb
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-plasma/kde-cli-tools:5
+	x11-misc/colord
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package X X11)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+	if ! has_version "gnome-extra/gnome-color-manager"; then
+		elog "You may want to install gnome-extra/gnome-color-manager to add support for"
+		elog "colorhug calibration devices."
+	fi
+}