gentoo auto-resync : 14:03:2023 - 00:16:42

2 files changed, 122 insertions, 0 deletions

diff --git a/gnome-extra/gnome-boxes/Manifest b/gnome-extra/gnome-boxes/Manifest
index f6f80ab9a1af..cd03337428f9 100644
--- a/gnome-extra/gnome-boxes/Manifest
+++ b/gnome-extra/gnome-boxes/Manifest
@@ -1,5 +1,7 @@
 DIST gnome-boxes-43.2.tar.xz 1235424 BLAKE2B f99106ee7a8744a92a6f749230802a882a96489a2b2047b70ec07263b2f03ee0fcd910c907e2307a09c78f85784849bf87c20e901894e7c9692dfa77a0182a18 SHA512 edddf5980adf6bce516a4fd35be14e7b261c6cf886f1f1e7fc9cd79089b8320e781c98f2a040babc1661af6ae1f331dec3a2ecd728bcdb26d9a9031175c8e1be
 DIST gnome-boxes-43.3.tar.xz 1235612 BLAKE2B b91953a77aae69a8307c4c9bb6944f9c62b49ac67aef352ba349a84b820bb6aa791cc27ce5a5402b55d3c822439f90700083b66c216a0fac83bb1a96e8410cca SHA512 ad53b1538d146aae9ec4f40d7cd8dc75e3ec54c903b0c2debd56445e613445281e9a641398cdecf584f1fbe8d31fc51d5309ce76b4eb8ed1eb0e0018341d7b4b
+DIST gnome-boxes-44.rc.tar.xz 1242060 BLAKE2B 36a043c83ee5a1900d09376ed1db2439ea814e093aa092dd75a0ef08f8827bf486b65f7fccf02957a3ba09ffd709902de57f75583cf8c235eb999ce5d4495ca7 SHA512 968782f7bf399b456ee381668314b454b0c041427dddfcbdccc0e9aee6c211f00a7e9cbafbf4dcf94b89ddbd4994279c16d7c8a8ea6af040179ac29e7836b9c8
 EBUILD gnome-boxes-43.2.ebuild 3487 BLAKE2B d181b659c3d14080391233e7edeac328b948b9cfc2283c9731a503f045684f7e695dd9bfc6844fcb0f0fb7ce7d55c482cfdecf77d171bda5a5e343d677178e3a SHA512 ef77513cc638c73f99874fd2dfd97087dde9249ad122783ea1dc3222bb27b27a200c54cf2bb10306d7c94302551fc5b5b1550b7dc7f6893e0211b7a5efc92092
 EBUILD gnome-boxes-43.3.ebuild 3488 BLAKE2B ff7a7557238b24d40cbd26d4333c88134374039e4f4d69c4ec9d2c748ae0602738830ce40cc8e44480381dc1ed2c991f20405c1e090ec83e75d6c07b8ed89140 SHA512 d7c79122f7d173d94b5cd9912f97ec81d955ab2643b571a5fb03c3a7cefee02fc0f412c82cfee7a9c109d54e89d2bc38ae410956bde8f19ee12f60229e1ae2e6
+EBUILD gnome-boxes-44_rc.ebuild 3547 BLAKE2B 5f0a5e2133d35f5e1952eb220b3cdc607b5a512cc03603edcf1f73bb8499fb3ffac303adf226fa3eec368694d4935ea2b456a14a9d5584784698479085e77ebd SHA512 c3f424ac17e39fd78f7b02ac8ff2cba3be7b6929472307d73c6d5517dc905d2c59fbeebe9e65d6e1e7e6795d3372ca1e8947c8ce4fe05bff57f3242124a7c72f
 MISC metadata.xml 352 BLAKE2B 285b6e588965df3d070f92552b36941c6346a9fde3dce831baa82d42c8ca23f62cc027e5984a27fc87bffca8181c2d13a52b064729349daef0aa815a566a885e SHA512 09baca6576a90ca57b6e0935879f1630550efc9d591b425d6944b28b1184612b34fcdbae6d835d98812c89ec7a47415af9a01678be16f35a52933bb7c374131f
diff --git a/gnome-extra/gnome-boxes/gnome-boxes-44_rc.ebuild b/gnome-extra/gnome-boxes/gnome-boxes-44_rc.ebuild
new file mode 100644
index 000000000000..beaa81cf21a4
--- /dev/null
+++ b/gnome-extra/gnome-boxes/gnome-boxes-44_rc.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils linux-info meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Simple GNOME application to access remote or virtual systems"
+HOMEPAGE="https://wiki.gnome.org/Apps/Boxes"
+SRC_URI="https://download.gnome.org/sources/${PN}/44/${PN}-44.rc.tar.xz"
+S="${WORKDIR}/${PN}-44.rc"
+
+LICENSE="LGPL-2+ CC-BY-2.0"
+SLOT="0"
+
+KEYWORDS="~amd64"
+
+# FIXME: qemu probably needs to depend on spice[smartcard] directly with USE=spice
+# FIXME: Check over libvirt USE=libvirtd,qemu and the smartcard/usbredir requirements
+# Technically vala itself still ships a libsoup vapi, but that may change, and it should be better to use the .vapi from the same libsoup version
+DEPEND="
+	>=app-arch/libarchive-3.0.0:=
+	>=dev-libs/glib-2.52:2
+	>=x11-libs/gtk+-3.24.1:3
+	>=gui-libs/libhandy-1.5.0:1
+	>=sys-libs/libosinfo-1.10.0-r1
+	net-libs/libsoup:3.0
+	virtual/libusb:1
+	>=app-emulation/libvirt-glib-4.0.0
+	>=dev-libs/libxml2-2.7.8:2
+	>=net-misc/spice-gtk-0.32[gtk3(+),smartcard,usbredir]
+	>=net-libs/webkit-gtk-2.38.0:4.1
+
+	>=dev-libs/gobject-introspection-1.56:=
+	>=dev-libs/libgudev-165:=
+" # gobject-introspection needed for libovf subproject
+# These are called via exec():
+# sys-fs/mtools mcopy for unattended file copying for files that libarchive doesn't support
+# app-cdr/cdrtools mkisofs is needed for unattended installer secondary disk image creation
+# app-emulation/libguestfs virt-sysprep is used for VM cloing, if not there, it logs debug and doesn't function
+# sys-apps/policycoreutils restorecon is used for checking selinux context
+# app-emulation/libvirt virsh used for various checks (and we need the library anyways)
+# sys-auth/polkit used for making all libvirt system disks readable via "pkexec chmod a+r" that aren't already readable to the user (libvirt system importer)
+# app-emulation/qemu qemu-img used to convert image to QCOW2 format during copy
+RDEPEND="${DEPEND}
+	app-cdr/cdrtools
+	app-misc/tracker-miners:3[iso]
+	app-emulation/spice[smartcard]
+	>=app-emulation/libvirt-0.9.3[libvirtd,qemu]
+	>=app-emulation/qemu-1.3.1[spice,smartcard,usbredir]
+	sys-fs/mtools
+	sys-auth/polkit
+"
+# This is only needed for creating the .vapi file, but gnome-boxes needs it
+BDEPEND="
+	$(vala_depend)
+	sys-libs/libosinfo[vala]
+	app-crypt/libsecret[vala]
+	net-libs/libsoup:3.0[vala]
+	app-emulation/libvirt-glib[vala]
+	net-misc/spice-gtk[vala]
+	x11-libs/vte:2.91[vala]
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="Before running gnome-boxes for local VMs, you will need to load the KVM modules.
+If you have an Intel Processor, run:
+# modprobe kvm-intel
+
+If you have an AMD Processor, run:
+# modprobe kvm-amd"
+
+pkg_pretend() {
+	linux-info_get_any_version
+
+	if linux_config_exists; then
+		if ! { linux_chkconfig_present KVM_AMD || \
+			linux_chkconfig_present KVM_INTEL; }; then
+			ewarn "You need KVM support in your kernel to use GNOME Boxes local VM support!"
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+	vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddistributor_name=Gentoo
+		-Ddistributor_version=${PVR}
+		-Dinstalled_tests=false
+		-Dflatpak=false
+		-Dprofile=default
+		-Duefi=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}