gentoo resync : 14.07.2018

1 files changed, 70 insertions, 0 deletions

diff --git a/games-action/chromium-bsu/chromium-bsu-0.9.15.1-r1.ebuild b/games-action/chromium-bsu/chromium-bsu-0.9.15.1-r1.ebuild
new file mode 100644
index 000000000000..578f593bf3df
--- /dev/null
+++ b/games-action/chromium-bsu/chromium-bsu-0.9.15.1-r1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gnome2-utils
+
+DESCRIPTION="Chromium B.S.U. - an arcade game"
+HOMEPAGE="http://chromium-bsu.sourceforge.net/"
+SRC_URI="mirror://sourceforge/chromium-bsu/${P}.tar.gz"
+
+LICENSE="Clarified-Artistic"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="mixer nls +sdl"
+
+RDEPEND="
+	media-fonts/dejavu
+	media-libs/quesoglc
+	media-libs/glpng
+	virtual/opengl
+	virtual/glu
+	x11-libs/libXmu
+	mixer? ( media-libs/sdl-mixer )
+	!mixer? (
+		media-libs/freealut
+		media-libs/openal
+	)
+	nls? ( virtual/libintl )
+	sdl? (
+		media-libs/libsdl[X]
+		media-libs/sdl-image[png]
+	)
+	!sdl? ( media-libs/freeglut )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )"
+
+PATCHES=( "${FILESDIR}"/${P}-gcc6.patch )
+
+src_configure() {
+	econf \
+		--disable-ftgl \
+		--enable-glc \
+		$(use_enable mixer sdlmixer) \
+		$(use_enable !mixer openal) \
+		$(use_enable nls) \
+		$(use_enable sdl) \
+		$(use_enable sdl sdlimage) \
+		$(use_enable !sdl glut)
+}
+
+src_install() {
+	default
+	dodoc data/doc/*.htm
+
+	newicon -s 64 misc/${PN}.png ${PN}.png
+	domenu misc/chromium-bsu.desktop
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}