reinit the tree, so we can have metadata

4 files changed, 288 insertions, 0 deletions

diff --git a/gnome-extra/gnome-builder/Manifest b/gnome-extra/gnome-builder/Manifest
new file mode 100644
index 000000000000..baad3cabc60f
--- /dev/null
+++ b/gnome-extra/gnome-builder/Manifest
@@ -0,0 +1,7 @@
+DIST gnome-builder-3.22.4.tar.xz 2480900 SHA256 d569446a83ab88872c265f238f8f42b5928a6b3eebb22fd1db3dbc0dd9128795 SHA512 69ee0d22f7e60f1bc236f2648662ece38f2a3c827d6877f8cbee82eadd499c19de8e4f6f94d7ad8832a93d26cddb5d34106ec6a9e878a7abea3350929d50711d WHIRLPOOL 9dd3f91d6f66a30e9ff6b415683f9a024d38f4af53029bb9fb4e5b3bf73f06c303516b4958585d7743ffb62cbb468da76b2a9c996ee460539762fada4c11a4da
+DIST gnome-builder-3.24.2.tar.xz 4342908 SHA256 84843a9f4af2e1ee1ebfac44441a2affa2d409df9066e7d11bf1d232ae0c535a SHA512 dec133ad3c5ef96a036598ebbe684667dc44f73d8643e700f1e776cf8eb860b99c1d333f1fed5bc896cb7bdcf607eb51fedb7bb1f5b0cc662e4b2703d74140bf WHIRLPOOL 1be12b2ab58286eb1273881700eccf5a0f759e1bd80f8799481c8444229fb1e9a98162ff837c8102879c7ea3ac04994747169af7446fa7514641aea9d1cf0fa0
+EBUILD gnome-builder-3.22.4.ebuild 5156 SHA256 32017d0e217a714de0b13b4b98f66f8aaaba39f55292522c73be1059f1b02b1a SHA512 c3a63df2d162b05f795b83acad7a248c2413620ab3bc39059036d4753149f6518e62f31c95a6dcb96fadb66f2d5a962ca066f20a861d4633dc2ac5d6b901fc08 WHIRLPOOL d32690711a182c522822a09ba1880d05c159952a4c75de86a2a9c2867f85e23959b859ef2102846f6111e18eba49fa5fc1defc6b4623cc154dae08cb9218bb32
+EBUILD gnome-builder-3.24.2.ebuild 5118 SHA256 129c0fa5edcbe750ded8a98dadd4fb860f16d7c4622e4a1074071a9523d5144c SHA512 346de3175a6f25497274372544a662e031e99a2b0e55226a8ab602ec7a429a81dc28af2b6eed0a4db466a7f4114cd132fd79d17ec36da3869be9f2270b967718 WHIRLPOOL 4a2cda368ad96a507e17ee6e946a46866df05777b421ca9f0407fff806a82979227c95156a12b110a10457594db053d685e0aee159f46ef89925558f9289ef04
+MISC ChangeLog 4644 SHA256 51aa1030da258e22b6c29579618251fc2327a550097e709c17a7b28500b011ae SHA512 4dcdc540a1dad4fad6d92bd7a3e3d2637f3ebf37723f209069dcc8269a43156369ebd1f8a28d3d0f262ab22f9113fbb039a9059afc49f8b05969a7e73121b178 WHIRLPOOL 0448c7ffb183ea23e1fdf6bb448c3b6f7292115cec364f62ecacf9422531750010139c467e490e21fe62277af246578c5ca4a5d60b7d29151d9ce62c4eebc2a0
+MISC ChangeLog-2015 411 SHA256 bf3dd003c68d59dc4dfe33515663a84a473daed34c55e5663fc68d56783236f0 SHA512 2294827a28a1428da2a30745f2c7d94685c3fe0ec2cd2012c3c13d0b297f0e51b3a911807d646fe0e9efedb699ffb96a9935afbaf1e83ce3bcb0d94311bfff29 WHIRLPOOL bf86082594e0733da566ab13eb7ce1422b86c0114f4d22f4a206bdd3d98e8bad76d13650cedf391fa3b2802a4d343e7fddf3599314387836c6f1ea1a9ca44fdd
+MISC metadata.xml 1011 SHA256 59028d6d9b5fa46032029f75161cee29b56291b40a6f6e9c54bba5b18365a226 SHA512 b3519707a4023a6c9892827abaf6465e28dbad2f1a8c2760a3f2d9b34d4be384d10326870e0d7952b41cb725c955cc838092786543ff1867db4a3acf41cb404a WHIRLPOOL 1b3b5dde7b6f1046a5c631fc1f6c0179e1af1b2d6f7e7bb9bbdc92b5dd3b8147de29f6528334aacb4d2bad93f99307d1814877b66891753cdab6dbd40ffd84a1
diff --git a/gnome-extra/gnome-builder/gnome-builder-3.22.4.ebuild b/gnome-extra/gnome-builder/gnome-builder-3.22.4.ebuild
new file mode 100644
index 000000000000..063b139c3079
--- /dev/null
+++ b/gnome-extra/gnome-builder/gnome-builder-3.22.4.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_3,3_4,3_5} )
+VALA_MIN_API_VERSION="0.30"
+VALA_USE_DEPEND="vapigen"
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome2 python-single-r1 vala virtualx readme.gentoo-r1
+
+DESCRIPTION="Builder attempts to be an IDE for writing software for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="clang +git sysprof vala webkit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# When bumping, pay attention to all the included plugins/*/configure.ac files and the requirements within.
+# Most have no extra requirements and default to enabled; we need to handle the ones with extra requirements, which tend to default to auto(magic).
+# Look at the last (fourth) argument given to AC_ARG_ENABLE to decide. We don't support any disabling of those that are default-enabled and have no extra deps beyond C/python/introspection.
+# FIXME: >=dev-util/devhelp-3.20.0 dependency is automagic for devhelp integration plugin
+# FIXME: vte could be optional via $(use_enable vte terminal-plugin) - but most/all people want this and have vte?
+# FIXME: flatpak-plugin needs flatpak.pc >=0.6.9, libgit2[threads] >=libgit2-glib-0.24.0[ssh] libsoup-2.4.pc
+# FIXME: --with-sanitizer configure option
+# FIXME: Enable rdtscp based high performance counter usage on suitable architectures for EGG_COUNTER?
+# Editorconfig needs pcre.h, with vte migrating away, might want it optional?
+# Python is always enabled - the core python plugin support checks are automagic and not worth crippling it by not supporting python plugins
+# Relatedly introspection is always required to not have broken python using plugins or have to enable/disable them based on it. This is a full IDE, not a place to be really minimal.
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it. Last full check at 3.22.4
+RDEPEND="
+	>=x11-libs/gtk+-3.22.1:3[introspection]
+	>=dev-libs/glib-2.50.0:2[dbus]
+	>=x11-libs/gtksourceview-3.22.0:3.0[introspection]
+	>=dev-libs/gobject-introspection-1.48.0:=
+	>=dev-python/pygobject-3.22.0:3
+	>=dev-libs/libxml2-2.9
+	>=x11-libs/pango-1.38.0
+	>=dev-libs/libpeas-1.18.0[python,${PYTHON_USEDEP}]
+	>=dev-libs/json-glib-1.2.0
+	webkit? ( >=net-libs/webkit-gtk-2.12.0:4=[introspection] )
+	clang? ( sys-devel/clang:= )
+	git? (
+		dev-libs/libgit2[ssh,threads]
+		>=dev-libs/libgit2-glib-0.24.0[ssh] )
+	>=x11-libs/vte-0.46:2.91
+	sysprof? ( >=dev-util/sysprof-3.22.2[gtk] )
+	dev-libs/libpcre:3
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+"
+# desktop-file-utils for desktop-file-validate check in configure for 3.22.4
+# mm-common due to not fully clean --disable-idemm behaviour, recheck on bump
+DEPEND="${RDEPEND}
+	dev-cpp/mm-common
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	>=dev-util/gtk-doc-am-1.11
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	!<sys-apps/sandbox-2.10-r3
+"
+
+# Tests fail if all plugins aren't enabled (webkit, clang, devhelp, perhaps more)
+RESTRICT="test"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+  C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+  highlighting and symbol resolving support.
+* dev-python/jedi and dev-python/lxml for more accurate Python
+  autocompletion support.
+* dev-util/meson for integration with the Meson build system.
+* dev-util/cargo for integration with the Rust Cargo build system.
+'
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# jhbuild support
+# rust language server via rls
+# autotools stuff for autotools plugin
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	export PYTHON3_CONFIG="$(python_get_PYTHON_CONFIG)"
+	# idemm is C++ wrapper for libide. Once that's needed by something, we might want to
+	# consider a split package instead of USE flag. Deps are in libidemm/configure.ac
+	gnome2_src_configure \
+		--disable-idemm \
+		--enable-editorconfig \
+		--enable-introspection \
+		$(use_enable vala vala-pack-plugin) \
+		$(use_enable webkit) \
+		$(use_enable webkit html-preview-plugin) \
+		$(use_enable clang clang-plugin) \
+		$(use_enable git git-plugin) \
+		$(use_enable git contributing-plugin) \
+		$(use_enable sysprof sysprof-plugin) \
+		--disable-flatpak-plugin \
+		--enable-terminal-plugin \
+		--disable-static
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}
+
+src_test() {
+	# FIXME: this should be handled at eclass level
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data/gsettings" || die
+
+	GSETTINGS_SCHEMA_DIR="${S}/data/gsettings" virtx emake check
+}
diff --git a/gnome-extra/gnome-builder/gnome-builder-3.24.2.ebuild b/gnome-extra/gnome-builder/gnome-builder-3.24.2.ebuild
new file mode 100644
index 000000000000..13a5b0fc43a6
--- /dev/null
+++ b/gnome-extra/gnome-builder/gnome-builder-3.24.2.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5} )
+VALA_MIN_API_VERSION="0.30"
+VALA_USE_DEPEND="vapigen"
+DISABLE_AUTOFORMATTING=1
+FORCE_PRINT_ELOG=1
+
+inherit gnome2 python-single-r1 vala virtualx readme.gentoo-r1
+
+DESCRIPTION="Builder attempts to be an IDE for writing software for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Builder"
+
+# FIXME: Review licenses at some point
+LICENSE="GPL-3+ GPL-2+ LGPL-3+ LGPL-2+ MIT CC-BY-SA-3.0 CC0-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang +git sysprof vala webkit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# When bumping, pay attention to all the included plugins/*/configure.ac files and the requirements within.
+# Most have no extra requirements and default to enabled; we need to handle the ones with extra requirements, which tend to default to auto(magic).
+# Look at the last (fourth) argument given to AC_ARG_ENABLE to decide. We don't support any disabling of those that are default-enabled and have no extra deps beyond C/python/introspection.
+# FIXME: >=dev-util/devhelp-3.20.0 dependency is automagic for devhelp integration plugin
+# FIXME: vte could be optional via $(use_enable vte terminal-plugin) - but most/all people want this and have vte?
+# FIXME: flatpak-plugin needs flatpak.pc >=0.6.9, libgit2[threads] >=libgit2-glib-0.24.0[ssh] libsoup-2.4.pc
+# FIXME: --with-sanitizer configure option
+# FIXME: Enable rdtscp based high performance counter usage on suitable architectures for EGG_COUNTER?
+# Editorconfig needs pcre.h, with vte migrating away, might want it optional?
+# Python is always enabled - the core python plugin support checks are automagic and not worth crippling it by not supporting python plugins
+# Relatedly introspection is always required to not have broken python using plugins or have to enable/disable them based on it. This is a full IDE, not a place to be really minimal.
+# An introspection USE flag of a dep is required if any introspection based language plugin wants to use it. Last full check at 3.22.4
+RDEPEND="
+	>=x11-libs/gtk+-3.22.1:3[introspection]
+	>=dev-libs/glib-2.50.0:2[dbus]
+	>=x11-libs/gtksourceview-3.22.0:3.0[introspection]
+	>=dev-libs/gobject-introspection-1.48.0:=
+	>=dev-python/pygobject-3.22.0:3
+	>=dev-libs/libxml2-2.9.0
+	>=x11-libs/pango-1.38.0
+	>=dev-libs/libpeas-1.18.0[python,${PYTHON_USEDEP}]
+	>=dev-libs/json-glib-1.2.0
+	>=app-text/gspell-1.2.0
+	>=app-text/enchant-1.6.0
+	webkit? ( >=net-libs/webkit-gtk-2.12.0:4=[introspection] )
+	clang? ( sys-devel/clang:= )
+	git? (
+		dev-libs/libgit2[ssh,threads]
+		>=dev-libs/libgit2-glib-0.25.0[ssh] )
+	>=x11-libs/vte-0.46:2.91
+	sysprof? ( >=dev-util/sysprof-3.23.91[gtk] )
+	dev-libs/libpcre:3
+	${PYTHON_DEPS}
+	vala? ( $(vala_depend) )
+"
+# desktop-file-utils for desktop-file-validate check in configure for 3.22.4
+# mm-common due to not fully clean --disable-idemm behaviour, recheck on bump
+DEPEND="${RDEPEND}
+	dev-cpp/mm-common
+	dev-libs/appstream-glib
+	dev-util/desktop-file-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	!<sys-apps/sandbox-2.10-r3
+"
+
+# Tests fail if all plugins aren't enabled (webkit, clang, devhelp, perhaps more)
+RESTRICT="test"
+
+DOC_CONTENTS='gnome-builder can use various other dependencies on runtime to provide
+extra capabilities beyond these expressed via USE flags. Some of these
+that are currently available with packages include:
+
+* dev-util/ctags with exuberant-ctags selected via "eselect ctags" for
+  C, C++, Python, JavaScript, CSS, HTML and Ruby autocompletion, semantic
+  highlighting and symbol resolving support.
+* dev-python/jedi and dev-python/lxml for more accurate Python
+  autocompletion support.
+* dev-util/valgrind for integration with valgrind.
+* dev-util/meson for integration with the Meson build system.
+* dev-util/cargo for integration with the Rust Cargo build system.
+'
+# FIXME: Package gnome-code-assistance and mention here, or maybe USE flag and default enable because it's rather important
+# eslint for additional diagnostics in JavaScript files
+# jhbuild support
+# rust language server via rls
+# autotools stuff for autotools plugin; gtkmm/autoconf-archive for C++ template
+# mono/PHPize stuff
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-channel=distro \
+		--enable-editorconfig \
+		--enable-introspection \
+		$(use_enable vala vala-pack-plugin) \
+		$(use_enable webkit) \
+		$(use_enable webkit html-preview-plugin) \
+		$(use_enable clang clang-plugin) \
+		$(use_enable git git-plugin) \
+		$(use_enable sysprof sysprof-plugin) \
+		--disable-flatpak-plugin \
+		--enable-terminal-plugin \
+		--enable-gettext-plugin \
+		--disable-static
+}
+
+src_install() {
+	gnome2_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	readme.gentoo_print_elog
+}
+
+src_test() {
+	# FIXME: this should be handled at eclass level
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data/gsettings" || die
+
+	GSETTINGS_SCHEMA_DIR="${S}/data/gsettings" virtx emake check
+}
diff --git a/gnome-extra/gnome-builder/metadata.xml b/gnome-extra/gnome-builder/metadata.xml
new file mode 100644
index 000000000000..78c212429a5c
--- /dev/null
+++ b/gnome-extra/gnome-builder/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="project">
+	<email>gnome@gentoo.org</email>
+	<name>Gentoo GNOME Desktop</name>
+</maintainer>
+<use>
+	<flag name="clang">Provide integration with <pkg>sys-devel/clang</pkg> for best possible C/C++ autocompletion, semantic highlighting, symbol resolving, and diagnostics support</flag>
+	<flag name="git">Provide support for the Git version control system via <pkg>dev-libs/libgit2-glib</pkg>
+		(such as setup of Git for New Project, direct cloning for Open Project and changed lines indicators in the editor gutter)</flag>
+	<flag name="sysprof">Provide an integrated profiler via <pkg>dev-util/sysprof</pkg></flag>
+	<flag name="vala">Provide an autoindenter, autocompletion, diagnostics, and symbol resolver for Vala</flag>
+	<flag name="webkit">Enable <pkg>net-libs/webkit-gtk</pkg> using plugins support and the HTML/Markdown previewer plugin</flag>
+</use>
+</pkgmetadata>