reinit the tree, so we can have metadata

4 files changed, 158 insertions, 0 deletions

diff --git a/dev-util/edb-debugger/Manifest b/dev-util/edb-debugger/Manifest
new file mode 100644
index 000000000000..e5767dfaac68
--- /dev/null
+++ b/dev-util/edb-debugger/Manifest
@@ -0,0 +1,4 @@
+DIST edb-debugger-0.9.21.tgz 1042641 SHA256 2686619e1288152033d4c9c9a2568cb12841d3854bba8815c37ce77d3bd11706 SHA512 de921fa866da7d83efad92797bebcac3544ba1ffd5b3a015865b9bd554e8bc2e43539a9e4648517aff37f7d2497fdc4e1f6dc63df5cb0663012662626b1964f7 WHIRLPOOL 00c77e770c7fdc68644fcef732dc1c93ca6327f6543e80f9b628630ee6059a70bb51f4a290f73ae7502cfabad8f7eefca9a3e8762c778059e5eabeb439baed8b
+EBUILD edb-debugger-0.9.21.ebuild 2109 SHA256 39e87b0b18b10b866f905f4c48d923177a5e10dfceb97e20d8d82f88434a6d24 SHA512 d1d932deeb4109438e97c4b8417b3fa493d40a86e3582ace599097047691d1c6148ac3b62ec1b500af25171db3cfd790a8b67bb04289ae5ac7c819b0dc836def WHIRLPOOL 806f8854fb7c566a6ba4f08c900e3583f82f2379971ade30c947b26e5088e5c3544990b35a36b1d04262e0a9857b3b3b33dcef51f9baa0bdd18ad8da47bb2907
+EBUILD edb-debugger-9999.ebuild 1238 SHA256 ca21234b9163c55ba010a4f1ed66ccdae6210956ce3dbb0516c640dec567c017 SHA512 24763b7327d5d23dff879bd230c0c56c0a88dd6a7fb94c13699ce6b45c371bbf6d27c8b72736e26f25877758f004e4d46997858349a36b00ef96d701bddb459b WHIRLPOOL 4d29b77e620d8d36347ecd0cd9e3ebed188fe293b8c00a45ac16a5595a8c74639c02cf5b82b25e9953a038ba4fddb4a9c1791eeaddcd8c83ef28d9028187e0ee
+MISC metadata.xml 688 SHA256 5e4c41c45b13cea524e508f1f55ea8f55c7c3ee1b07bf2f0176902e1f270dfa2 SHA512 f83568251c245ecc4b3c2aebebd461e5ef765f79736a97c230bd58bdfa4da3643aa2e9fc6ca2b80eacf81ec2af6c1102c5f432002505ac6ad7977675aa629d65 WHIRLPOOL 83037a1b64b0fdb75cc9cf9bebd817afdff4942c1ada5a565114281d704139c5087c559b0ef136537593b9bf25c6861875a347801f5e5da9d95d1dcf210579d8
diff --git a/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild b/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild
new file mode 100644
index 000000000000..8d159b715b63
--- /dev/null
+++ b/dev-util/edb-debugger/edb-debugger-0.9.21.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils
+
+DESCRIPTION="edb is a cross platform x86/x86-64 debugger, inspired by Ollydbg"
+HOMEPAGE="https://github.com/eteran/edb-debugger"
+
+LICENSE="GPL-2+"
+IUSE="graphviz legacy-mem-write pax_kernel"
+SLOT="0"
+
+SRC_URI="https://github.com/eteran/edb-debugger/releases/download/${PV}/edb-debugger-${PV}.tgz"
+KEYWORDS="~amd64 ~x86"
+
+S="${WORKDIR}/edb-debugger-${PV}"
+
+RDEPEND="
+	>=dev-libs/capstone-3.0
+	graphviz? ( >=media-gfx/graphviz-2.38.0 )
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtgui:5
+	dev-qt/qtcore:5
+	"
+DEPEND="
+	>=dev-libs/boost-1.35.0
+	virtual/pkgconfig
+	${RDEPEND}"
+
+src_prepare(){
+	#Remove this in a future version; There won't be any edb48-logo.png
+	sed -i  '/edb48-logo/d' CMakeLists.txt || die
+
+	#Make the desktop's entries somewhat cuter
+	sed -i -e 's/GenericName=edb debugger/GenericName=Evan\x27s Debugger/' edb.desktop || die
+	sed -i -e 's/Comment=edb debugger/Comment=edb is a cross platform x86\/x86-64 debugger/' edb.desktop || die
+
+	if ! use graphviz; then
+		sed -i '/pkg_check_modules(GRAPHVIZ/d' CMakeLists.txt || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX=/usr
+		-DQT_VERSION=Qt5
+	)
+	if use pax_kernel || use legacy-mem-write; then
+		mycmakeargs+=( -DASSUME_PROC_PID_MEM_WRITE_BROKEN=Yes )
+	else
+		mycmakeargs+=( -DASSUME_PROC_PID_MEM_WRITE_BROKEN=No )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cd src/images/ || die
+	newicon "edb48-logo.png" "edb.png"
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	if use legacy-mem-write; then
+		ewarn "You really do not want to turn on legacy-mem-write unless you need it."
+		ewarn "Be sure to test without legacy-mem-write first and only enable if you actually need it."
+	else
+		ewarn
+		ewarn "If you notice that EDB doesn't work correctly, enable legacy-mem-write USE Flag"
+		ewarn "Please Report Bugs & Requests At: https://github.com/eteran/edb-debugger/issues"
+		ewarn
+	fi
+}
diff --git a/dev-util/edb-debugger/edb-debugger-9999.ebuild b/dev-util/edb-debugger/edb-debugger-9999.ebuild
new file mode 100644
index 000000000000..800b7d58d535
--- /dev/null
+++ b/dev-util/edb-debugger/edb-debugger-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils git-r3
+
+DESCRIPTION="edb is a cross platform x86/x86-64 debugger, inspired by Ollydbg"
+HOMEPAGE="https://github.com/eteran/edb-debugger"
+
+LICENSE="GPL-2+"
+IUSE="debug graphviz"
+SLOT="0"
+EGIT_REPO_URI="https://github.com/eteran/edb-debugger.git"
+KEYWORDS=""
+
+RDEPEND="
+	>=dev-libs/capstone-3.0
+	graphviz? ( >=media-gfx/graphviz-2.38.0 )
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtxmlpatterns:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtconcurrent:5
+	dev-qt/qtgui:5
+	dev-qt/qtcore:5
+	"
+DEPEND="
+	>=dev-libs/boost-1.35.0
+	virtual/pkgconfig
+	${RDEPEND}"
+
+src_prepare(){
+	#Make the desktop's entries somewhat cuter
+	sed -i -e 's/GenericName=edb debugger/GenericName=Evan\x27s Debugger/' edb.desktop || die
+	sed -i -e 's/Comment=edb debugger/Comment=edb is a cross platform x86\/x86-64 debugger/' edb.desktop || die
+
+	if ! use graphviz; then
+		sed -i '/pkg_check_modules(GRAPHVIZ/d' CMakeLists.txt || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	CMAKE_BUILD_TYPE=Release
+	use debug && CMAKE_BUILD_TYPE=Debug
+
+	mycmakeargs+=(
+		-DCMAKE_INSTALL_PREFIX=/usr
+		-DQT_VERSION=Qt5
+	)
+
+	cmake-utils_src_configure
+}
diff --git a/dev-util/edb-debugger/metadata.xml b/dev-util/edb-debugger/metadata.xml
new file mode 100644
index 000000000000..9be9b854d3f5
--- /dev/null
+++ b/dev-util/edb-debugger/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>petross404@gmail.com</email>
+		<name>Petros S</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<use>
+		<flag name="legacy-mem-write">Probe if writes to /proc/PID/mem are broken.</flag>
+		<flag name="graphviz">Add support for the Graphviz library</flag>
+		<flag name="pax_kernel">Enable building under a PaX enabled kernel</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">eteran/edb-debugger</remote-id>
+	</upstream>
+</pkgmetadata>