Revert "gentoo resync : 24.03.2019"

This reverts commit aa3411e241a201d53a2689766fe419f2756819f3.

3 files changed, 125 insertions, 2 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index ed9cfd926a46..92a99e438ba5 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,3 +1,5 @@
+DIST k3b-18.08.3.tar.xz 10598316 BLAKE2B 7758f1f037834728edaddb38068a4cb1bc32fe4953c89a14c735592d3842ec8ec28044e4764fd76a1cc116c060702167fe8c043f6121d7c85654996a3f97d26a SHA512 5479f29770363a14f2f7b9ea7e14c628b031f7744bd459314c502c138daec4728d65c7a4193364aaab7ee9e2516583f00647e07f05acd959c48a749b1ee84ef7
 DIST k3b-18.12.3.tar.xz 10593176 BLAKE2B 80f454912378ecdca0884d0c4720f245e2dadb6f6c579674de65a4fe72d0292c1ebf29913939a523f82ff8438b58541d2abd31c8f0bb0c7712281780187bfb02 SHA512 73b8b3a5b7fe081604ad7c5fb11cf539bd41353836e06e1c8f54bf5375122a2187e33e609a111524693d63087c53706b7b14a5e52cdc7fcb46114cb5ab223449
-EBUILD k3b-18.12.3.ebuild 3355 BLAKE2B 941cb522017dde3ab91ef368cadfc2cbfb2021fdf9a241c3447177edb6ed7ff22c8520dca0b2720092f15c7b1e41b3e80b072e493b1665b3b489a15c5fdde669 SHA512 a9d0024cc666cf18764a03a28b5fd6fd3ca597384a426c7dc3402539a632faa0a6879dad826b6474e00c5e59cc8961068f210d645735d4845d8a73832b45ac69
+EBUILD k3b-18.08.3.ebuild 3331 BLAKE2B fcb2079f9d6c00436b4d54a34643ac59887b1d6cbb3b7113e25d0b69a9246e3995ced23b1880716acc2d961f82ed05f0e605a880bc1d4b26a36cc80bdfe3e400 SHA512 67379129f16ddc6943da43f574b1a67290aaf89a6843de8c93a08553c0675987050d6516af2afaadbdfa3c92580936d6be7dc238094cf8d0777ce01cf3b105fe
+EBUILD k3b-18.12.3.ebuild 3357 BLAKE2B efe679715fe3dffd7b0d42cc4c344d02bed0f8a08fbeb06799ed7c6fd91b12bfd68e4df8179065164d21bc00e4a09daaa84c555e84f8e7a26f2cc60a3d159a2d SHA512 3ad2565ad9cdf80c0d5a4ebf341a742e9c073745064b1ff09794a99c1f248f5a7f50e970e30f825a53720c1126cd2acaa574ff20c84e271d479fd6c67e5fbafc
 MISC metadata.xml 334 BLAKE2B 0af18188f4b2d7ffa34ad43e06154f943c5da262588331287f89c34f737b435ecf6ac092424057440c9de9ccef1228d0d3c0978d457b5bbf5bdfeaefc464863e SHA512 16203cd75177004bb4844f67659dc7370c12e216871272ff8f781ed11172e72271b15f347ad6d59354ef077ebab1fad2bc150f3e2388f370b660b2d2adcb0faa
diff --git a/kde-apps/k3b/k3b-18.08.3.ebuild b/kde-apps/k3b/k3b-18.08.3.ebuild
new file mode 100644
index 000000000000..39da19644488
--- /dev/null
+++ b/kde-apps/k3b/k3b-18.08.3.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="forceoptional"
+KDE_TEST="true"
+inherit kde5
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+KEYWORDS="amd64 x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+DEPEND="
+	$(add_frameworks_dep karchive)
+	$(add_frameworks_dep kbookmarks)
+	$(add_frameworks_dep kcmutils)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kfilemetadata 'taglib?')
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep knewstuff)
+	$(add_frameworks_dep knotifications)
+	$(add_frameworks_dep knotifyconfig)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kxmlgui)
+	$(add_frameworks_dep solid)
+	$(add_kdeapps_dep libkcddb)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtnetwork)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webkit? ( $(add_qt_dep qtwebkit) )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	kde5_src_configure
+}
+
+pkg_postinst() {
+	kde5_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}
diff --git a/kde-apps/k3b/k3b-18.12.3.ebuild b/kde-apps/k3b/k3b-18.12.3.ebuild
index df58f1f3182d..aa08a04f48d8 100644
--- a/kde-apps/k3b/k3b-18.12.3.ebuild
+++ b/kde-apps/k3b/k3b-18.12.3.ebuild
@@ -11,7 +11,7 @@ DESCRIPTION="Full-featured burning and ripping application based on KDE Framewor
 HOMEPAGE="https://userbase.kde.org/K3b"
 
 LICENSE="GPL-2 FDL-1.2"
-KEYWORDS="amd64 ~arm64 x86"
+KEYWORDS="~amd64 ~arm64 ~x86"
 IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
 
 REQUIRED_USE="