reinit the tree, so we can have metadata

1 files changed, 54 insertions, 0 deletions

diff --git a/games-arcade/wop/wop-0.4.3-r2.ebuild b/games-arcade/wop/wop-0.4.3-r2.ebuild
new file mode 100644
index 000000000000..f0ef50085b68
--- /dev/null
+++ b/games-arcade/wop/wop-0.4.3-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs
+
+MY_DATA_V="2005-12-21"
+MY_DATA_P="${PN}data-${MY_DATA_V}"
+
+DESCRIPTION="Worms of Prey - A multi-player, real-time clone of Worms"
+HOMEPAGE="http://wormsofprey.org/"
+SRC_URI="
+	http://wormsofprey.org/download/${P}-src.tar.bz2
+	http://wormsofprey.org/download/${MY_DATA_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND="
+	media-libs/libsdl
+	media-libs/sdl-image
+	media-libs/sdl-mixer
+	media-libs/sdl-net
+	media-libs/sdl-ttf"
+DEPEND="${RDEPEND}
+	x11-misc/makedepend"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-fix-build-system.patch
+	"${FILESDIR}"/${P}-gcc43.patch
+	"${FILESDIR}"/${P}-gcc6.patch
+)
+
+src_configure() {
+	tc-export AR CXX RANLIB
+}
+
+src_install() {
+	dobin bin/${PN}
+
+	insinto /usr/share/${PN}
+	doins -r "${WORKDIR}/${MY_DATA_P}"/.
+
+	insinto /etc
+	doins woprc
+
+	newicon "${WORKDIR}/${MY_DATA_P}"/images/misc/icons/wop16.png ${PN}.png
+	make_desktop_entry wop "Worms of Prey"
+
+	dodoc AUTHORS ChangeLog README{,-Libraries.txt} REVIEWS
+}