gentoo auto-resync : 06:08:2022 - 02:09:04

2 files changed, 116 insertions, 0 deletions

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index b76b67c82f4e..6cd6c0a75ac9 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -4,4 +4,5 @@ DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69b
 EBUILD lldb-13.0.1.ebuild 2587 BLAKE2B 1e017726c7d7f9879c96c744c63f950ff2837d3082e5e5f81202b9b6259d71d013285fb48e81a25d8cbdb81b1db8b2f6807f897ea83b9742a24c3c35ac9761c0 SHA512 6e626b26f6ed4c51e9b2c732de21a60d3a5db90ee57c890b40dd8a6c82f738d6e8bd7a02f8f7fe7cdb9cb067ead82513b3ce7d35e20210f10f4d525cb3baed77
 EBUILD lldb-14.0.6.ebuild 2661 BLAKE2B 272053742b016bf234e75bb6b05e4b113b1f8b34249e8a601842412216665cf00df1b93bf590815d1dd1a709ce5006671bddb92cda7d42a5d099f3cfc3968368 SHA512 91a303661ae706bde45a7d12da928735690fdbb48901a31d6477c2d8595a42a59d4e07dc0ffe4eeb64e0775c61c329b05c0f12ccdece7bed1d5a9093db690f34
 EBUILD lldb-15.0.0.9999.ebuild 2648 BLAKE2B ce0a4d9170e7ecb6331a0f793100c6ffbb7334135f34fb2bf1cbd6301ae57d7bfb4d6787b6b7e38a76fac78b54fc9041f3d5034a24a2ae0a31ea976ace2c5cc0 SHA512 e215a3dfb8c44f10af4b2c91da74238f1126f714e7e15d451564413c14ef88a8ec0b81fdbf2636ef265ebc7579e535da40c93dba95174d8154fa88c6820267ab
+EBUILD lldb-16.0.0.9999.ebuild 2648 BLAKE2B ce0a4d9170e7ecb6331a0f793100c6ffbb7334135f34fb2bf1cbd6301ae57d7bfb4d6787b6b7e38a76fac78b54fc9041f3d5034a24a2ae0a31ea976ace2c5cc0 SHA512 e215a3dfb8c44f10af4b2c91da74238f1126f714e7e15d451564413c14ef88a8ec0b81fdbf2636ef265ebc7579e535da40c93dba95174d8154fa88c6820267ab
 MISC metadata.xml 299 BLAKE2B 2feead2cd1b35b3a43335ddd7711f8181b52bc63ee7166608914260c67528add5251349063afbef4f8cf0ec09b2cd4c3ffdd90f2c14ed60bb69ebc03888f6333 SHA512 cd745c54ab18d25bdaff18582105072574103a36cfe7c175ef740f266d00e9fc6f44c332904d23b911c939cf5bdf52973b388923099d8dd5dfef3c283b5cb685
diff --git a/dev-util/lldb/lldb-16.0.0.9999.ebuild b/dev-util/lldb/lldb-16.0.0.9999.ebuild
new file mode 100644
index 000000000000..fd12eb1fbf30
--- /dev/null
+++ b/dev-util/lldb/lldb-16.0.0.9999.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit cmake llvm llvm.org python-single-r1
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="debug +libedit lzma ncurses +python test +xml"
+RESTRICT="test"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	lzma? ( app-arch/xz-utils:= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	xml? ( dev-libs/libxml2:= )
+	~sys-devel/clang-${PV}
+	~sys-devel/llvm-${PV}
+"
+RDEPEND="
+	${DEPEND}
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+		${PYTHON_DEPS}
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	>=dev-util/cmake-3.16
+	python? (
+		>=dev-lang/swig-3.0.11
+		$(python_gen_cond_dep '
+			dev-python/six[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		$(python_gen_cond_dep "
+			~dev-python/lit-${PV}[\${PYTHON_USEDEP}]
+			dev-python/psutil[\${PYTHON_USEDEP}]
+		")
+		sys-devel/lld
+	)
+"
+
+LLVM_COMPONENTS=( lldb cmake )
+LLVM_TEST_COMPONENTS=( llvm/lib/Testing/Support llvm/utils/unittest )
+llvm.org_set_globals
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	# LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
+	use debug || local -x CPPFLAGS="${CPPFLAGS} -DNDEBUG"
+
+	local mycmakeargs=(
+		-DLLDB_ENABLE_CURSES=$(usex ncurses)
+		-DLLDB_ENABLE_LIBEDIT=$(usex libedit)
+		-DLLDB_ENABLE_PYTHON=$(usex python)
+		-DLLDB_ENABLE_LZMA=$(usex lzma)
+		-DLLDB_ENABLE_LIBXML2=$(usex xml)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		-DCLANG_LINK_CLANG_DYLIB=ON
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+
+		-DLLDB_EXTERNAL_CLANG_RESOURCE_DIR="${BROOT}/usr/lib/clang/${PV%_*}"
+
+		-DPython3_EXECUTABLE="${PYTHON}"
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=$(usex test)
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="$(get_lit_flags)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake_build check-lldb-{shell,unit}
+	# failures + hangs
+	#use python && cmake_build check-lldb-api
+}
+
+src_install() {
+	cmake_src_install
+	find "${D}" -name '*.a' -delete || die
+
+	use python && python_optimize
+}