reinit the tree, so we can have metadata

1 files changed, 44 insertions, 0 deletions

diff --git a/gnome-extra/polkit-gnome/polkit-gnome-0.105-r1.ebuild b/gnome-extra/polkit-gnome/polkit-gnome-0.105-r1.ebuild
new file mode 100644
index 000000000000..5013ca8e3219
--- /dev/null
+++ b/gnome-extra/polkit-gnome/polkit-gnome-0.105-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=4
+inherit gnome.org
+
+DESCRIPTION="A dbus session bus service that is used to bring up authentication dialogs"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/polkit"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~sh sparc x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.30
+	>=sys-auth/polkit-0.102
+	x11-libs/gtk+:3
+	!lxde-base/lxpolkit"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+DOCS=( AUTHORS HACKING NEWS README TODO )
+
+src_install() {
+	default
+
+	cat <<-EOF > "${T}"/polkit-gnome-authentication-agent-1.desktop
+	[Desktop Entry]
+	Name=PolicyKit Authentication Agent
+	Comment=PolicyKit Authentication Agent
+	Exec=/usr/libexec/polkit-gnome-authentication-agent-1
+	Terminal=false
+	Type=Application
+	Categories=
+	NoDisplay=true
+	NotShowIn=MATE;KDE;
+	AutostartCondition=GNOME3 if-session gnome-fallback
+	EOF
+
+	insinto /etc/xdg/autostart
+	doins "${T}"/polkit-gnome-authentication-agent-1.desktop
+}