gentoo resync : 12.05.2022

3 files changed, 178 insertions, 2 deletions

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index a9d5bb29750c..ea5c341071cb 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -3,6 +3,8 @@ DIST gnome-control-center-41.2-patchset.tar.xz 6380 BLAKE2B de9eacf549686e43870d
 DIST gnome-control-center-41.4.tar.xz 6616908 BLAKE2B 7c1a2692667c0447590d81c17ae990bff4b3bb7b85007ec70f8623d284cc0743ca79380dc60f1a9f97c01f897260c74acae0d730b197e8d4314e8002c7eec826 SHA512 63fa20041a06f5075d172b543176b4f037fcd623d9fa5ca5f785e047a9b95ccd002c423d29de673dcb28b7d99a83157b39d7bd65ef77fe70065e9a03b5ae38a4
 DIST gnome-control-center-42.0-patchset.tar.xz 5932 BLAKE2B 1c9311481be6a07dc2ff61fc9e65f190bc1668026fba2a1e4a8edf9a033e6b2b9019542d89aac4480323ee4802e00b765654008f5252e87040f013a990cb8048 SHA512 b76c1facd3566edcadfe33f81027966da35bb03909bfbae6faad72005b92447e291fa424611196bfae6e1dc5bf5982917f3ae14c36d87206f6bfb4af502bf1a4
 DIST gnome-control-center-42.0.tar.xz 6238096 BLAKE2B 63540c94d64d312ff9ce523cc3ef0023b35b93bbd0593cc6a3f5d671cc70980969617b2436b0c9994b8d225fac972d639b935affac36bc32bf621c4593d490bd SHA512 d8097240444ab45174e89db0f543d6523051829b124933cdbb84b1bc5d2d6809ee810f6d2c09702da51c991fe11496635b3164b490ed1e2ac523481d5466cf3e
+DIST gnome-control-center-42.1.tar.xz 6239960 BLAKE2B ba539267a00bca7218a8088fba1c2790d26239ea57ef45cdbbe6b54b687b30ab15ec4ced0078d9fab48a7d6d8fd9e966ffa3dd92bcae164d99a5e64c458e5852 SHA512 a29df2604d90e42a602060a7042d70238eed9e59c46b500610c6b5842e015ba0d9567528a3dfd6bf365973f274de47ccd4b8f2f50cfa35c8f88bb05cb31e774d
 EBUILD gnome-control-center-41.4-r1.ebuild 6117 BLAKE2B 91a6d1c145971c45330865eb6017546cc4df1d99b87c441ba21edaef1ca3fa2eef9a8ce4396ad741a27557a3fa8e87e11ee54b35fb4d42321e129b5fe55bb742 SHA512 f7db79a7888306f9291c3e90eae254ffb85c7db5deb747b6af9d103a9cc9ea430e4a01642ec1017899fd452f24545031cde765c87c86168744f0973f0b58c588
-EBUILD gnome-control-center-42.0-r1.ebuild 6106 BLAKE2B 8430e30b14c0f569c6aa38b392c7c3333c8bc1f186162acce72b20b78b5c9aa06f519b17711e8dda2d34ef9a203782eb6e01a3bd6c17cd0b67f7f24204755932 SHA512 7f2e5b02831f912ba5ea0dd38aa8e8a9c39972f31538a9f8c7425fbcb7aa2d209324d14d5d885a6d685684c434dc028505fa8ee48e5c0cfdd99229b28396efdb
+EBUILD gnome-control-center-42.0-r1.ebuild 6113 BLAKE2B bf91416360ffea17c708cf9501272d1637ce4275e8ce99548ab70b6ddba4bf0371bd754203658958e42708aeef64c1a93c5c32cb5ca6b3faa7a513fa36048cbc SHA512 86deb32ce02025476ae33f7b73cd0d36e956fdce919f2254f85aa10e772a562566c131ddea677d490356415023200a55e74856f5c06aae1f3757da33af7758e0
+EBUILD gnome-control-center-42.1.ebuild 6058 BLAKE2B 071bc0ef3ca97838a7ae829ee495a3d13c2642f24b9aaed6c354ce1d85dd93b9f18ab929f5d37ad12186f09b12630f3678df704aee916613481268cd448ccf54 SHA512 2d680e74f387f339499dedccdf06a6dd50de680ffc1cf197a12f1b3aac8aaa636c05dfe53a14466ffea49877be9768cb3cf5582a08dce0a9a7b6be54b3cc1397
 MISC metadata.xml 497 BLAKE2B 27aa6d9d725a3ce90d351442da83bdb5680f9931d78e5d6a653a1d2d392df118406e3eab36c77bbaeefc581be3a62c5df13fdfb611b2db27fc9c7440ba4ceae3 SHA512 c44903fa5a9462871c065bc776450c25bcca1dfe2f52d6bf676568f587bc308a0465bd5cb6e095fb0ecaefd0b8471df90df3b96164c7e7de76a86fbbe416a82b
diff --git a/gnome-base/gnome-control-center/gnome-control-center-42.0-r1.ebuild b/gnome-base/gnome-control-center/gnome-control-center-42.0-r1.ebuild
index 70008f3ef6ff..97ebfb3fe3b6 100644
--- a/gnome-base/gnome-control-center/gnome-control-center-42.0-r1.ebuild
+++ b/gnome-base/gnome-control-center/gnome-control-center-42.0-r1.ebuild
@@ -17,7 +17,7 @@ RESTRICT="!test? ( test )"
 REQUIRED_USE="
 	^^ ( elogind systemd )
 " # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
-KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
 
 # meson.build depends on python unconditionally
 BDEPEND="${PYTHON_DEPS}"
diff --git a/gnome-base/gnome-control-center/gnome-control-center-42.1.ebuild b/gnome-base/gnome-control-center/gnome-control-center-42.1.ebuild
new file mode 100644
index 000000000000..17e5b231ef47
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-42.1.ebuild
@@ -0,0 +1,174 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-control-center"
+SRC_URI+=" https://dev.gentoo.org/~mattst88/distfiles/${PN}-42.0-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug elogind +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager systemd test wayland"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	^^ ( elogind systemd )
+" # Theoretically "?? ( elogind systemd )" is fine too, lacking some functionality at runtime, but needs testing if handled gracefully enough
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~x86"
+
+# meson.build depends on python unconditionally
+BDEPEND="${PYTHON_DEPS}"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+DEPEND="
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
+	>=media-sound/pulseaudio-2.0[glib]
+	>=gui-libs/libadwaita-1.1:1=
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.56.0:2
+	gnome-base/gnome-desktop:4=
+	>=gnome-base/gnome-settings-daemon-41.0[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-42_alpha
+	dev-libs/libxml2:2
+	>=sys-power/upower-0.99.8:=
+	>=dev-libs/libgudev-232
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	media-libs/libepoxy
+	app-crypt/gcr:=
+	>=dev-libs/libpwquality-1.2.2
+	>=gui-libs/gtk-4.4:4[X,wayland=]
+	>=sys-auth/polkit-0.114
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	networkmanager? (
+		>=net-libs/libnma-1.8.36
+		>=net-misc/networkmanager-1.24.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	bluetooth? ( net-wireless/gnome-bluetooth:3= )
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.3.0
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=sys-fs/udisks-2.1.8:2
+	app-crypt/libsecret
+	net-libs/gnutls:=
+	media-libs/gsound
+"
+# systemd/elogind USE flagged because package manager will potentially try to satisfy a
+# "|| ( systemd ( elogind openrc-settingsd)" via systemd if openrc-settingsd isn't already installed.
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${DEPEND}
+	systemd? ( >=sys-apps/systemd-31 )
+	elogind? ( app-admin/openrc-settingsd
+		sys-auth/elogind )
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1
+	networkmanager? ( gnome-extra/nm-applet )" # networking panel can call into nm-connection-editor
+
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	test? ( $(python_gen_any_dep '
+		dev-python/python-dbusmock[${PYTHON_USEDEP}]
+	') )
+"
+
+PATCHES=(
+	# Patches from gnome-40 branch on top of 40.0
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+python_check_deps() {
+	use test || return 0
+	has_version "dev-python/python-dbusmock[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	xdg_environment_reset
+	# Mark python tests with shebang executable, so that meson will launch them directly, instead
+	# of via its own python-single-r1 version, which might not match what we get from python_check_deps
+	chmod a+x tests/network/test-network-panel.py tests/datetime/test-datetime.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		-Dprivileged_group=wheel
+		-Dsnap=false
+		$(meson_use test tests)
+		$(meson_use debug tracing)
+		$(meson_use input_devices_wacom wacom)
+		#$(meson_use wayland) # doesn't do anything in 3.34 and 3.36 due to unified gudev handling code
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+		-Dmalcontent=false # unpackaged
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}