gentoo resync : 18.08.2019

1 files changed, 50 insertions, 0 deletions

diff --git a/kde-apps/kwrite/kwrite-19.08.0.ebuild b/kde-apps/kwrite/kwrite-19.08.0.ebuild
new file mode 100644
index 000000000000..41a4ad5e9a3d
--- /dev/null
+++ b/kde-apps/kwrite/kwrite-19.08.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+KMNAME="kate"
+KDE_HANDBOOK="optional"
+inherit kde5
+
+DESCRIPTION="KDE simple text editor"
+HOMEPAGE="https://kde.org/applications/utilities/kwrite"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtwidgets)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	kde5_src_prepare
+	# delete colliding kate translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "kwrite*" -delete || die
+		rm -rf po/*/docs/kate* || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_addons=FALSE
+		-DBUILD_kate=FALSE
+	)
+	use handbook && mycmakeargs+=( -DBUILD_katepart=FALSE )
+
+	kde5_src_configure
+}