gentoo Easter resync : 12.04.2020

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-ruby/rubyzip/rubyzip-2.3.0.ebuild b/dev-ruby/rubyzip/rubyzip-2.3.0.ebuild
new file mode 100644
index 000000000000..5ab4e5fa4366
--- /dev/null
+++ b/dev-ruby/rubyzip/rubyzip-2.3.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+USE_RUBY="ruby24 ruby25 ruby26 ruby27"
+
+RUBY_FAKEGEM_RECIPE_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md TODO"
+
+RUBY_FAKEGEM_GEMSPEC="rubyzip.gemspec"
+
+RUBY_FAKEGEM_BINWRAP=""
+
+inherit ruby-fakegem
+
+DESCRIPTION="A ruby library for reading and writing zip files"
+HOMEPAGE="https://github.com/rubyzip/rubyzip"
+# Tests are not included in the gem.
+SRC_URI="https://github.com/rubyzip/rubyzip/archive/v${PV}.tar.gz -> ${P}-git.tgz"
+
+LICENSE="Ruby"
+SLOT="$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND=""
+DEPEND="${DEPEND} test? ( app-arch/zip )"
+
+ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc samples/*
+}
+
+all_ruby_prepare() {
+	# Avoid dependencies on simplecov and coveralls
+	sed -i -e '/simplecov/ s:^:#:' test/test_helper.rb || die
+
+	# Avoid dependency on bundler
+	sed -i -e '/bundler/ s:^:#: ; /rubocop/I s:^:#:' Rakefile || die
+
+	# Fix hardcoded path to /tmp
+	sed -i -e 's:/tmp/:'${T}'/:g' test/entry_test.rb || die
+
+	# Add missing requires
+	sed -i -e '1irequire "forwardable"; require "pathname"' test/input_stream_test.rb || die
+}