gentoo auto-resync : 01:08:2022 - 09:15:08

1 files changed, 62 insertions, 0 deletions

diff --git a/gnome-extra/gnome-shell-extension-pop-shell/gnome-shell-extension-pop-shell-1.2.0_p20210727-r1.ebuild b/gnome-extra/gnome-shell-extension-pop-shell/gnome-shell-extension-pop-shell-1.2.0_p20210727-r1.ebuild
new file mode 100644
index 000000000000..f31ee1c0fd0e
--- /dev/null
+++ b/gnome-extra/gnome-shell-extension-pop-shell/gnome-shell-extension-pop-shell-1.2.0_p20210727-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2-utils optfeature
+
+EGIT_COMMIT=475b49dc02386e26fbe6b91a559c77515d96caaf
+
+DESCRIPTION="Keyboard-driven layer for GNOME Shell with tiling support"
+HOMEPAGE="https://github.com/pop-os/shell"
+SRC_URI="https://github.com/pop-os/shell/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64"
+IUSE=""
+
+RDEPEND="
+	app-eselect/eselect-gnome-shell-extensions
+	>=gnome-base/gnome-shell-40.1
+	sys-apps/fd
+"
+
+BDEPEND="dev-lang/typescript"
+
+S="${WORKDIR}/shell-${EGIT_COMMIT}"
+
+src_install() {
+	default
+
+	insinto /usr/share/glib-2.0/schemas
+	doins schemas/org.gnome.shell.extensions.pop-shell.gschema.xml
+
+	exeinto /usr/lib/pop-shell/scripts
+	doexe scripts/configure.sh
+
+	insinto /usr/share/gnome-control-center/keybindings
+	doins keybindings/*.xml
+}
+
+pkg_postinst() {
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+
+	gnome2_schemas_update
+
+	echo
+	elog "To configure keybindings run /usr/lib/pop-shell/scripts/configure.sh as user"
+	echo
+
+	optfeature gnome-extra/gnome-shell-extensions "better tiling via native-window-placement"
+}
+
+pkg_postrm() {
+	ebegin "Updating list of installed extensions"
+	eselect gnome-shell-extensions update
+	eend $?
+
+	gnome2_schemas_update
+}