gentoo resync : 02.05.2018

1 files changed, 48 insertions, 0 deletions

diff --git a/games-puzzle/icebreaker/icebreaker-1.9.6-r1.ebuild b/games-puzzle/icebreaker/icebreaker-1.9.6-r1.ebuild
new file mode 100644
index 000000000000..f064951fac68
--- /dev/null
+++ b/games-puzzle/icebreaker/icebreaker-1.9.6-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit desktop
+
+DESCRIPTION="Trap and capture penguins on Antarctica"
+HOMEPAGE="http://www.mattdm.org/icebreaker/"
+SRC_URI="http://www.mattdm.org/${PN}/1.9.x/${P}.tgz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	media-libs/libsdl[video]
+	media-libs/sdl-mixer
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-ldflags.patch
+	"${FILESDIR}"/${P}-gentoo.patch
+	"${FILESDIR}"/${P}-parallell-install.patch
+	"${FILESDIR}"/${P}-ovfl.patch
+)
+
+src_compile() {
+	emake \
+		OPTIMIZE="${CFLAGS}" \
+		prefix=/usr \
+		bindir=/usr/bin \
+		datadir=/usr/share \
+		highscoredir="/var"
+}
+
+src_install() {
+	emake \
+		prefix="${D}/usr" \
+		bindir="${D}/usr/bin" \
+		datadir="${D}/usr/share" \
+		highscoredir="${D}/var" install
+
+	newicon ${PN}_48.bmp ${PN}.bmp
+	make_desktop_entry ${PN} IceBreaker /usr/share/pixmaps/${PN}.bmp
+	einstalldocs
+}