gentoo resync : 25.11.2020

1 files changed, 51 insertions, 0 deletions

diff --git a/games-strategy/liquidwar/liquidwar-5.6.5.ebuild b/games-strategy/liquidwar/liquidwar-5.6.5.ebuild
new file mode 100644
index 000000000000..47a0e6ddf7a1
--- /dev/null
+++ b/games-strategy/liquidwar/liquidwar-5.6.5.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop toolchain-funcs
+
+DESCRIPTION="Unique multiplayer wargame"
+HOMEPAGE="https://ufoot.org/liquidwar/"
+SRC_URI="https://ufoot.org/download/liquidwar/v5/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND=">=media-libs/allegro-4.2:0[X]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-exec-stack.patch
+	"${FILESDIR}"/${P}-gcc10.patch
+	"${FILESDIR}"/${P}-makefile.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's:$(GMAKE):$(MAKE):' \
+		-e "/^DOCDIR/ s:=.*:= ${EPREFIX}/usr/share/doc/\$(PF):" Makefile.in \
+		|| die 'sed Makefile.in failed'
+}
+
+src_configure() {
+	tc-export CC
+	econf \
+		--disable-doc-ps \
+		--disable-doc-pdf \
+		$(use_enable x86 asm)
+}
+
+src_compile() {
+	# skip build_doc target wrt bug 460344
+	emake build_bin build_data
+}
+
+src_install() {
+	emake DESTDIR="${D}" install_nolink
+	einstalldocs
+	make_desktop_entry ${PN} "Liquid War" /usr/share/pixmaps/${PN}.xpm
+}