gentoo auto-resync : 29:01:2023 - 02:53:24

1 files changed, 55 insertions, 0 deletions

diff --git a/gui-apps/swaylock/swaylock-1.7.2.ebuild b/gui-apps/swaylock/swaylock-1.7.2.ebuild
new file mode 100644
index 000000000000..aeef41c319be
--- /dev/null
+++ b/gui-apps/swaylock/swaylock-1.7.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps meson
+
+DESCRIPTION="Screen locker for Wayland"
+HOMEPAGE="https://github.com/swaywm/swaylock"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
+else
+	SRC_URI="https://github.com/swaywm/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="+gdk-pixbuf +man +pam"
+
+DEPEND="
+	dev-libs/wayland
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	gdk-pixbuf? ( x11-libs/gdk-pixbuf:2 )
+	pam? ( sys-libs/pam )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.25
+	>=dev-util/wayland-scanner-1.15
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=$(usex man enabled disabled)
+		-Dpam=$(usex pam enabled disabled)
+		-Dgdk-pixbuf=$(usex gdk-pixbuf enabled disabled)
+		"-Dfish-completions=true"
+		"-Dzsh-completions=true"
+		"-Dbash-completions=true"
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	if ! use pam; then
+		fcaps cap_sys_admin usr/bin/swaylock
+	fi
+}